VBA 범위/셀 선택하기

VBA를 사용하면 워크시트에서 셀, 셀 범위 또는 모든 셀을 선택할 수 있습니다. Selection 개체를 사용하여 선택한 셀 또는 범위를 조작할 수 있습니다.

VBA를 사용하여 단일 셀 선택하기

선택 방법을 사용하여 워크시트에서 셀을 선택할 수 있습니다. 다음 코드를 통해 활성 워크시트에서 A2 셀을 선택할 수 있습니다:

Range("A2").Select

또는

Cells(2, 1).Select

결과는 다음과 같습니다:

VBA를 사용하여 셀 범위 선택하기

Select 메서드와 Range 개체를 사용하여 워크시트에서 셀 영역을 선택할 수 있습니다. 다음 코드는 A1:C5를 선택합니다:

Range("A1:C5").Select

VBA를 사용하여 연속되지 않은 셀 범위 선택하기

VBA에서 쉼표를 사용하여 셀 또는 범위를 구분하여 연속되지 않은 셀 또는 범위를 선택할 수 있습니다. 다음 코드를 사용하면 A1, C1, E1 셀을 선택할 수 있습니다:

Range("A1, C1, E1").Select

VBA에서 비연속적인 범위 영역을 선택할 수도 있습니다. 다음 코드는 A1:A9 및 B11:B18을 선택합니다:

Range("A1:A9, B11:B18").Select

워크시트의 모든 셀 선택하기

VBA를 사용하여 워크시트의 모든 셀을 선택할 수 있습니다. 다음 코드는 워크시트의 모든 셀을 선택합니다.

Cells.Select

행 선택하기

행 개체와 선택하려는 행의 인덱스 번호를 사용하여 워크시트에서 특정 행을 선택할 수 있습니다. 다음 코드는 워크시트의 첫 번째 행을 선택합니다:

Rows(1).Select

열 선택하기

열 개체와 선택하려는 열의 인덱스 번호를 사용하여 워크시트에서 특정 열을 선택할 수 있습니다. 다음 코드는 워크시트에서 C 열을 선택합니다:

Columns(3).Select

열에서 마지막 비어 있지 않은 셀 선택하기

A1, A2, A3 및 A4 셀에 데이터가 있고 열에서 마지막 비어 있지 않은 셀인 A4 셀을 선택하려고 한다고 가정해 보겠습니다. 이 작업을 수행하려면 VBA와 Range.End 메서드를 사용할 수 있습니다.

Range.End 메서드에는 xlToLeft, xlToRight, xlUp 및 xlDown의 네 가지 인수를 사용할 수 있습니다.

다음 코드는 A1이 활성 셀인 경우 마지막 비어 있지 않은 셀(이 경우 A4)을 선택합니다:

Range("A1").End(xlDown).Select

행에서 마지막 비어 있지 않은 셀 선택하기

A1, B1, C1, D1, E1 셀에 데이터가 있고 행에서 마지막 비어 있지 않은 셀인 셀 E1을 선택하려고 한다고 가정해 보겠습니다. 이 작업을 수행하려면 VBA에서 Range.End 메서드를 사용할 수 있습니다.

다음 코드는 A1이 활성 셀인 경우 마지막 비어 있지 않은 셀(이 경우 E1)을 선택합니다:

Range("A1").End(xlToRight).Select

VBA에서 현재 영역 선택하기

범위 개체의 CurrentRegion 속성을 사용하여 지정된 특정 입력 셀 주변의 빈 셀과 비어 있지 않은 셀의 직사각형 범위를 선택할 수 있습니다. A1, B1, C1 셀에 데이터가 있는 경우 다음 코드는 A1 셀을 중심으로 이 영역을 선택합니다:

Range("A1").CurrentRegion.Select

코드의 실행 결과로 A1:C1 범위가 선택됩니다.

상대참조를 이용하여 셀 선택하기

오프셋 속성을 사용하여 다른 셀에 상대적인 셀을 선택할 수 있습니다. 다음 코드는 A1 셀을 기준으로 행 방향으로  1칸, 열 방향으로 1칸 이동한 B2 셀을 선택하는 방법을 보여줍니다:

Range("A1").Offset(1, 1).Select

이름으로 정의된 셀 범위 선택하기

이름으로 정의된 범위도 선택할 수 있습니다. A1:A4 범위의 이름을 “과일”로 지정했다고 가정해 보겠습니다. 다음 코드를 사용하여 이 이름으로 정의된 범위를 선택할 수 있습니다:

Range("과일").Select

다른 워크시트에서 셀 선택하기

다른 워크시트에서 셀을 선택하려면 먼저 Worksheets.Activate 메서드를 사용하여 시트를 활성화해야 합니다. 다음 코드를 사용하면 Sheet5 시트에서 A1셀을 선택할 수 있습니다:

Worksheets("Sheet5").Activate
Range("A1").Select

VBA에서 Selection개체 조작하기

셀 또는 셀 범위를 선택한 후에는 Selection 개체를 참조하여 이러한 셀을 조작할 수 있습니다. 다음 코드는 A1:C1 셀을 선택하고 이 셀의 글꼴을 Arial로, 글꼴 굵기를 굵게, 글꼴 스타일을 이탤릭체로, 채우기 색상을 녹색으로 설정합니다.

Sub FormatSelection()
Range("A1:C1").Select

Selection.Font.Name = "Arial"
Selection.Font.Bold = True
Selection.Font.Italic = True
Selection.Interior.Color = vbGreen

End Sub

결과는 아래와 같습니다:

With…End With 구문 사용하기

위 예제에서 With / End With 문을 사용하여 Selection 개체를 한 번만 참조하도록 할 수 있습니다. 이렇게 하면 타이핑이 절약되고 일반적으로 코드를 더 읽기 쉽게 만들 수 있습니다.

Sub UsingWithEndWithSelection()
Range("A1:C1").Select

With Selection
.Font.Name = "Arial"
.Font.Bold = True
.Font.Italic = True
.Interior.Color = vbGreen
End With

End Sub