PROCV Retorna 0? Retornar em Branco em vez disso – Excel e Google Planilhas

Este tutorial demonstra como retornar um espaço em branco se a saída do PROCV estiver em branco. Se sua versão do Excel for compatível com o PROCX, recomendamos usar o PROCX.

No Excel, ao se referir a outra célula com uma fórmula, os valores em branco são calculados como zero.

Isso pode ser um problema em alguns cenários de PROCV em que precisamos distinguir espaços em branco de zeros:

=PROCV("2021-D";B3:C7;2;FALSO)

PROCV com SE e É.NÃO.DISP

Podemos usar a combinação de PROCV com SE e É.NÃO.DISP para resolver esse problema:

=SE(ÉCÉL.VAZIA(PROCV(E3;B3:C7;2;FALSO));"";PROCV(E3;B3:C7;2;FALSO))

 

Vamos detalhar e analisar a fórmula:

Para retornar em branco se a saída do PROCV estiver em branco, precisamos de duas coisas:

1. Um método para verificar se a saída do PROCV está em branco
2. E uma função que possa substituir zero por uma string vazia (“”), que é o mais próximo de branco que podemos retornar.

Função ÉCEL.VAZIA

Podemos usar ÉCEL.VAZIA para verificar se o resultado de PROCV está em branco.

=ISBLANK(VLOOKUP(E3,B3:C7,2,FALSE))

Observações:

1. A função ÉCEL.VAZIA retorna VERDADEIRO se um valor estiver em branco. A cadeia de caracteres vazia (“”) e 0 não são equivalentes a um espaço em branco. Uma célula que contém uma fórmula não está em branco, e é por isso que não podemos usar F3 como entrada para ÉCEL.VAZIA.
2. As fórmulas podem retornar espaços em branco como resultados, mas eles são convertidos em zero no estágio final do cálculo.
3. Portanto, podemos aninhar fórmulas em ÉCEL.VAZIA para verificar se seus resultados são espaços em branco em vez de atribuir as fórmulas às células antes de aplicar ÉCEL.VAZIA às células.

Função SE

Em seguida, podemos usar a função SE para testar se a combinação de ÉCEL.VAZIA e PROCV é VERDADEIRA ou FALSA. Podemos definir qualquer processo (por exemplo, emitir uma string vazia) onde a condição é VERDADEIRA e outro (por exemplo, o resultado da PROCV se não estiver em branco) se o resultado for FALSO.

=SE(G3;"";F3)

 

A combinação de todos esses conceitos resulta em nossa fórmula original:

=SE(ÉCÉL.VAZIA(PROCV(E3;B3:C7;2;FALSO));"";PROCV(E3;B3:C7;2;FALSO))

PROCV com SE e String Vazia (“”)

Podemos usar a cadeia de caracteres vazia como critério para verificar se o valor do PROCV está em branco em vez de usar a função ÉCÉL.VAZIA:

=SE(PROCV(E3;B3:C7;2;FALSO)="";"";PROCV(E3;B3:C7;2;FALSO))

Observação: Célula em branco pode ser equivalente a zero ou cadeia de caracteres vazia, dependendo do cálculo, mas cadeias de caracteres vazias e 0s não são espaços em branco.

PROCV com SE e NÚM.CARACT

Outra alternativa ao ÉCÉL.VAZIA é usar a função NÚM.CARACT:

=SE(NÚM.CARACT(PROCV(E3;B3:C7;2;FALSO))=0;"";PROCV(E3;B3:C7;2;FALSO))

 

Vamos nos aprofundar nessa solução alternativa:

Verificar se é Em Branco com NÚM.CARACT

Como dito anteriormente, as fórmulas retornam resultados em branco, mas são convertidas no final dos cálculos.

Portanto, podemos usar a função NÚM.CARACT para contar o número de caracteres da saída do PROCV:

=NÚM.CARACT(PROCV(E3;B3:C7;2;FALSO))

Se o número de caracteres for 0, isso significa que o valor está em branco. Podemos então usar a função SE para verificar se a função NÚM.CARACT  é igual a 0 e retornar uma cadeia de caracteres vazia se isso for verdade:

=SE(G3=0;"";F3)

A combinação de todos esses conceitos resulta em nossa fórmula original:

=SE(NÚM.CARACT(PROCV(E3;B3:C7;2;FALSO))=0;"";PROCV(E3;B3:C7;2;FALSO))

PROCV Retorna em Branco no Google Planilhas

Todas as fórmulas mencionadas acima funcionam da mesma forma no Google Planilhas mas, de fato, não precisamos implementá-las no Planilhas Google para exibir um resultado semelhante a um espaço em branco, pois o Planilhas Google pode retornar espaços em branco.

 

Observação: isso é muito útil em situações em que precisamos distinguir espaços em branco de cadeias de caracteres vazias.

Observe que as fórmulas acima só são aplicáveis se a saída estiver em branco, o que é diferente de um resultado “sem correspondência”. Se o PROCV não encontrar uma correspondência, ele retornará o erro #N/D e, nesse caso, precisamos lidar com o erro #N/D; consulte o artigo: “PROCV – Corrigir o erro #ND”