Fórmula PERCENTIL SE – Excel e Google Planilhas

Written by

Editorial Team

Reviewed by

Steve Rynearson

Translated by

Luciano Farina

Last updated on July 24, 2023

Este tutorial demonstra como calcular o “percentil se”, recuperando o k-ésimo percentil considerando apenas os valores que atendem a determinados critérios.

mf porcento se 2

Função PERCENTIL

A função PERCENTIL é usada para calcular o k-ésimo percentil de valores em um intervalo em que k é o valor do percentil entre 0 e 1, inclusive.

=PERCENTIL($D$2:$D$10;0,75)

porcento se 1

Para criar um “Percentil Se”, usaremos a função PERCENTIL junto com a função SE em uma fórmula de matriz.

PERCENTIL SE

Ao combinar PERCENTIL e SE em uma fórmula de matriz, podemos essencialmente criar uma função “PERCENTIL SE” que funciona de modo semelhante ao funcionamento da função MÉDIASE integrada.

Neste exemplo, temos uma lista de pontuações obtidas pelos alunos em duas matérias diferentes:

porcento se 2

Queremos encontrar o 75º percentil das pontuações obtidas em cada matéria da seguinte forma:

porcento se 3

Para isso, podemos aninhar uma função SE com a matéria como nosso critério dentro da função PERCENTIL da seguinte forma:

=PERCENTIL(SE(<intervalo de critérios>=<critérios>; <intervalo de valores>);<percentil>)

=PERCENTIL(SE($C$2:$C$10=$F2;$D$2:$D$10);0,75)

Ao usar o Excel 2019 e versões anteriores, você deve inserir a fórmula de matriz pressionando CTRL SHIFT ENTER (em vez de ENTER), informando ao Excel que a fórmula é uma fórmula de matriz. Você saberá que se trata de uma fórmula de matriz pelos colchetes que aparecem ao redor da fórmula (veja a primeira imagem deste artigo).

Como a Fórmula Funciona?

A função SE avalia cada célula em nosso intervalo de critérios como VERDADEIRO ou FALSO, criando duas matrizes:

=PERCENTIL(SE({VERDADEIRO;FALSO;FALSO;VERDADEIRO;FALSO;VERDADEIRO;FALSO;VERDADEIRO;FALSO}; {0,99;0,8;0,93;0,42;0,87;0,63;0,71;0,58;0,73}); 0,75)

Em seguida, a função SE cria uma única matriz, substituindo cada valor por FALSO se a condição não for atendida.

=PERCENTIL({0,99;FALSO;FALSO;0,42;FALSO;0,63;FALSO;0,58;FALSO}; 0,75)

Agora a função PERCENTIL ignora os valores FALSO e calcula o 75º percentil dos valores restantes (0,72 é o 75º percentil).

PERCENTILE SE com Vários Critérios

Para calcular o PERCENTIL SE com vários critérios (semelhante ao funcionamento da função MÉDIASES integrada), basta multiplicar os critérios:

=PERCENTIL(SE((<intervalo de critérios1>=<critérios1>)*(<intervalo de critérios2>=<critérios2>);<intervalo de valores>);<percentil>)

=PERCENTIL(SE(($D$2:$D$10=$H2)*($C$2:$C$10=$G2);$E$2:$E$10);0,75)

porcento se 4

Outra maneira de incluir vários critérios é aninhar mais instruções SE dentro da fórmula.

Dicas e truques:

Sempre que possível faça referência à posição (k) de uma célula auxiliar e bloqueie a referência (usando tecla F4), pois isso facilitará o preenchimento automático das fórmulas.
Se estiver usando o Excel 2019 ou mais recente, você poderá inserir a fórmula sem CTRL SHIFT ENTER, apenas com o ENTER.
Para recuperar os nomes dos alunos que obtiveram as melhores notas, combine isso com ÍNDICE / CORRESP.

PERCENTIL SE no Google Planilhas

Google A fórmula PERCENTIL SE funciona exatamente da mesma forma no Google Planilhas e no Excel, exceto pelo fato de que você deve envolver a fórmula com a função ARRAYFORMULA para informar ao Planilhas que se trata de uma fórmula de matriz.

porcento se google