Arredondar o Número para N Algarismos Significativos no Excel e no Google Planilhas

Este tutorial demonstrará como arredondar um número para um número específico de dígitos significativos no Excel e no Planilhas Google.

O que são Algarismos Significativos?

Algarismos significativos são o número de dígitos que trazem contribuições significativas para sua resolução de medição (fonte: Wikipedia).

Arredondar para N Algarismos Significativos

Essa fórmula arredonda um número para um número especificado de dígitos (algarismos):

=ARRED(A2;B2-(1+INT(LOG10(ABS(A2)))))

Essa é uma fórmula complicada. Vamos simplificá-la:

=ARRED(número_para_arredondar; alg_significativos - (1 + dígitos_no_número))

A seguir, mostraremos como a fórmula funciona.

Função ARRED

A função ARRED arredonda um número para o número especificado de dígitos relativos ao decimal. Ao usar números negativos, podemos arredondar para a esquerda do decimal.

Como você pode ver, precisamos de uma maneira para calcular a entrada núm_dígitos (segundo argumento) para arredondar para um número especificado de dígitos. Como sabemos os dígitos significativos para os quais queremos arredondar, precisamos apenas de uma forma de calcular o número de dígitos em um número.

Número de Dígitos em um Número

Primeiro, vamos calcular o número de dígitos em um número. Faremos isso com a seguinte fórmula:

=INT(LOG10(ABS(A2)))

 

Vamos ver como a fórmula funciona…

Os números podem ser armazenados usando notação científica:

1234567 = 1,234567 * 10 ^ 6
 123456 = 1,23456 * 10 ^ 5
 12345 = 1,2345 * 10 ^ 4
 1234 = 1,234 * 10 ^ 3
 123 = 1,23 * 10 ^ 2
 12 = 1,2 * 10 ^ 1

O valor do expoente na notação científica nos informa quantos dígitos o número contém.

Função LOG10

Em seguida, podemos usar as funções INT e LOG10 para retornar o expoente acima.

Como isso Funciona? A função LOG10 retorna o expoente ao qual 10 deve ser elevado para produzir o número.

Usamos a função INT para remover o valor decimal do expoente, de modo que apenas o número inteiro permaneça.

Função ABS

LOG10 não funcionará com números negativos, portanto, também devemos adicionar a função ABS para calcular o valor absoluto, o que nos dá a fórmula para calcular o número de dígitos em um número.

Número de Dígitos para Arredondar

Agora sabemos como calcular o número de dígitos em um número. Lembra-se de nossa fórmula simplificada acima?

=ARRED(número_para_arredondar; alg_significativos - (1 + dígitos_no_número))

Insira a fórmula para calcular o número de dígitos em um número:

=ARRED(número_para_arredondar; alg_significativos - (1 + INT(LOG10(ABS(número_para_arredondar)))))

e vamos adicionar referências de células para chegar à nossa fórmula:

=ARRED(A2;B2-(1+INT(LOG10(ABS(A2)))))

 

Arredondamento de números para n algarismos significativos no Google Planilhas

Todos os exemplos acima funcionam exatamente da mesma forma no Google Planilhas e no Excel.