SOMA com uma Função PROCV – Excel e Google Planilhas

Written by

Editorial Team

Reviewed by

Steve Rynearson

Translated by

Luciano Farina

Last updated on July 7, 2023

Este tutorial vai demonstrar como somar os resultados de várias funções PROCV em uma fórmula no Excel e no Google Planilhas.

mf soma procv 3

SOMA com PROCV

A função PROCV pesquisa um único valor, mas, ao criar uma fórmula de matriz, você pode pesquisar e somar vários valores de uma só vez.

Este exemplo vai mostrar como calcular a receita total de vendas de uma loja específica ao longo de 3 meses usando uma função de matriz com SOMA e PROCV:

=SOMA(PROCV(P3;B3:N6;{2;3;4};FALSO))

soma procv 2

Essa fórmula de matriz é equivalente ao uso das três funções regulares PROCV a seguir para somar as receitas dos meses de janeiro, fevereiro e março.

=PROCV(P3;B3:N6;2;FALSO)+PROCV(P3;B3:N6;3;FALSO)+PROCV(P3;B3:N6;4;FALSO)

procv 3x

Podemos combinar essas funções fazendo o seguinte:

Primeiro, definimos a função PROCV para retornar as colunas 2, 3 e 4 como uma saída de matriz (entre colchetes):

=PROCV(P3;B3:N6,{2;3;4},FALSO)

Isso produzirá o resultado da matriz:

{98; 20; 76}

Em seguida, para somar o resultado da matriz, usamos a função SOMA.

Importante! Se você estiver usando as versões 2019 ou anteriores do Excel, deverá inserir a fórmula pressionando CTRL + SHIFT + ENTER para criar a fórmula de matriz. Você saberá que fez isso corretamente quando os colchetes aparecerem ao redor da fórmula. Isso não é necessário no Excel 365 (ou em versões mais recentes do Excel).

Uso de Tamanhos Maiores de Matriz em uma Função PROCV

Podemos ampliar o tamanho da entrada da matriz para representar mais dados. O próximo exemplo calculará a receita total de vendas de uma loja específica por 12 meses usando uma função de matriz que contém a função SOMA para combinar 12 usos da função PROCV em uma célula.

{=SOMA(PROCV(P3;B3:N6;{2;3;4;5;6;7;8;9;10;11;12;13};FALSO))}

soma tamanho 2

Outras funções de resumo e PROCV

Outras funções de resumo podem ser usadas da mesma forma que a função SOMA para produzir estatísticas de resumo alternativas. Por exemplo, podemos usar as funções MÁXIMO, MÍNIMO, MÉDIA, MED, SOMA e CONT.NÚM para resumir a receita de vendas de janeiro a março:

=MÁXIMO(PROCV(J3;B3:H6;{2;3;4};FALSO))

=MÍNIMO(PROCV(J3;B3:H6;{2;3;4};FALSO))

=MÉDIA(PROCV(J3;B3:H6;{2;3;4};FALSO))

=MED(PROCV(J3;B3:H6;{2;3;4};FALSO))

=SOMA(PROCV(J3;B3:H6;{2;3;4};FALSO))

=CONT.NÚM(PROCV($J3;$B$3:$H$6;{2;3;4};FALSO))

procv outros 2

Bloqueio de Referências de Células

Para facilitar a leitura de nossas fórmulas, mostramos as fórmulas sem referências de células bloqueadas:

=SOMA(PROCV(P3;B3:N6;{2;3;4};FALSO))

Mas essas fórmulas não funcionarão corretamente quando forem copiadas e coladas em outro local do arquivo. Em vez disso, você deve usar referências de células bloqueadas como esta:

{=SOMA(PROCV(P3;$B$3:$N$6;{2;3;4};FALSO))}

Leia nosso artigo sobre Bloqueio de referências de células para saber mais.

Resultados do SOMA PROCV no Google Planilhas

Essas fórmulas funcionam da mesma forma no Google Planilhas e no Excel, exceto pelo fato de que a função ARRAYFORMULA deve ser usada no Planilhas Google para que os resultados sejam avaliados corretamente. Isso pode ser adicionado automaticamente pressionando as teclas CTRL + SHIFT + ENTER durante a edição da fórmula.

=ARRAYFORMULA(SOMA(PROCV(O2;A2:M5;{2;3;4};FALSO)))