Soma no Mês até a Data ou no Ano até a Data – Planilhas do Excel e do Google

Este tutorial demonstra como usar a função SOMASES para somar dados acumulados no mês ou no ano no Excel e no Google Planilhas.

 

Soma no Mês até a Data

A função SOMASES soma os dados das linhas que atendem a determinados critérios. Sua sintaxe é:

Este exemplo soma as Reservas de tabela no mês, usando as funções: SOMASES, DATA, ANO, MÊS e HOJE.

=SOMASES(C3:C11;B3:B11;">="&DATA(ANO(HOJE());MÊS(HOJE());1);B3:B11;"<="&HOJE())

Agora vamos examinar a fórmula.

Função HOJE

A função HOJE retorna a data atual. O valor é recalculado toda vez que o arquivo é visualizado.

=HOJE()

 

Esse é o limite superior do nosso intervalo de datas para a fórmula.

Função DATA

Em seguida, calcule a extremidade inferior do intervalo de datas: o primeiro dia do mês atual. Usamos a função DATA com ANO e MÊS para produzir esse valor de data. Use o ano e o mês da data de hoje e defina o dia como 1.

=DATA(ANO(E3);MÊS(E3);1)

Função SOMASES

Use a função SOMASES para somar as reservas de tabela quando a data for maior ou igual ao primeiro dia do mês e menor ou igual ao dia atual.

=SOMASES(C3:C11;B3:B11;">="&F3;B3:B11;"<="&E3)

A combinação dessas etapas nos dá a fórmula para a soma do mês até a data:

=SOMASES(C3:C11;B3:B11;">="&DATA(ANO(HOJE());MÊS(HOJE());1);B3:B11;"<="&HOJE())

 

Soma no Ano até a Data

A mesma lógica pode ser usada para somar o número de reservas de mesa do ano atual até hoje, fazendo com que a data de início seja o primeiro dia do ano. Tanto o mês quanto o dia são definidos como 1.

=SOMASES(C3:C11;B3:B11;">="&DATA(ANO(HOJE());1;1);B3:B11;"<="&HOJE())

 

Bloqueio de Referências de Células

Para facilitar a leitura de nossas fórmulas, nós as mostramos sem referências de células bloqueadas:

=SOMASES(C3:C11;B3:B11;">="&DATA(ANO(HOJE());1;1);B3:B11;"<="&HOJE())

Mas essas fórmulas não funcionarão corretamente quando forem copiadas e coladas em outro local do arquivo do Excel. Em vez disso, você deve usar referências de células bloqueadas como esta:

=SOMASES($C$3:$C$11;$B$3:$B$11;">="&DATA(ANO(HOJE());1;1);$B$3:$B$11;"<="&HOJE())

Leia nosso artigo sobre Bloqueio de referências de células para saber mais.

Soma no Mês ou por Ano até a Data no Google Planilhas

Essas fórmulas funcionam exatamente da mesma forma no Google Planilhas e no Excel.