VLOOKUP을 사용하여 조건합계 구하기 – Excel 및 Google 스프레드시트

이 튜토리얼에서는 SUMIFS 함수 내에서 중첩된 VLOOKUP 함수의 결과 값과 일치하는 데이터 행을 합산하는 방법을 보여드립니다.

SUMIFS 함수 내에서 VLOOKUP 함수 사용하기

이 예제는 별도의 참조 테이블에 정의된 지정된 제품명과 일치하는 모든 제품코드의 총 판매량을 합산합니다.

=SUMIFS(F3:F9,E3:E9,VLOOKUP(H3,B3:C9,2,FALSE))

이 예제에서는 판매량 테이블에 제품 코드만 포함되어 있으므로 SUMIFS 함수에서 제품명을 직접 사용할 수 없습니다. 총 판매량을 올바르게 계산하려면 이름을 코드로 변환해야 합니다.

수식을 여러 단계로 나누어서 살펴 보겠습니다.

SUMIFS 함수

제품 코드(“T1”)를 알고 있다면 SUMIFS 함수를 쉽게 사용할 수 있습니다:

=SUMIFS(F3:F9,E3:E9,"T1")

이 수식은 코드 “T1″에 해당하는 판매량을 모두 합산합니다.

VLOOKUP 함수

사용자가 제품 코드로 제품명을 식별하기 어려울 경우 제품명을 사용하도록 수식을 변형할 수 있습니다. VLOOKUP 함수를 사용하여 이름(“테이블”)을 해당 코드로 변경할 수 있습니다:

=VLOOKUP("Table",B3:C9,2,FALSE)

이 수식은 제품 코드 매칭 테이블에서 “테이블”을 찾아 해당 범위의 두 번째 열에 있는 값(“T1”)을 불러옵니다. 정확히 일치하는 항목을 찾고 있음을 나타내기 위해 VLOOKUP 함수에서 4번째 인수를 FALSE로 설정합니다.

SUMIFS 함수 내에서 VLOOKUP 함수 사용하기 – 셀 참조

제품코드별 판매량을 합산하는 방법과 제품명에 대한 제품코드를 조회하는 방법을 살펴보았으므로 두 단계를 단일 수식으로 결합해 보겠습니다.

먼저, VLOOKUP 함수의 “테이블”을 해당 셀 참조(H3)로 바꿔줍니다.

VLOOKUP(H3,B3:C9,2,FALSE)

VLOOKUP의 입력은 “테이블”이고 출력은 “T1″입니다. 기존 SUMIFS 함수의 “T1″을 VLOOKUP 함수로 대체하여 최종 수식을 얻을 수 있습니다:

=SUMIFS(F3:F9,E3:E9,VLOOKUP(H3,B3:C9,2,FALSE))

절대참조 사용하기

수식을 더 쉽게 읽을 수 있도록 절대참조를 사용하지 않고 수식을 표시했습니다:

=SUMIFS(F3:F9,E3:E9,VLOOKUP(H3,B3:C9,2,FALSE))

하지만 이러한 수식은 파일의 다른 곳에 복사하여 붙여넣으면 제대로 작동하지 않습니다. 대신 다음과 같이 잠긴 셀 참조(절대참조)를 사용해야 합니다:

=SUMIFS($F$3:$F$9,$E$3:$E$9,VLOOKUP(H3,$B$3:$C$9,2,FALSE))

자세한 내용은 셀 참조 잠그기 문서를 참조하세요.

Google 스프레드시트에서 VLOOKUP 함수를 이용하여 조건합계 구하기

이 수식은 Excel에서와 마찬가지로 Google 스프레드시트에서도 똑같이 작동합니다.