Excel에서 파일 경로 삽입

이 튜토리얼에서는 Excel에서 수식을 사용하여 경로와 파일 이름을 가져오는 방법을 보여드립니다.

경로 및 파일 이름 가져오기

Excel에는 경로와 파일 이름을 직접 가져오는 함수가 없지만 CELL 함수는 파일 경로, 이름 및 시트를 반환합니다. 텍스트 함수인 FIND, LEFT, SUBSTITUTE를 사용하면 경로와 파일 이름을 분리할 수 있습니다.

=SUBSTITUTE(LEFT(CELL("filename",B2),FIND("]",CELL("filename",B2))-1),"[","")

수식을 단계별로 살펴보겠습니다.

파일 이름, 경로 및 워크시트

정보 유형으로 “filename”을 입력하여 파일 경로, 이름 및 시트를 반환하는 CELL 함수를 사용합니다.

=CELL("filename",B2)

파일 이름 위치 찾기

위와 같이 CELL 함수는 파일 경로, 이름 및 워크시트를 반환합니다. 워크시트나 대괄호는 필요하지 않으므로 FIND 함수를 사용하여 파일 이름의 마지막 문자(즉, “]” 앞의 문자)의 위치를 확인합니다.

=FIND("]",B3)-1

워크시트 이름 제거

파일 이름의 마지막 문자 위치를 찾았으면 LEFT 함수를 사용하여 워크시트의 이름을 제거합니다.

=LEFT(B3,C3)

SUBSTITUTE 함수

위에서 경로와 파일 이름 사이에 여전히 열린 대괄호가 있는 것을 볼 수 있습니다. SUBSTITUTE 함수를 사용하여 “[“를 빈 문자열로 바꿉니다.

=SUBSTITUTE(D3,"[","")

이 단계를 단일 수식으로 결합하면 다음과 같이 됩니다.

=SUBSTITUTE(LEFT(CELL("filename",B2),FIND("]",CELL("filename",B2))-1),"[","")

경로만 가져오기

파일 이름 없이 경로만 표시하고 싶을 수 있습니다. 이를 위해선 LEFT 함수에서 약간의 조정을 하면 됩니다. 삭제할 문자열 중간 문자가 없으므로 SUBSTITUTE를 사용할 필요가 없습니다. 경로만 반환하려면 파일 이름의 마지막 문자 대신 첫 번째 문자(“[“)의 위치를 찾으면 경로 이름은 왼쪽에 있는 모든 문자가 됩니다.

=LEFT(CELL("filename",B2),FIND("[",CELL("filename",B2))-1)