VLOOKUP – #N/A 오류 처리하기 – Excel 및 Google 스프레드시트
이 튜토리얼에서는 Excel 및 Google 스프레드시트에서 VLOOKUP을 사용할 때 #N/A 오류를 처리하는 방법을 보여드립니다. 사용 중인 Excel 버전이 XLOOKUP을 지원하는 경우 대신 XLOOKUP 함수를 사용하는 것을 추천합니다.
VLOOKUP: #N/A 오류 처리
VLOOKUP 함수는 일치하는 항목을 찾지 못하면 #N/A 오류를 반환합니다. 일치하는 항목을 찾지 못한 경우 #N/A가 아닌 다른 값을 표시하고 싶을 수 있습니다. 이 오류를 사용자가 정의한 값으로 대체하기 위해 사용할 수 있는 함수가 두 가지 있습니다: IFNA와 IFERROR 입니다.
VLOOKUP과 IFNA를 같이 사용하기
이 예제에서는 IFNA 함수를 사용하여 #N/A 오류를 “값을 찾을 수 없음”이라는 텍스트로 대체하겠습니다.
=IFNA(VLOOKUP(E3,B3:C7,2,FALSE),"값을 찾을 수 없음")
위의 수식을 자세히 살펴보겠습니다:
VLOOKUP 함수
VLOOKUP 함수는 조회 값(예: Sub)을 검색하고 일치하는 값을 찾지 못하면 #N/A 오류를 반환합니다.
참고: VLOOKUP 함수는 지정한 범위의 첫 번째 열에서 값을 검색하고 col_index_num으로 정의된 열의 해당 값을 반환합니다.
IFNA 함수
IFNA 함수는 #N/A 오류를 찾습니다. #N/A 오류가 발견되면 지정된 값(예: “값을 찾을 수 없음”)을 반환합니다.
=IFERROR(F3,"값을 찾을 수 없음")
두 함수를 결합하면 원래의 수식이 됩니다:
=IFNA(VLOOKUP(E3,B3:C7,2,FALSE),"값을 찾을 수 없음")텍스트 대신 #N/A 오류를 0과 같은 숫자 값으로 대체할 수도 있습니다:
=IFNA(VLOOKUP(E3,B3:C7,2,FALSE),0)
VLOOKUP과 IFERROR 함께 사용하기
IFNA 함수와 비교하여 IFERROR 함수는 모든 유형의 오류(예: #N/A, #REF!, #VALUE!)를 처리한다는 점만 제외하고 완전히 동일한 방식으로 작동합니다.
=IFERROR(VLOOKUP(E3,B3:C7,2,FALSE),"값을 찾을 수 없음")
IFNA는 #N/A 오류만 대체하므로 더 일반적인 오류를 처리하는 IFERROR 대신 IFNA 함수를 사용하는 것을 추천합니다. IFNA를 사용하면 다른 중요한 오류를 놓치지 않을 수 있습니다.
VLOOKUP: 한 번에 여러 시트 조회
한 번에 여러 시트에서 VLOOKUP을 수행하려는 경우 사용자 지정 값 대신 IFNA/IFERROR 안에 다른 VLOOKUP 함수를 중첩할 수 있습니다.
VLOOKUP과 IFNA 함께 사용하기: 두 시트를 한 번에 조회하기
=IFNA(VLOOKUP(E3,B3:C7,2,FALSE),VLOOKUP(E3,'한 번에 여러 시트 조회 - 데이터2'!B3:C7,2,FALSE))
위의 수식을 자세히 살펴보겠습니다:
VLOOKUP 함수
각 시트에서 VLOOKUP을 수행해야 합니다. 다음 수식은 첫 번째 시트에서 VLOOKUP 함수를 수행합니다:
=VLOOKUP(E3,B3:C7,2,FALSE)
다음 수식은 두 번째 시트에서 VLOOKUP 함수를 수행합니다:
=VLOOKUP(E3,'한 번에 여러 시트 조회 - 데이터2'!B3:C7,2,FALSE)=VLOOKUP(E3,'2 Sheets - Data 2'!B3:C7,2,FALSE)
IFNA 함수
첫 번째 VLOOKUP에서 일치하는 항목을 찾지 못한 경우 IFNA 함수를 사용하여 두 번째 VLOOKUP의 결과를 반환합니다.
=IFNA(F3,G3)
모든 함수를 결합하면 원래 수식이 됩니다:
=IFNA(VLOOKUP(E3,B3:C7,2,FALSE),VLOOKUP(E3,'한 번에 여러 시트 조회 - 데이터2'!B3:C7,2,FALSE))
Google 스프레드시트에서 IFNA/IFERROR를 사용한 VLOOKUP
IFNA-VLOOKUP 및 IFERROR-VLOOKUP은 Excel에서와 마찬가지로 Google 스프레드시트에서도 동일한 방식으로 작동합니다..
=IFNA(VLOOKUP(D2,A2:B6,2,FALSE),"값을 찾을 수 없음")
=IFERROR(VLOOKUP(D2,A2:B6,2,FALSE),"값을 찾을 수 없음")
