SUMPRODUCT IF 수식 – Excel 및 Google 스프레드시트

Written by

Editorial Team

Reviewed by

Steve Rynearson

Translated by

Younjung Kim

Last updated on 8월 6, 2023

이 튜토리얼에서는 기준에 따라 배열 또는 범위의 곱의 합을 반환하는 “sumproduct if”를 계산하는 방법을 보여 줍니다.

sumproduct if 인트로

SUMPRODUCT 함수

SUMPRODUCT 함수는 숫자 배열을 곱하여 결과 배열을 합산하는 데 사용됩니다.

sumproduct if 총수수료

“Sumproduct If”를 만들려면 배열 수식에서 IF 함수와 함께 SUMPRODUCT 함수를 사용합니다.

SUMPRODUCT IF

배열 수식에 SUMPRODUCT와 IF를 결합하면 기본적으로 내장된 SUMIF 함수의 작동 방식과 유사하게 작동하는 “SUMPRODUCT IF”를 만들 수 있습니다. 예제를 살펴보겠습니다.

여러 지역의 매니저별 판매 목록과 해당 수수료율이 있습니다:

sumproduct if 목록

각 매니저의 수수 금액을 다음과 같이 계산해 달라는 요청을 받았다고 가정해 보겠습니다:

sumproduct if 매니저 수수료

이 작업을 수행하기 위해 다음과 같이 SUMPRODUCT 함수 안에 매니저를 기준으로 하는 IF 함수를 중첩할 수 있습니다:

=SUMPRODUCT(IF(<기준 범위>=<기준>,<값 범위1>*<값 범위2>))

=SUMPRODUCT(IF($C$2:$C$10=$G2,$D$2:$D$10*$E$2:$E$10)))

Excel 2019 및 이전 버전을 사용하는 경우, 수식 주위에 중괄호를 넣으려면 CTRL + SHIFT + ENTER를 눌러 수식을 입력해야 합니다.(위쪽 이미지 참조)

수식은 어떻게 작동하나요?

이 공식은 기준 범위의 각 셀을 참 또는 거짓으로 평가하는 방식으로 작동합니다.

Olivia의 총 커미션을 계산해 봅시다:

=SUMPRODUCT(IF($C$2:$C$10=$G2,$D$2:$D$10*$E$2:$E$10))

=SUMPRODUCT (IF({TRUE; TRUE; FALSE; FALSE; FALSE; FALSE; TRUE; FALSE; FALSE}, {928.62; 668.22; 919.695; 447.384; 697.620; 480.564; 689.325; 752.366; 869.61}))

다음으로, IF 함수는 조건이 충족되지 않으면 각 값을 FALSE로 바꿉니다.

= SUMPRODUCT({928.62; 668.22; FALSE; FALSE; FALSE; FALSE; 480.564; FALSE; FALSE; FALSE}))

이제 SUMPRODUCT 함수는 FALSE 값을 건너뛰고 나머지 값을 합산합니다.(2,077.40)

여러 기준이 있는 SUMPRODUCT IF

여러 기준이 있는 SUMPRODUCT IF를 사용하려면(기본 제공 SUMIFS 함수의 작동 방식과 유사), 다음과 같이 SUMPRODUCT 함수에 IF 함수를 더 중첩하면 됩니다:

=SUMPRODUCT(IF(<기준1 범위>=<기준1>, IF(<기준2 범위>=<기준2>, <값 범위1>*<값 범위2>))

=SUMPRODUCT(IF($B$2:$B$10=$G2,IF($C$2:$C$10=$H2,$D$2:$D$10*$E$2:$E$10))))

(CTRL + SHIFT + ENTER) sumproduct if 지역 매니저

SUMPRODUCT IF에 대한 또 다른 접근 방식

Excel에서는 원하는 결과를 도출하는 여러 가지 방법이 있습니다. “sumproduct if”를 계산하는 다른 방법은 다음과 같이 이중 단항을 사용하여 SUMPRODUCT 함수 내에 기준을 배열로 포함하는 것입니다:

sumproduct if 다른접근방식

=SUMPRODUCT(--($B$2:$B$10=$G2),--($C$2:$C$10=$H2),$D$2:$D$10*$E$2:$E$10)

이 메서드는 이중 단항(–)을 사용하여 TRUE FALSE 배열을 0과 1로 변환합니다. 그런 다음 SUMPRODUCT는 변환된 기준 배열을 함께 곱합니다:

=SUMPRODUCT({1;1;0;0;0;0;1;0;0;0},{1;0;1;0;1;0;0;0;0},{928.62; 668.22;919.695; 447.384; 697.620; 480.564; 689.325; 752.366; 869.61})

팁과 요령:

가능하면 항상 범위와 수식 입력을 고정 참조(F4)로 설정하여 자동 채우기를 활용하세요.
Excel 2019 이상을 사용하는 경우 Ctrl + Shift + Enter 키를 누르지 않고 수식을 입력할 수 있습니다.

Google 스프레드시트의SUMPRODUCT IF

배열 수식을 만들 때 CTRL+SHIFT+ENTER 입력 대신 배열 수식 함수를 사용해야 한다는 점을 제외하면 Google 스프레드시트에서 SUMPRODUCT IF 함수는 Excel에서와 똑같이 작동합니다.

sumproduct if 구글 결과