Remover Números de Texto no Excel e no Google Planilhas

Este tutorial vai demonstrar como remover números do texto em uma célula no Excel e no Google Planilhas.

Discutiremos duas fórmulas diferentes para remover números do texto no Excel.

Fórmula da Função SUBSTITUIR

Podemos usar uma fórmula baseada na função SUBSTITUIR. É uma fórmula longa, mas é uma das maneiras mais fáceis de remover números de uma cadeia alfanumérica.

Nessa fórmula, temos funções SUBSTITUIR aninhadas 10 vezes (uma para cada número: 0,1,…,9), assim:

=SUBSTITUIR(SUBSTITUIR(SUBSTITUIR(SUBSTITUIR(SUBSTITUIR(SUBSTITUIR(SUBSTITUIR(SUBSTITUIR(SUBSTITUIR(
SUBSTITUIR(B3;1;"");2;"");3;"");4;"");5;"");6;"");7;"");8;"");9;"");0;"")

 

Fórmula de Matriz UNIRTEXTO

Para remover números de cadeias alfanuméricas, também podemos usar uma fórmula de matriz complexa que consiste nas funções UNIRTEXTO, EXT.TEXTO, LIN e INDIRETO.

{=UNIRTEXTO("";VERDADEIRO;SE(ÉERRO(EXT.TEXTO(B3;LIN(INDIRETO("1:"&NÚM.CARACT(B3)));1)+0);
EXT.TEXTO(B3;LIN(INDIRETO("1:"&NÚM.CARACT(B3)));1);""))}

Observação: UNIRTEXTO é uma nova função do Excel, disponível no Excel 2019+ e no Office 365.

Essa é uma fórmula complexa, portanto, vamos dividi-la em etapas para entendê-la melhor.

Etapa 1

A Função EXT.TEXTO é uma Função de Texto que retorna o texto do meio de uma célula. Você deve indicar o número de caracteres a serem retornados e o caractere inicial.

Para o argumento do número inicial (núm_inicial) na função EXT.TEXTO, usaremos a lista de matriz resultante das funções LIN e INDIRETO.

=LIN(INDIRETO("1:"&NÚM.CARACT(B3)))

Para o número de caracteres (núm_caract), use 1. Depois de inserir os argumentos na função EXT.TEXTO, ela retornará uma matriz.

{=EXT.TEXTO(B3;LIN(INDIRETO("1:"&NÚM.CARACT(B3)));1)}

Etapa 2

Adicionaremos zero (+ 0) a cada valor na matriz resultante (que obtemos da função EXT.TEXTO acima). No Excel, se números forem adicionados a caracteres não numéricos, receberemos um erro #VALOR. Portanto, após adicionar 0 na matriz acima, obteremos uma matriz de números e erros #VALOR.

{=EXT.TEXTO(B3;LIN(INDIRETO("1:"&NÚM.CARACT(B3)));1)+0}

Etapa 3

Em seguida, use a função ÉERRO para retornar VERDADEIRO para erros e FALSO para valores sem erros, gerando uma matriz de VERDADEIRO e FALSO, VERDADEIRO para caracteres não numéricos e FALSO para números.

=ÉERRO(EXT.TEXTO(B3;@LIN(INDIRETO("1:"&NÚM.CARACT(B3)));1)+0)

Etapa 4

Em seguida, adicione a função SE.

A função SE verificará o resultado da função ÉERRO (Etapa 3). Se seu valor for VERDADEIRO, ela retornará uma matriz de todos os caracteres de uma string alfanumérica. Para isso, adicionamos outra função EXT.TEXTO sem adicionar zero no final. Se o valor da função se for FALSO, ela retornará um espaço em branco (“”).

Dessa forma, teremos uma matriz que contém apenas os caracteres não numéricos da string.

=SE(ÉERRO(EXT.TEXTO(B3;@LIN(INDIRETO("1:"&NÚM.CARACT(B3)));1)+0);EXT.TEXTO(B3;@LIN(INDIRETO("1:"&NÚM.CARACT(B3)));1);"")

Etapa 5

Por fim, a matriz acima é colocada na função UNIRTEXTO. A função UNIRTEXTO juntará todos os caracteres da matriz acima e ignorará a string vazia.

O delimitador para essa função é definido como uma cadeia vazia (“”) e o valor do argumento ignore_empty é inserido como VERDADEIRO.

Isso nos dará o resultado desejado, ou seja, apenas os caracteres não numéricos da cadeia alfanumérica.

{=UNIRTEXTO("";VERDADEIRO;SE(ÉERRO(EXT.TEXTO(B3;LIN(INDIRETO("1:"&NÚM.CARACT(B3)));1)+0);
EXT.TEXTO(B3;LIN(INDIRETO("1:"&NÚM.CARACT(B3)));1);""))}

Observação: essa é uma fórmula de matriz. Ao inserir fórmulas de matriz no Excel 2019 ou anterior, você deve usar CTRL + SHIFT + ENTER para inserir a fórmula em vez do ENTER normal.

Você saberá que inseriu a fórmula corretamente pelos colchetes que aparecem. NÃO digite manualmente os colchetes, pois a fórmula não funcionará.

Com o Office 365 (e, presumivelmente, com as versões do Excel posteriores a 2019), você pode simplesmente inserir a fórmula normalmente.

Função ARRUMAR

Quando os números são removidos da cadeia de caracteres, pode haver espaços extras. Para remover todos os espaços à direita e à esquerda e os espaços extras entre as palavras, podemos usar a função ARRUMAR antes da fórmula principal, assim:

=ARRUMAR(C3)

Remover Números de Texto no Google Planilhas

A fórmula para remover números do texto funciona exatamente da mesma forma no Google Planilhas e no Excel. Algumas funções novas não possuem tradução, como a UNIRTEXTO, que ainda aparece, abaixo, como TEXT JOIN. Importante lembrar que no Google Planilhas as fórmulas matriciais são definidas pelo comando ARRAY_CONSTRAIN, no lugar das chaves {} do Excel: