Somme Si Non-Vide – Excel et Google Sheets

Ce tutoriel montre comment utiliser la fonction SOMME.SI.ENS pour additionner des données liées à des cellules non vides dans Excel et Google Sheets.

Additionner Si les Cellules ne Sont pas Vides

Tout d’abord, nous allons montrer comment additionner les données relatives aux cellules non vides.

Nous pouvons utiliser la fonction SOMME.SI.ENS pour additionner tous les pointages des joueurs dont le nom n’est pas vide en utilisant le critère (« <> »).

=SOMME.SI.ENS(C3:C8;B3:B8;"<>")

Traiter les Espaces Comme des Cellules Vides – Avec une Colonne d’Aide

Vous devez être prudent lorsque vous interagissez avec des cellules vides dans Excel. Les cellules peuvent vous sembler vides, mais Excel ne les traitera pas comme telles. Cela peut se produire si la cellule contient des espaces, des sauts de ligne ou d’autres caractères invisibles. Il s’agit d’un problème courant lors de l’importation de données dans Excel à partir d’autres sources.

Si nous devons traiter les cellules qui ne contiennent que des espaces de la même manière que si elles étaient vides, la formule de l’exemple précédent ne fonctionnera pas. Remarquez que la formule SOMME.SI.ENS ne considère pas la cellule B9 ci-dessous ( » « ) comme étant vide :

=SOMME.SI.ENS(D3:D9;B3:B9;"<>")

Pour traiter une cellule ne contenant que des espaces comme s’il s’agissait d’une cellule vide, nous pouvons ajouter une colonne d’aide en utilisant les fonctions NBCAR et SUPPRESPACE.

La fonction SUPPRESAPCE supprime les espaces supplémentaires de la cellule.

La fonction NBCAR compte le nombre de caractères restants. Si le compte est égal à 0, la cellule « rognée » est vide.

=NBCAR(SUPPRESPACE(B3))

Utilisez maintenant la fonction SOMME.SI.ENS pour faire la somme si le nombre est > 0.

=SOMME.SI.ENS(E3:E9;D3:D9;">0")

La colonne d’aide est facile à créer et à lire, mais vous souhaiterez peut-être avoir une seule formule pour accomplir la tâche. Cette question est abordée dans la section suivante.

Traiter les Espaces Comme des Cellules Vides – Sans Colonne d’Aide

Pour accomplir tout cela avec une seule formule, nous pouvons utiliser la fonction SOMMEPROD en combinaison avec les fonctions NBCAR et SUPPRESPACE.

=SOMMEPROD(--(NBCAR(SUPPRESPACE(B3:B9))>0);D3:D9)

Parcourons la formule. Tout d’abord, la fonction SOMMEPROD lit les valeurs des cellules :

=SOMMEPROD(--(NBCAR(SUPPRESPACE({"A"; "B"; ""; "C"; ""; "XX"; ""}))>0);{25; 10; 15; 5; 8; 17; 50})

Ensuite, la fonction SUPPRESPACE supprime les espaces de début et de fin des noms de joueurs :

=SOMMEPROD(--(NBCAR({"A"; "B"; ""; "C"; ""; "XX"; ""})>0);{25; 10; 15; 5; 8; 17; 50})

La fonction NBCAR calcule la longueur des noms de joueurs coupés :

=SOMMEPROD(--({1; 1; 0; 1; 0; 2; 0}>0);{25; 10; 15; 5; 8; 17; 50})

Avec le test logique (>0), tous les noms de joueurs rognés comportant plus de 0 caractères sont transformés en VRAI :

=SOMMEPROD(--({VRAI; VRAI; FAUX; VRAI; FAUX; VRAI; FAUX});{25; 10; 15; ; 8; 17; 50})

Ensuite, les doubles tirets (–) convertissent les valeurs VRAI et FAUX en 1 et 0 :

=SOMMEPROD({1; 1; 0; 1; 0; 1; 0};{25; 10; 15; 5; 8; 17; 50})

La fonction SOMMEPROD multiplie ensuite chaque paire d’entrées dans les tableaux pour produire un tableau de pointages uniquement pour les noms de joueurs qui ne sont pas vides ou qui ne sont pas composés uniquement d’espaces :

=SOMMEPROD({25; 10; 0; 5; 0; 17; 0})

Enfin, les nombres dans le tableau sont additionnés ensemble

=57

Pour plus de détails sur l’utilisation des instructions booléennes et de la commande « — » dans une fonction SOMMEPROD, cliquez ici

Somme Si Non Vide dans Google Sheets

Ces formules fonctionnent exactement de la même manière dans Google Sheets et dans Excel.