와일드카드를 사용하여 셀에 특정 텍스트가 포함된 경우 합계 – Excel 및 Google 스프레드시트

Written by

Editorial Team

Reviewed by

Steve Rynearson

Translated by

Younjung Kim

Last updated on 8월 24, 2023

이 튜토리얼에서는 와일드카드와 함께 SUMIFS 함수를 사용하여 Excel 및 Google 스프레드시트에서 특정 텍스트가 포함된 셀에 해당하는 데이터를 합산하는 방법을 보여드립니다.

와일드카드 인트로

특정 텍스트가 포함된 경우 합계

SUMIFS 함수는 특정 기준을 충족하는 데이터 행을 합산합니다. 구문은 다음과 같습니다.

이 예에서는 SUMIFS 함수와 * 와일드카드 문자를 사용하여 “Dakota”가 포함된 주 이름이 있는 모든 점수를 합산합니다.

=SUMIFS(C3:C9,B3:B9,"*Dakota*")

와일드카드 예제

*문자를 사용하면 임의의 수(0 포함)의 다른 문자를 대신할 수 있습니다. 이 예에서는 “Dakota”가 포함된 모든 셀을 찾습니다. 이 검색은 대소문자를 구분하지 않으므로 “dakota”는 “Dakota” 또는 “DAKOTA”와 동일하게 간주됩니다.

텍스트가 다음으로 시작하는 경우 합계

문자를 사용하여 지정된 텍스트로 시작하는 셀을 찾을 수도 있습니다.

=SUMIFS(C3:C9,B3:B9,"New*")

와일드카드 예제 New로 시작

New York, New Jersey, New Mexico는 “New”로 시작하므로 합계에 포함됩니다. “New*” 검색어의 경우 텍스트 셀이 “New”로 시작해야 하며, 단순히 해당 문자가 포함된 것만으로는 충분하지 않다는 점에 유의하세요.

텍스트가 다음으로 끝나는 경우 합산

마찬가지로 이름이 “o”로 끝나는 주의 모든 점수를 합산할 수 있습니다.

=SUMIFS(C3:C9,B3:B9,"*o")

와일드카드 끝나는문구

New Mexico와 Ohio 는 “o”로 끝나므로 합계에 포함됩니다.

와일드카드 ? 문자 사용

? 문자는 텍스트 문자열에서 단일 문자를 나타내는 데 사용할 수 있습니다.

이 예에서는 “New”로 시작하는 모든 주 이름과 그 뒤에 정확히 7자(공백 포함)가 오는 주 이름을 찾습니다.

=SUMIFS(C3:C9,B3:B9,"New???????")

와일드카드 글자수

New Jersey와 New Mexico는 이 기준을 충족하지만, New York은“New” 다음에 오는 문자가 5자밖에 없기 때문에 충족하지 않습니다.

필요한 경우 * 및 ? 와일드카드 문자를 결합하여 매우 구체적인 검색 명령을 만들 수 있습니다. 다음 예에서는 “N”으로 시작하고 문자열의 마지막 문자 앞에 “o”가 포함된 주 이름을 찾습니다. 여기서는 “N”으로 시작하지만 마지막 문자 앞에 “o”가 없는 New Mexico는 제외됩니다.

=SUMIFS(C3:C9,B3:B9,"N*o?*")

와일드카드 N,o포함

이 기능은 각 문자의 위치에 특정 의미가 있는 제품 코드, 우편번호 또는 일련번호를 검색할 때 특히 유용합니다.

~(물결표) 문자 사용

특수 문자 ~( 물결표)를 사용하면 * 또는 ? 문자를 와일드카드로 작동하지 않고 단순한 텍스트 값처럼 취급할 수 있습니다.

아래 예제에서는 제품명이 “제품 ?” 텍스트와 구체적으로 일치하는 경우 재고 수준을 합산해야 합니다.

=SUMIFS(C3:C8,B3:B8,"제품 ~?")

와일드카드 다른기호

문자 바로 앞의 ~는 * 또는 ? 문자를 다시 텍스트 값으로 바꾸므로 검색어 “Product ~?”는 “Product ?”와 정확히 일치하는 텍스트를 찾는 데 사용됩니다.

SUMIFS 와일드카드와 셀 참조 결합하기

일반적으로 수식에 값을 직접 입력 하는 것은 좋은 방법이 아닙니다. 대신 별도의 셀을 사용하여 검색어에 대한 값을 지정하는 것이 더 효율적인 방법입니다.

셀 참조와 * 와일드카드를 사용하여 셀 E3에 포함된 텍스트가 셀에 포함되어 있는지 검색하려면 다음과 같이 SUMIFS 함수를 사용할 수 있습니다.

=SUMIFS(C3:C9,B3:B9,"*"&E3&"*")

와일드카드 sumifs 별표

“Dakota”라는 텍스트가 셀 참조 &E3&로 대체되고 * 문자가 따옴표(” “)로 묶여 있다는 점에 유의하세요.

여러 셀 참조와 와일드카드 문자를 함께 결합할 수도 있습니다. 셀 E3의 텍스트로 시작하고 셀 F3의 텍스트 다음에 최소 1개 이상의 문자가 더 포함된 주 이름을 찾으려면 다음 수식을 사용할 수 있습니다.

=SUMIFS(C3:C9,B3:B9,E3&"*"&F3&"?*")

와일드카드 시작 포함

셀 참조 고정

수식을 더 쉽게 읽을 수 있도록 셀 참조를 고정하지 않은 수식을 표시했습니다.

=SUMIFS(C3:C9,B3:B9,"*"&E3&"*")

그러나 이러한 수식은 파일의 다른 곳에 복사하여 붙여넣을 때 제대로 작동하지 않습니다. 대신 다음과 같이 셀 절대 참조를 사용해야 합니다.

=SUMIFS($C$3:$C$9,$B$3:$B$9,"*"&E3&"*")

자세한 내용은 셀 참조 고정 문서를 참조하세요.

Google 스프레드시트에서 와일드카드를 사용하여 셀에 특정 텍스트가 포함된 경우 합계

이 수식은 Google 스프레드시트에서도 Excel에서와 똑같이 작동합니다.

와일드카드 구글