Soma se Célula Não Estiver em Branco – Excel e Google Planilhas

Este tutorial vai demonstrar como usar a função SOMASES para somar dados relacionados a células não vazias ou não em branco no Excel e no Google Planilhas.

Soma se Não em Branco

Primeiro demonstraremos como somar dados relacionados a células não vazias.

Podemos usar a função SOMASES para somar todas as pontuações de jogadores com nomes que não estejam em branco usando critérios (“<>”).

=SOMASES(C3:C8;B3:B8;"<>")

Tratando Espaços como Células em Branco – Usando Coluna Auxiliar

É preciso ter cuidado ao interagir com células em branco no Excel. As células podem parecer em branco para você, mas o Excel não as tratará como tal. Isso pode ocorrer se a célula contiver espaços, quebras de linha ou outros caracteres invisíveis. Esse é um problema comum ao importar dados de outras fontes para o Excel.

Se precisarmos tratar quaisquer células que contenham apenas espaços da mesma forma como se estivessem em branco, a fórmula do exemplo anterior não funcionará. Observe como a fórmula SOMASES não considera a célula B9 abaixo (” “) como em branco:

=SOMASES(D3:D9;B3:B9;"<>")

Para tratar uma célula que contém apenas espaços como se fosse uma célula em branco, podemos adicionar uma coluna auxiliar usando as funções NÚM.CARACT e ARRUMAR.

A função ARRUMAR remove espaços extras da célula.

A função NÚM.CARACT conta o número de caracteres restantes. Se a contagem for 0, a célula “aparada” estará em branco.

=NÚM.CARACT(ARRUMAR(B3))

 

Agora, use a função SOMASES para somar se a contagem for > 0.

=SOMASES(E3:E9;D3:D9;">0")

A coluna auxiliar é fácil de criar e de ler, mas talvez você queira ter uma única fórmula para realizar a tarefa. Isso será abordado na próxima seção.

Tratamento de Espaços como Células em Branco – Sem Coluna Auxiliar

Para realizar tudo isso com uma única fórmula, podemos usar a função SOMARPRODUTO em combinação com as funções NÚM.CARACT e ARRUMAR.

=SOMARPRODUTO(--(NÚM.CARACT(ARRUMAR(B3:B9))>0);D3:D9)

Vamos examinar a fórmula.

Primeiro, a função SOMARPRODUTO lê os valores das células:

=SOMARPRODUTO(--(NÚM.CARACT(ARRUMAR({"A"; "B"; ""; "C"; ""; "XX"; "   "}))>0);{25; 10; 15; 5; 8; 17; 50})

Em seguida, a função ARRUMAR remove os espaços à esquerda e à direita dos nomes dos jogadores :

=SOMARPRODUTO(--(NÚM.CARACT({"A"; "B"; ""; "C"; ""; "XX"; ""})>0);{25; 10; 15; 5; 8; 17; 50})

A função NÚM.CARACT calcula os comprimentos dos nomes dos jogadores cortados:

=SOMARPRODUTO(--({1; 1; 0; 1; 0; 2; 0}>0);{25; 10; 15; 5; 8; 17; 50})

Com o teste lógico (>0), todos os nomes de jogadores cortados com mais de 0 caracteres são alterados para VERDADEIRO:

=SOMARPRODUTO(--({VERDADEIRO; VERDADEIRO; FALSO; VERDADEIRO; FALSO; VERDADEIRO; FALSO});{25; 10; 15; 5; 8; 17; 50})

Em seguida, os traços duplos (–) convertem os valores VERDADEIRO e FALSO em 1s e 0s:

=SOMARPRODUTO({1; 1; 0; 1; 0; 1; 0};{25; 10; 15; 5; 8; 17; 50})

A função SOMARPRODUTO multiplica cada par de entradas nas matrizes para produzir uma matriz de pontuações somente para nomes de jogadores que não estejam em branco ou não sejam formados somente por espaços:

=SOMARPRODUTO({25; 10; 0; 5; 0; 17; 0})

Por fim, os números da matriz são somados

=57

Mais detalhes sobre o uso de declarações booleanas e do comando “–” em uma função SOMARPRODUTO podem ser encontrados aqui.

Soma se Não em Branco no Google Planilhas

Essas fórmulas funcionam exatamente da mesma forma no Planilhas Google e no Excel.