Fórmula SOMARPRODUTO SE – Excel e Google Sheets

Written by

Editorial Team

Reviewed by

Steve Rynearson

Translated by

Carlos Jensen

Last updated on July 10, 2023

Este tutorial demonstrará como calcular o “SOMARPRODUTO SE”, retornando a soma dos produtos de matrizes ou intervalos com base em critérios.

funcao somaproduto se

Função SOMARPRODUTO

A função SOMARPRODUTO é usada para multiplicar matrizes de números, somando a matriz resultante.

funcao somarprodutos

Para criar um “Somarproduto Se”, usaremos a função SOMARPRODUTO junto com a função SE em uma fórmula de matriz.

SOMARPRODUTO SE

Ao combinar SOMARPRODUTO e SE em uma fórmula de matriz, podemos essencialmente criar um “SOMARPRODUTO SE” que funciona de forma semelhante ao funcionamento da função SOMASE integrada. Vamos ver um exemplo.

Temos uma lista de vendas por gerentes em diferentes regiões com as respectivas taxas de comissão:

lista de regioes gerentes vendas comissoes

Suponha que sejamos solicitados a calcular o valor da comissão para cada gerente da seguinte forma:

comissoes por gerentes

Para isso, podemos aninhar uma função SE com o gerente como nosso critério dentro da função SOMARPRODUTO da seguinte forma:

=SOMARPRODUTO(SE(<intervalo de critério>=<critério>;<intervalo de valores1>*<intervalo de valores2>))

=SOMARPRODUTO(se($C$2:$C$10=$G2;$D$2:$D$10*$E$2:$E$10))

Ao usar o Excel 2019 e versões anteriores, você deve inserir a fórmula pressionando CTRL + SHIFT + ENTER para obter os colchetes ao redor da fórmula (veja a imagem superior).

Como funciona a fórmula?

A fórmula funciona avaliando cada célula em nosso intervalo de critérios como VERDADEIRO ou FALSO.

Cálculo da comissão total para Olivia:

=SOMARPRODUTO(SE($C$2:$C$10=$G2;$D$2:$D$10*$E$2:$E$10))

=SOMARPRODUTO(SE({VERDADEIRO; VERDADEIRO;FALSO; FALSO; FALSO; VERDADEIRO; FALSO; FALSO; FALSO}; {928,62; 668,22;919,695; 447,384; 697,620; 480,564; 689,325; 752,366; 869,61}))

Em seguida, a função SE substitui cada valor por FALSO se a condição não for atendida.

= SOMARPRODUTO({928,62; 668,22; FALSO; FALSO; FALSO; 480,564; FALSO; FALSO; FALSO})

Agora, a função SOMARPRODUTO ignora os valores de FALSO e soma os valores restantes (2.077,40).

SOMARPRODUTO SE com múltiplos critérios

Para usar o SOMARPRODUTO SE com vários critérios (semelhante ao funcionamento da função SOMASES integrada), basta aninhar mais funções SE na função SOMARPRODUTO da seguinte forma:

=SOMARPRODUTO(SE(<intervalo de critério>=<critério1>; SE(<intervalo de critério2>=<critério2>; <intervalo de valores1>*<intervalo de valores2>))

=SOMARPRODUTO(SE($B$2:$B$10=$G2;SE($C$2:$C$10=$H2;$D$2:$D$10*$E$2:$E$10)))

funcao somarproduto se

=SOMARPRODUTO(--($B$2:$B$10=$G2);--($C$2:$C$10=$H2);$D$2:$D$10*$E$2:$E$10)

Esse método usa o unário duplo (–) para converter uma matriz VERDADEIRO FALSO em zeros e uns. Em seguida, o SOMARPRODUTO multiplica as matrizes de critérios convertidos:

=SOMARPRODUTO({1;1;0;0;0;1;0;0;0};{1;0;1;0;1;0;0;0;0};{928,62; 668,22;919,695; 447,384; 697,620; 480,564; 689,325; 752,366; 869,61})

Dicas e truques:

Sempre que possível, bloqueie a referência (F4) de seus intervalos e entradas de fórmula para permitir o preenchimento automático.
Se estiver usando o Excel 2019 ou mais recente, você poderá inserir a fórmula sem Ctrl + Shift + Enter.

SOMARPRODUTO SE no Google Sheets

A função SOMARPRODUTO SE funciona exatamente da mesma forma no Planilhas Google e no Excel, exceto que você deve usar a função ARRAYFORMULA em vez de CTRL+SHIFT+ENTER para criar a fórmula de matriz.

funcao arrayformula google sheets