XLOOKUP – 여러 시트를 한 번에 – Excel 및 Google 스프레드시트

Written by

Editorial Team

Reviewed by

Steve Rynearson

Translated by

Younjung Kim

Last updated on 8월 30, 2023

이 튜토리얼에서는 Excel의 여러 시트에서 XLOOKUP을 수행하는 방법을 보여드립니다.사용 중인 Excel 버전이 XLOOKUP을 지원하지 않거나 Google 스프레드시트를 사용하는 경우 대신 VLOOKUP을 사용하는 방법을 읽어보세요.

xlookup 인트로

XLOOKUP 함수는 데이터 세트당 한 번만 조회를 수행할 수 있습니다. 서로 다른 시트에 저장된 여러 데이터 집합에서 조회를 수행하려면 XLOOKUP 함수의 네 번째 인수(즉, if_not_found)에 다른 XLOOKUP을 중첩하면 됩니다.

중첩된 XLOOKUP: 찾을 수 없는 경우

일치하는 항목을 찾을 수 없는 경우 XLOOKUP 함수(또는 다른 조회 수식)는 #N/A 오류를 반환하며, 네 번째 인수를 사용하여 오류를 사용자 정의된 값으로 바꿀 수 있습니다.

첫 번째 조회에서 첫 번째 시트에서 일치하는 항목을 찾을 수 없는 경우 사용자 지정 값 대신 다른 XLOOKUP을 중첩하여 다른 시트에서 또 다른 조회를 수행합니다.

XLOOKUP – 한 번에 2개 시트 조회

=XLOOKUP(B3,'부서 A'!$B$3:$B$7,'부서 A'!$C$3:$C$7,XLOOKUP(B3,'부서 B'!$B$3:$B$7,'부서 B'!$C$3:$C$7))

xlookup 2개시트조회

이 수식을 분석하고 시각화해 보겠습니다.

XLOOKUP 함수

다음은 네 번째 인수가 비어 있는 케이스의 첫 번째 시트에 대한 XLOOKUP입니다.

=XLOOKUP(B3,'부서 A'!$B$3:$B$7,'부서 A'!$C$3:$C$7)

xlookup 인수 예제

참고: XLOOKUP 함수에는 조회 값, 조회 배열, 반환 배열 등 최소 3개의 인수가 필요합니다. 기본적으로 XLOOKUP 함수는 조회 배열의 위쪽에서 아래로 내려가는 방식(즉, 하향식)으로 정확히 일치하는 항목을 찾습니다. 일치하는 항목을 찾으면 반환 배열에서 해당 값을 반환합니다. 그렇지 않으면 오류를 반환합니다.

다음은 두 번째 시트에 대한 XLOOKUP입니다.

=XLOOKUP(B3,'부서 B'!$B$3:$B$7,'부서 B'!$C$3:$C$7)

xlookup 부서B

찾을 수 없는 경우 인수

XLOOKUP 함수의 네 번째 인수는 IFNA 함수와 동일한 방식으로 작동합니다. 값이 #N/A 오류인지 확인하고, 참이면 설정한 사용자 지정 값을 반환합니다.

두 번째 시트(예: 부서 B)에 대한 XLOOKUP의 결과는 첫 번째 시트(예: 부서 A)에 대한 조회의 #N/A 오류에 대한 대체 값으로 사용됩니다.

=XLOOKUP(B3,'부서 A'!$B$3:$B$7,'부서 A'!$C$3:$C$7,F3)

xlookup 찾을수없는경우

이 모든 개념을 결합하면 원래 수식이 됩니다.

=XLOOKUP(B3,'부서 A'!$B$3:$B$7,'부서 A'!$C$3:$C$7,XLOOKUP(B3,'부서 B'!$B$3:$B$7,'부서 B'!$C$3:$C$7)))

XLOOKUP – 한 번에 2개 이상의 시트 조회

시트를 더 추가하려면 수식의 마지막 XLOOKUP에 다른 XLOOKUP을 중첩하기만 하면 됩니다. 다음은 시트 3개에 대한 수식입니다.

=XLOOKUP(B3,'부서 A'!$B$3:$B$7,'부서 A'!$C$3:$C$7,XLOOKUP(B3,'부서 B'!$B$3:$B$7,'부서 B'!$C$3:$C$7,XLOOKUP(B3,'부서 C'!$B$3:$B$7,'부서 C'!$C$3:$C$7)))

xlookup 3개시트조회