SIERREUR (ET SI.NON.DISP) RECHERCHEX

Ce tutoriel montre comment gérer les erreurs #N/A de la fonction RECHERCHEX dans Excel. Si votre version d’Excel ne supporte pas les RECHERCHEX, lisez comment gérer les erreurs RECHERCHEV à la place.

RECHERCHEX : #N/A Traitement des Erreurs

Contrairement à RECHERCHEV, RECHERCHEX a l’option intégrée de traiter les erreurs #N/A. En entrant une valeur dans le 4^ème argument, la fonction RECHERCHEX remplacera une erreur #N/A par la valeur spécifiée.

Dans cet exemple, nous remplaçons l’erreur #N/A par le texte « Valeur Introuvable ».

=RECHERCHEX(E3;B3:B7;C3:C7;"Valeur Introuvable")

Ou nous pouvons aussi le mettre à 0 :

=RECHERCHEX(E3;B3:B7;C3:C7;0)

Remarque : la fonction RECHERCHEX requiert au moins trois arguments : la valeur de la recherche, le tableau de recherche et le tableau de retour. Par défaut, la fonction RECHERCHEX recherche une correspondance exacte en partant du haut du tableau de recherche vers le bas (c’est-à-dire de haut en bas). Lorsqu’elle trouve une correspondance, elle renvoie la valeur correspondante dans le tableau de retour. Sinon, elle renvoie une erreur.

RECHERCHEX Imbriquée : 2 Feuilles à la Fois

Au lieu d’une valeur personnalisée, nous pouvons imbriquer une autre RECHERCHEX dans le 4^e argument de la fonction RECHERCHEX pour effectuer une recherche parmi plusieurs ensembles de données stockés dans des feuilles différentes.

=RECHERCHEX(E3;B3:B7;C3:C7;RECHERCHEX(E3;'2 Feuilles - Données 2'!B3:B7;'2 Feuilles - Données 2'!C3:C7)

RECHERCHEX ET SIERREUR

Pour les calculs arithmétiques impliquant une RECHERCHEX, nous pouvons utiliser la fonction SIERREUR pour traiter tous les types d’erreur.

=SIERREUR(1,5*RECHERCHEX(E3;B3:B7;C3:C7);"Valeur Introuvable")

Le traitement d’erreur #N/A de la fonction RECHERCHEX ne fonctionnera pas dans le scénario ci-dessus :

=1,5*RECHERCHEX(F3;C3:C7;D3:D7;"Valeur Introuvable")