Utilisation de la Mise en Forme Conditionnelle en VBA

Mise en forme conditionnelle d’Excel

La mise en forme conditionnelle d’Excel vous permet de définir des règles qui déterminent le formatage des cellules.

Par exemple, vous pouvez créer une règle qui met en évidence les cellules qui répondent à certains critères. Voici quelques exemples :

• Les nombres qui se situent dans une certaine plage de valeurs (ex. : moins de 0).
• Les 10 premiers éléments d’une liste.
• Création d’une « carte thermique ».
• Règles déterminées par des formules pour pratiquement tout formatage conditionnel souhaité.

Dans Excel, la mise en forme conditionnelle se trouve dans le ruban, sous Accueil > Styles (ALT > H > L).

Pour créer votre propre règle, cliquez sur « Nouvelle règle » et une nouvelle fenêtre apparaîtra :

Mise en Forme Conditionnelle en VBA

Toutes ces fonctions de mise en forme conditionnelle sont accessibles en utilisant VBA.

Notez que lorsque vous configurez un formatage conditionnel à partir du code VBA, vos nouveaux paramètres apparaissent dans la fenêtre de formatage conditionnel dans l’interface graphique d’Excel et sont visibles par l’utilisateur. L’utilisateur pourra les modifier ou les supprimer, sauf si vous avez verrouillé la feuille de calcul.

Les règles de formatage conditionnel sont également enregistrées lorsque la feuille de calcul est sauvegardée

Les règles de formatage conditionnel s’appliquent spécifiquement à une feuille de calcul particulière et à une plage de cellules particulière. Si elles sont nécessaires ailleurs dans le classeur, elles doivent également être configurées sur cette feuille de calcul.

Utilisations Pratiques de la Mise en Forme Conditionnelle en VBA

Vous pouvez avoir un grand nombre de données brutes importées dans votre feuille de calcul à partir d’un fichier CSV (valeurs séparées par des virgules), d’une table ou d’une requête de base de données. Ces données peuvent être intégrées dans un tableau de bord ou un rapport, avec des chiffres changeants importés d’une période à l’autre.

Lorsqu’un nombre change et se trouve en dehors d’une fourchette acceptable, vous pouvez vouloir le mettre en évidence, par exemple en colorant la cellule en rouge, ce que vous pouvez faire en configurant un formatage conditionnel. De cette façon, l’utilisateur sera instantanément attiré par ce chiffre et pourra ensuite investiguer davantage pourquoi ce nombre est à l’extérieur de la plage déterminée.

Vous pouvez utiliser VBA pour activer ou désactiver la mise en forme conditionnelle. Vous pouvez utiliser VBA pour effacer les règles d’une plage de cellules ou les réactiver. Il peut arriver qu’un chiffre inhabituel soit parfaitement justifié, mais lorsque l’utilisateur présente le tableau de bord ou le rapport à un niveau de gestion supérieur, il souhaite pouvoir supprimer les « signaux d’alarme ».

De même, sur les données brutes importées, vous pouvez mettre en évidence les chiffres qui sont excessivement grands ou petits. La plage de données importées est généralement de taille différente pour chaque période. Vous pouvez donc utiliser VBA pour évaluer la taille de la nouvelle plage de données et insérer un formatage conditionnel uniquement pour cette plage.

Vous pouvez également vous trouver dans une situation où il existe une liste triée de noms avec des valeurs numériques pour chacun d’eux, par exemple le salaire d’un employé ou les notes d’un examen. Avec la mise en forme conditionnelle, vous pouvez utiliser des couleurs graduées pour aller du plus élevé au plus bas, ce qui est très impressionnant pour la présentation.

Cependant, la liste de noms ne sera pas toujours statique en taille, et vous pouvez utiliser le code VBA pour rafraîchir l’échelle des couleurs graduées en fonction des changements de taille de la plage.

Un Exemple Simple de Création d’un Formatage Conditionnel sur une Plage

Cet exemple met en place un formatage conditionnel pour une plage de cellules (A1:A10) sur une feuille de calcul. Si le nombre dans la plage est compris entre 100 et 150, la couleur de fond de la cellule sera rouge, sinon elle n’aura pas de couleur.

Sub ExempleFormatageConditionnel()

'Définition de la plage
Dim MaPlage As Range
Set MaPlage = Range("A1:A10")

'Supprime le formatage conditionnel existant dans cette plage
MaPlage.FormatConditions.Delete

'Applique le nouveau formatage conditionnel souhaité
MaPlage.FormatConditions.Add Type:=xlCellValue, Operator:=xlBetween, _
        Formula1:="=100", Formula2:="=150"
MaPlage.FormatConditions(1).Interior.Color = RGB(255, 0, 0)
End Sub

Remarquez que nous définissons d’abord la plage MyRange pour appliquer la mise en forme conditionnelle.

Ensuite, nous supprimons tout formatage conditionnel existant pour la plage. C’est une bonne idée pour éviter que la même règle soit ajoutée à chaque fois que le code est exécuté (bien sûr, cela ne sera pas approprié dans toutes les circonstances).

Les couleurs sont données par des valeurs numériques. Il est bon d’utiliser la notation RVB (rouge, vert, bleu ou « RGB » en anglais) pour cela. Vous pouvez utiliser les constantes de couleur standard, par exemple vbRed, vbBlue, mais vous êtes limité à huit choix de couleurs.

Il y a plus de 16,7 millions de couleurs disponibles, et en utilisant la notation RVB, vous pouvez accéder à toutes ces possibilités. C’est beaucoup plus facile que d’essayer de se rappeler quel numéro va avec quelle couleur. Chacun des trois numéros de couleur RVB est compris entre 0 et 255.

Notez que le paramètre « xlBetween » est inclusif, de sorte que les valeurs de cellule de 100 ou 150 satisfont à la condition.

Mise en Forme Multi-Conditionnelle

Vous souhaiterez peut-être définir plusieurs règles conditionnelles dans votre plage de données afin que toutes les valeurs d’une plage soient couvertes par différentes conditions :

Sub ExempleFormatageConditionnelMultiple()

'Création de l'objet Range
Dim MaPlage As Range
Set MaPlage = Range("A1:A10")

'Supprime le formatage conditionnel existant dans cette plage
MaPlage.FormatConditions.Delete

'Création de la première règle
MaPlage.FormatConditions.Add Type:=xlCellValue, Operator:=xlBetween, _
        Formula1:="=100", Formula2:="=150"
MaPlage.FormatConditions(1).Interior.Color = RGB(255, 0, 0)

'Création de la deuxième règle
MaPlage.FormatConditions.Add Type:=xlCellValue, Operator:=xlLess, _
        Formula1:="=100"
MaPlage.FormatConditions(2).Interior.Color = vbBlue

'Création de la troisième règle
MaPlage.FormatConditions.Add Type:=xlCellValue, Operator:=xlGreater, _
        Formula1:="=150"
MaPlage.FormatConditions(3).Interior.Color = vbYellow

End Sub

Cet exemple configure la première règle comme précédemment, avec une couleur de cellule rouge si la valeur de la cellule est comprise entre 100 et 150.

Deux autres règles sont ensuite ajoutées. Si la valeur de la cellule est inférieure à 100, la couleur de la cellule est bleue, et si elle est supérieure à 150, la couleur de la cellule est jaune.

Dans cet exemple, vous devez vous assurer que toutes les possibilités de nombres sont couvertes et que les règles ne se chevauchent pas.

Si des cellules vides se trouvent dans cette plage, elles apparaîtront en bleu, car Excel considère toujours qu’elles ont une valeur inférieure à 100.

Le moyen de contourner ce problème est d’ajouter une autre condition sous forme d’expression. Celle-ci doit être ajoutée comme première règle de condition dans le code. Il est très important, lorsqu’il y a plusieurs règles, de respecter l’ordre d’exécution, sinon les résultats peuvent être imprévisibles.

Sub ExempleFormatageConditionnelMultiple4()

'Création de l'objet Range
Dim MaPlage As Range
Set MaPlage = Range("A1:A10")

'Supprime le formatage conditionnel existant dans cette plage
MaPlage.FormatConditions.Delete

'Création de la première règle
MaPlage.FormatConditions.Add Type:=xlExpression, Formula1:= _
        "=NBCAR(SUPPRESPACE(A1))=0"
MaPlage.FormatConditions(1).Interior.Pattern = xlNone

'Création de la deuxième règle
MaPlage.FormatConditions.Add Type:=xlCellValue, Operator:=xlBetween, _
        Formula1:="=100", Formula2:="=150"
MaPlage.FormatConditions(2).Interior.Color = RGB(255, 0, 0)

'Création de la troisième règle
MaPlage.FormatConditions.Add Type:=xlCellValue, Operator:=xlLess, _
        Formula1:="=100"
MaPlage.FormatConditions(3).Interior.Color = vbBlue

'Création de la quatrième règle
MaPlage.FormatConditions.Add Type:=xlCellValue, Operator:=xlGreater, _
        Formula1:="=150"
MaPlage.FormatConditions(4).Interior.Color = RGB(0, 255, 0)

End Sub

Cette méthode utilise le type de xlExpression, puis une formule Excel standard pour déterminer si une cellule est vide au lieu d’une valeur numérique.

L’objet FormatConditions fait partie de l’objet Range. Cet objet se comporte de la même manière qu’une collection dont l’index commence à 1. Vous pouvez itérer dans cet objet en utilisant une boucle For…Next ou For…Each.

Suppression d’une Règle

Parfois, il peut être nécessaire de supprimer une règle individuelle dans un ensemble de règles multiples si elle ne répond pas aux exigences des données.

Sub SuppressionRegleFormatageCondtionnel()

'Création de l'objet Range
Dim MaPlage As Range
Set MaPlage = Range("A1:A10")

'Supprime le formatage conditionnel existant dans cette plage
MaPlage.FormatConditions.Delete

'Ajoute une règle
MaPlage.FormatConditions.Add Type:=xlCellValue, Operator:=xlBetween, _
        Formula1:="=100", Formula2:="=150"
        MaPlage.FormatConditions(1).Interior.Color = RGB(255, 0, 0)

'Supprime la règle 1
MaPlage.FormatConditions(1).Delete

End Sub

Ce code crée une nouvelle règle pour la plage A1:A10, puis la supprime. Vous devez utiliser le bon numéro d’index pour la suppression, donc vérifiez dans ‘Gérer les Règles’ dans l’interface graphique d’Excel (cela montrera les règles dans l’ordre d’exécution) pour vous assurer que vous obtenez le bon numéro d’index. Notez qu’il n’y a pas de fonction d’annulation dans Excel si vous supprimez une règle de formatage conditionnel en utilisant VBA, contrairement à si vous le faites par le biais de l’interface graphique.

Modification d’une Règle

Comme les règles sont une collection d’objets basés sur une plage spécifiée, vous pouvez facilement apporter des modifications à des règles particulières à l’aide de VBA. Une fois que la règle a été ajoutée, les propriétés réelles sont en lecture seule, mais vous pouvez utiliser la méthode Modify pour les modifier. Les propriétés telles que les couleurs sont en lecture/écriture.

Sub ExempleModificationFormatageConditionnel()

'Création de l'objet Range
Dim MaPlage As Range
Set MaPlage = Range("A1:A10")

'Supprime le formatage conditionnel existant dans cette plage
MaPlage.FormatConditions.Delete

'Ajoute une règle
MaPlage.FormatConditions.Add Type:=xlCellValue, Operator:=xlBetween, _
        Formula1:="=100", Formula2:="=150"
        MaPlage.FormatConditions(1).Interior.Color = RGB(255, 0, 0)

'Modifie la règle
MaPlage.FormatConditions(1).Modify xlCellValue, xlLess, "10"

'Modifie la couleur associé à la règle
MaPlage.FormatConditions(1).Interior.Color = vbGreen

End Sub

Ce code crée un objet de plage (A1:A10) et ajoute une règle pour les nombres compris entre 100 et 150. Si la condition est vraie, la couleur de la cellule devient rouge. Le code modifie ensuite la règle pour les nombres inférieurs à 10. Si la condition est vraie, la couleur de la cellule devient verte.

Utilisation d’un Schéma de Couleurs Graduées

La mise en forme conditionnelle d’Excel permet d’utiliser des gradients de couleurs sur une plage de chiffres en ordre croissant ou décroissant.

C’est très utile lorsque vous disposez de données telles que les chiffres de vente par zone géographique, les températures des villes ou les distances entre les villes. En utilisant VBA, vous avez l’avantage supplémentaire de pouvoir choisir votre propre schéma de couleurs graduées, plutôt que les schémas standard proposés par l’interface graphique.

Sub GradientCouleurs()

'Création de l'objet Range
Dim MaPlage As Range
Set MaPlage = Range("A1:A10")

'Supprime le formatage conditionnel existant dans cette plage
MaPlage.FormatConditions.Delete

'Définition du type d'échelle de couleur
 MaPlage.FormatConditions.AddColorScale ColorScaleType:=3
 
'Définition de la couleur associée à la valeur inférieure de la plage
 MaPlage.FormatConditions(1).ColorScaleCriteria(1).Type = _
     xlConditionValueLowestValue
 With MaPlage.FormatConditions(1).ColorScaleCriteria(1).FormatColor
     .Color = 7039480
 End With
 
'Définition de la couleur associée à la valeur centrale de la plage
 MaPlage.FormatConditions(1).ColorScaleCriteria(2).Type = _
     xlConditionValuePercentile
 MaPlage.FormatConditions(1).ColorScaleCriteria(2).Value = 50
 
 With MaPlage.FormatConditions(1).ColorScaleCriteria(2).FormatColor
     .Color = 8711167
 End With
 
'Définition de la couleur associée à la valeur supérieure de la plage
 MaPlage.FormatConditions(1).ColorScaleCriteria(3).Type = _
     xlConditionValueHighestValue
 With MaPlage.FormatConditions(1).ColorScaleCriteria(3).FormatColor
     .Color = 8109667
 End With
    
End Sub

Lorsque ce code est exécuté, il gradue les couleurs des cellules en fonction des valeurs ascendantes de la plage A1:A10.

Il s’agit d’une façon très impressionnante d’afficher les données et qui attirera certainement l’attention des utilisateurs.

Formatage Conditionnel pour les Valeurs d’Erreur

Lorsque vous disposez d’une grande quantité de données, vous pouvez facilement manquer une valeur erronée dans vos différentes feuilles de calcul. Si cette erreur est présentée à un utilisateur sans être résolue, elle peut entraîner de gros problèmes et l’utilisateur peut perdre confiance quant aux chiffres qui lui sont présentés. Cette méthode utilise une règle de type xlExpression et la fonction Excel ESTERREUR pour évaluer la cellule.

Vous pouvez créer du code pour que toutes les cellules contenant des erreurs aient une couleur de cellule rouge :

Sub ExempleFormatageConditionnelErreur()

'Création de l'objet Range
Dim MaPlage As Range
Set MaPlage = Range("A1:A10")

'Supprime le formatage conditionnel existant dans cette plage
MaPlage.FormatConditions.Delete

'Ajouter une règle d'erreur
MaPlage.FormatConditions.Add Type:=xlExpression, Formula1:="=ESTERREUR(A1)=VRAI"

'Défini la couleur intérieure en rouge
MaPlage.FormatConditions(1).Interior.Color = RGB(255, 0, 0)

End Sub

Notez que la formule doit être écrite en francais dans VBA dans ce cas particulier car la formule utilisée est une fonction de cellule Excel. On y fait référence par une simple chaine de caractères dans VBA en utilisant xlExpression. Si Excel est configuré en Anglais sur votre ordinateur, la formule « IsError » doit plutôt être employée.

Formatage Conditionnel des Dates du Passé

Il se peut que vous ayez importé des données pour lesquelles vous souhaitez mettre en évidence des dates qui se situent dans le passé. Il peut s’agir, par exemple, d’un rapport sur les débiteurs dans lequel vous souhaitez faire ressortir les dates de facture datant de plus de 30 jours.

Ce code utilise le type de règle xlExpression et une fonction Excel pour évaluer les dates.

Sub ExempleFormatageConditionnelDatesPassées()

'Création de l'objet Range
Dim MaPlage As Range
Set MaPlage = Range("A1:A10")

'Supprime le formatage conditionnel existant dans cette plage
MaPlage.FormatConditions.Delete

'Ajoute une règle pour les dates passées de plus de 30 jours
MaPlage.FormatConditions.Add Type:=xlExpression, Formula1:="=AUJOURDHUI()-A1 > 30"

'Associe la couleur Rouge à la règle précédente
MaPlage.FormatConditions(1).Interior.Color = RGB(255, 0, 0)

End Sub

Ce code prend les dates dans la plage A1:A10, et définit la couleur de la cellule en rouge pour toute date dépassant 30 jours dans le passé.

La formule utilisée dans la condition, AUJOURDHUI() (« Now() » en anglais) donne la date et l’heure actuelle. Cette formule sera recalculée à chaque fois que la feuille de calcul sera recalculée, de sorte que le formatage changera d’un jour à l’autre.

Utilisation des Barres de Données dans la Mise en Forme Conditionnelle de VBA

Vous pouvez utiliser VBA pour ajouter des barres de données à une plage de chiffres. Ces barres ressemblent à des mini graphiques et donnent un aperçu instantané de la taille des chiffres les uns par rapport aux autres. En acceptant des valeurs par défaut pour les barres de données, le code est très facile à écrire.

Sub ExempleFormatageBarreDonnées()

'Création de l'objet Range
Dim MaPlage As Range
Set MaPlage = Range("A1:A10")

' Ajout des barres de données
MaPlage.FormatConditions.Delete
MaPlage.FormatConditions.AddDatabar

End Sub

Vos données ressembleront à ceci sur la feuille de calcul :

Utilisation des Icônes dans le Formatage Conditionnel de VBA

Vous pouvez utiliser la mise en forme conditionnelle pour placer des icônes à côté de vos chiffres dans une feuille de calcul. Ces icônes peuvent être des flèches, des cercles ou d’autres formes. Dans cet exemple, le code ajoute des icônes en forme de flèche aux nombres en fonction de leurs valeurs en pourcentage :

Sub ExempleAjoutsIcones()

'Création de l'objet Range
Dim MaPlage As Range
Set MaPlage = Range("A1:A10")

'Supprime le formatage conditionnel existant dans cette plage
MaPlage.FormatConditions.Delete

'Ajoute une collection d'icones au formatage conditionnel
MaPlage.FormatConditions.AddIconSetCondition

'Associe la collection d'icones de flèche à la condition 1
With MaPlage.FormatConditions(1)
    .IconSet = ActiveWorkbook.IconSets(xl3Arrows)
End With

'Défini le critère de pourcentage requis pour la condition 2
With MaPlage.FormatConditions(1).IconCriteria(2)
    .Type = xlConditionValuePercent
    .Value = 33
    .Operator = xlGreaterEqual
End With

'Défini le critère de pourcentage requis pour la condition 3
With MaPlage.FormatConditions(1).IconCriteria(3)
    .Type = xlConditionValuePercent
    .Value = 67
    .Operator = xlGreaterEqual
End With

End Sub

Cela donnera une vue instantanée montrant si un nombre est élevé ou faible. Après avoir exécuté ce code, votre feuille de calcul ressemblera à ceci :

Utilisation de la Mise en Forme Conditionnelle pour Mettre en Évidence les Cinq Premières Réponses

Vous pouvez utiliser le code VBA pour mettre en évidence les 5 premiers chiffres d’une plage de données. Vous utilisez un paramètre appelé « AddTop10 », mais vous pouvez ajuster le numéro de rang dans le code à 5. Un utilisateur peut souhaiter voir les chiffres les plus élevés d’une plage sans avoir à trier les données au préalable.

Sub ExempleTop5()

'Création de l'objet Range
Dim MaPlage As Range
Set MaPlage = Range("A1:A10")

'Supprime le formatage conditionnel existant dans cette plage
MaPlage.FormatConditions.Delete

'Ajout d'une condition "Top10"
MaPlage.FormatConditions.AddTop10
With MaPlage.FormatConditions(1)
    'Définition de la propriété "Top to Bottom"
    .TopBottom = xlTop10Top
    'Défini le top 5 seulement
    .Rank = 5
End With
With MaPlage.FormatConditions(1).Font
    'Sélection de la couleur de police
    .Color = -16383844
End With
With MaPlage.FormatConditions(1).Interior
    'Sélection de la couleur de cellule
    .Color = 13551615
End With
    
End Sub

Les données de votre feuille de calcul ressembleront à ceci après l’exécution du code :

Notez que la valeur 145 apparaît deux fois et que six cellules sont mises en évidence.

Signification des Paramètres « StopIfTrue » et « SetFirstPriority »

StopIfTrue correspond à l’option « Interrompre si vrai » dans l’interface graphique. Ce paramètre est important si une plage de cellules est soumise à plusieurs règles de formatage conditionnel. Une cellule de la plage peut satisfaire à la première règle, mais aussi aux règles suivantes. En tant que développeur, vous pouvez souhaiter que le formatage ne s’affiche que pour la première règle à laquelle il correspond. Les autres critères de règle peuvent se chevaucher et entraîner des modifications involontaires si vous laissez l’exécution conditions continuer à descendre dans la liste des règles.

La valeur par défaut de ce paramètre est True, mais vous pouvez la modifier si vous souhaitez que toutes les autres règles de cette cellule soient prises en compte :

MaPlage.FormatConditions(1).StopIfTrue = False

Le paramètre SetFirstPriority indique si la règle de condition sera évaluée en premier lorsqu’il existe plusieurs règles pour cette cellule.

MaPlage.FormatConditions(1).SetFirstPriority

Cette opération déplace la position de cette règle à la position 1 dans la collection de conditions de format, et toutes les autres règles seront déplacées vers le bas avec des numéros d’index modifiés. Faites attention si vous apportez des modifications aux règles dans le code en utilisant les numéros d’index. Vous devez vous assurer que vous modifiez ou supprimez la bonne règle. Vous pouvez modifier la priorité d’une règle :

MaGamme.FormatConditions(1).Priority=3

Cela modifiera la position relative de toutes les autres règles dans la liste des formats conditionnels.

Utilisation du Formatage Conditionnel Faisant Référence à d’Autres Valeurs de Cellules

C’est une chose que le formatage conditionnel standard d’Excel ne peut pas faire avec autant de flexibilité. Cependant, vous pouvez créer votre propre code VBA pour créer une inifinité de possiblité de formatage.

Supposons que vous disposiez d’une colonne de données et que la cellule adjacente à chaque chiffre contienne du texte indiquant le formatage à appliquer à chaque chiffre.

Le code suivant parcourt votre liste de chiffres, recherche le texte de formatage dans la cellule adjacente, puis formate le chiffre comme il se doit :

Sub RéférerÀUneAutreCellulePourLeFormatage()

'Création de variables qui vont contenir le nombre de lignes à traiter
Dim NbLignes As Long, N As Long

'Récupère le nombre de lignes dans la plage utilisée de la feuille active
NbLignes = ActiveSheet.UsedRange.Rows.Count

'Itère pour chaque ligne dans la plage utilisée
For N = 1 To NbLignes

    ' Utilisation d'une structure "Select Case" pour évaluer le formatage basé sur la colonne 2
    Select Case ActiveSheet.Cells(N, 2).Value
        'Définition de la couleur de cellule en bleu
        Case "Bleu"
        ActiveSheet.Cells(N, 1).Interior.Color = vbBlue
        'Définition de la couleur de cellule en rouge
        Case "Rouge"
        ActiveSheet.Cells(N, 1).Interior.Color = vbRed
        'Définition de la couleur de cellule en vert
        Case "Vert"
        ActiveSheet.Cells(N, 1).Interior.Color = vbGreen
    End Select
    
Next N

End Sub

Une fois ce code exécuté, votre feuille de calcul ressemblera désormais à ceci :

Les cellules auxquelles le code fait référence pour le formatage peuvent se trouver n’importe où sur la feuille de calcul, ou même sur une autre feuille de calcul du classeur. Vous pouvez utiliser n’importe quelle forme de texte pour créer une condition de mise en forme, et votre imagination est la seule limite aux utilisations que vous pouvez accomplir en utilisant ce type code.

Opérateurs Pouvant Être Utilisés dans les Déclarations de Formatage Conditionnel

Comme vous l’avez vu dans les exemples précédents, les opérateurs sont utilisés pour déterminer comment les valeurs de la condition seront évaluées, par exemple xlBetween.

Plusieurs opérateurs peuvent être utilisés, en fonction de la manière dont vous souhaitez spécifier les critères de votre règle.

Nom	Valeur	Description
xlBetween	1	Entre. Ne peut être utilisé que si deux formules sont fournies.
xlEqual	3	Egal.
xlGreater	5	Supérieur à.
xlGreaterEqual	7	Supérieur ou égal à.
xlLess	6	Inférieur à.
xlLessEqual	8	Inférieur ou égal à.
xlNotBetween	2	Pas entre. Ne peut être utilisé que si deux formules sont fournies.
xlNotEqual	4	Pas égal.