Median If 수식 – Excel 및 Google 스프레드시트

Written by

Reviewed by

Translated by

Last updated on 9월 10, 2023

이 튜토리얼에서는 Excel 및 Google 스프레드시트에서 특정 기준을 충족하는 중앙값을 계산하는 방법을 보여드립니다.

중앙값 인트로

MEDIAN 함수

MEDIAN 함수는 중앙값을 계산합니다.

=MEDIAN(C2:C10)

중앙값 재고중앙값

그러나 특정 기준을 충족하는 숫자에 대해서만 중앙값을 계산하는 내장된 “Median If” 함수는 없습니다.

참고: 특정 기준을 충족하는 숫자의 평균을 계산하는 AVERAGEIFS 함수에 익숙할 수 있습니다. 중앙값을 대체할 수 있는 함수는 없습니다.

따라서 “Median If”를 계산하려면 MEDIAN 함수 안에 IF 함수가 포함된 배열 수식을 사용해야 합니다.

=MEDIAN(IF($A$2:$A$10=$E2, $C$2:$C$10))

중앙값 median

이 수식을 살펴 보겠습니다.

Office 365 및 2019 이후 버전의 Excel에서는 평소와 같이 위의 수식을 입력하면 됩니다. (Enter 키를 누름)

하지만 Excel 2019 및 이전 버전의 경우 CTRL + SHIFT + ENTER를 눌러 수식을 입력해야 합니다. 이렇게 하면 수식 주위에 중괄호가 나타나는 것을 볼 수 있습니다.

{=MEDIAN(IF($A$2:$A$10=$E2, $C$2:$C$10))}

중앙값 사과 예제

중요: 이 중괄호는 직접 작성하지 마시고, 반드시 CTRL + SHIFT + ENTER 키를 누른 상태에서만 입력해야 합니다.

이 수식을 기억하세요.

{=MEDIAN(IF($A$2:$A$10=$E2, $C$2:$C$10))}

이 수식은 각 값의 기준을 참 또는 거짓으로 평가하는 방식으로 작동합니다.

=MEDIAN(IF({FALSE;TRUE;FALSE;FALSE;TRUE;FALSE;TRUE;TRUE;FALSE},{1287;1205;1243;1482;1261;1042;1090;1748;1909}))

IF 함수는 TRUE를 실제 값으로 대체합니다.

=MEDIAN({FALSE;1205;FALSE;FALSE;1261;FALSE;1090;1748;FALSE})

이제 MEDIAN 함수는 FALSE 값을 무시하고 나머지 값의 중앙값을 계산합니다.(1233은 두 중간 값인 1205와 1261의 평균입니다.)

부울 논리를 사용하여 여러 조건을 기준으로 중앙값을 계산할 수도 있습니다.

위치, 연도 및 재고 열이 있는 새 데이터 집합을 살펴보겠습니다.

중앙값 다중기준

이제 여러 기준에 따라 중앙값을 계산하는 수식은 다음과 같습니다.

=MEDIAN(IF((A2:A4="B")*(B2:B4=2008),C2:C4))

중앙값 최종수식

여기서는 두 기준 집합을 함께 곱합니다.

(A2:A4="b")*(B2:B4=2008)

두 기준이 모두 참이면 참으로 계산되지만, 하나(또는 그 이상)의 기준이 거짓이면 거짓으로 계산됩니다.

위의 모든 예제는 Google 스프레드시트에서 동일하게 작동하지만, 수식이 배열 수식이기 때문에 배열 수식 함수 안에 포함되어야 한다는 점을 제외하고는 동일합니다.

=ARRAYFORMULA(MEDIAN(IF($A$2:$A$10=$E2, $C$2:$C$10))))

중앙값 구글