파일 이름 삽입 – Excel 수식

Written by

Reviewed by

Translated by

Last updated on 8월 27, 2023

이 튜토리얼에서는 Excel에서 수식을 사용하여 파일 이름을 가져오는 방법에 대해 설명합니다.

이름삽입 인트로

파일 이름 가져오기

Excel에는 파일 이름을 직접 가져오는 함수가 없습니다. 하지만 CELL 함수는 파일 경로, 이름 및 시트를 반환합니다. 텍스트 함수인 FIND와 MID를 사용하면 파일 이름만 추출할 수 있습니다.

=MID(CELL("filename"),FIND("[",CELL("filename"))+1, FIND("]",CELL("filename"))-
(FIND("[",CELL("filename"))+1))

이름삽입 이름수식

수식을 단계별로 살펴보겠습니다.

정보 유형으로 “filename”을 입력하여 파일 경로, 이름 및 시트를 반환하는 CELL 함수를 사용합니다.

=CELL("filename")

이름삽입 cell함수

위와 같이 CELL 함수는 파일 경로, 이름 및 워크시트를 반환합니다. 경로와 워크시트 이름은 필요하지 않으므로 FIND 함수를 사용하여 파일 이름 바로 앞(“[“) 및 뒤(“]”)에 있는 문자의 위치를 확인합니다.

이 첫 번째 수식은 “[“를 찾습니다. 첫 번째 대괄호(“[“) 뒤에 시작하는 첫 번째 위치에 1을 더합니다.

=FIND("[",CELL("filename"))+1

이름삽입 첫번째위치

다음으로 “]”의 위치를 계산하여 파일 이름이 끝나는 위치를 결정합니다.

=FIND("]",CELL("filename"))

이름삽입 마지막위치

두 위치의 차이를 사용하여 파일 이름의 길이를 찾습니다.

이름삽입 문장길이

이제 파일 이름의 시작 위치와 길이를 알 수 있습니다. 이 결과를 MID 함수에 연결하여 파일 경로, 이름 및 워크시트 문자열에서 파일 이름을 추출합니다.

=MID(B3,C3,E3))

이름삽입 mid함수

이 단계를 하나의 수식으로 결합하면 다음과 같이 됩니다.

=MID(CELL("filename"),FIND("[",CELL("filename"))+1, FIND("]",CELL("filename"))
-(FIND("[",CELL("filename"))+1))

이름삽입 이름수식