Soma se por mês – Excel e Google Sheets

Este tutorial demonstrará como usar a função SOMASES para somar dados correspondentes a meses específicos no Excel e no Google Sheets.

SOMASEs por mês

Primeiro, demonstraremos como somar dados correspondentes a datas que caem em um mês e ano específicos.

Podemos usar a função SOMASES, juntamente com as funções DATA, ANO, MÊS e FIMMÊS, para somar o Número de Vendas em cada Mês.

=SOMASES(C3:C9;B3:B9;">="& DATA( ANO(E3);MÊS(E3);1);B3:B9;"<="& FIMMÊS(E3;0))

Para criar a fórmula acima, começamos definindo o intervalo de datas para cada mês. Usamos a função DATA para definir o primeiro dia do mês (ex.: 1/5/2021). Podemos fazer isso “codificando” a data na fórmula:

">="&DATA(2021;5;1)

Ou, melhor ainda, podemos tornar os critérios flexíveis fazendo referência a uma data na célula E3, extraindo o ano e o mês da data (e definindo o dia como 1), conforme mostrado no exemplo acima:

">="&DATA(ANO(E3);MÊS(E3);1)

Para definir o último dia do mês, podemos usar a função FIMMÊS:

"<="&FIMMÊS(E3;0)

Juntando todos esses critérios, podemos escrever a seguinte fórmula SOMASES:

=SOMASES(C3:C9;B3:B9;">="& DATA(ANO(E3);MÊS(E3);1);B3:B9;"<="& FIMMÊS(E3;0))

 

Bloqueio de referências de células

Para facilitar a leitura de nossas fórmulas, mostramos as fórmulas sem referências de células bloqueadas:

=SOMASES(C3:C9;B3:B9;">="& DATA(ANO(E3);MÊS(E3);1);B3:B9;"<="& FIMMÊS(E3;0))

Mas essas fórmulas não funcionarão corretamente quando forem copiadas e coladas em outro local do arquivo. Em vez disso, você deve usar referências de células bloqueadas como esta:

=SOMASES($C$3:$C$9;$B$3:$B$9;">="& DATA(ANO(E3);MÊS(E3);1);$B$3:$B$9;"<="& FIMMÊS(E3;0))

Leia nosso artigo sobre bloqueio de referências de células para saber mais.

Formatação de valores de mês

Neste exemplo, listamos os meses na coluna E. Esses valores de mês são, na verdade, datas formatadas para omitir o dia, usando a formatação de números personalizados.

O formato de dados personalizado é “mmm yyyy” para mostrar maio de 2021.

 

Soma por mês ao longo de vários anos

O exemplo acima somou dados com datas que caíram em um mês e ano específicos. Em vez disso, você pode somar dados com datas que caem em um mês em qualquer ano usando a função SOMARPRODUTO.

Neste exemplo, usamos a função SOMARPRODUTO para realizar cálculos complicados de “soma se”. Vamos examinar a fórmula.

Essa é a nossa fórmula final:

=SOMARPRODUTO(C3:C8;--(MÊS(B3:B8)=MÊS(E3)))

Primeiro, a função  SOMARPRODUTO lista o Número de vendas para cada Data de Vendas e, em seguida, compara o mês de cada Data de Vendas com o Mês especificado, retornando VERDADEIRO se os meses coincidirem ou FALSO se não coincidirem:

=SOMARPRODUTO({30;42;51;28;17;34};--({VERDADEIRO;FALSO;VERDADEIRO;FALSO;VERDADEIRO;FALSO}))

Em seguida, os traços duplos (–) convertem os valores VERDADEIRO e FALSO em 1s e 0s:

=SOMARPRODUTO({30;42;51;28;17;34},{1;0;1;0;1;0})

Em seguida, a função SOMARPRODUTO multiplica cada par de entradas nas matrizes:

=SOMARPRODUTO({30;0;51;0;17;0})

Por fim, os números da matriz são somados:

=98

Mais detalhes sobre o uso de declarações booleanas e do comando “–” em uma função SOMARPRODUTO podem ser encontrados aqui