RECHERCHEX Renvoie 0? Renvoyer un Blanc à la Place – Excel
Télécharger le Classeur Exemple
Ce tutoriel montre comment retourner un blanc au lieu d’un zéro lors de l’utilisation de la fonction RECHERCHEX. Si votre version d’Excel ne prend pas en charge la fonction RECHERCHEX, lisez comment utiliser la fonction RECHERCHEV à la place.
Dans Excel, lorsque vous faites référence à une autre cellule avec une formule, les valeurs vides sont calculées comme zéro.
C’est également le cas lorsque vous recherchez des valeurs avec RECHERCHEV ou RECHERCHEX :
=RECHERCHEX("2021-D";B3:B7;C3:C7)
Cela peut être très problématique dans certains scénarios.
RECHERCHEX avec SI et ESTVIDE
Afin de renvoyer une valeur vide au lieu de zéro, nous pouvons ajouter les fonctions SI et ESTVIDE à une formule :
=SI(ESTVIDE(RECHERCHEX(E3;B3:B7;C3:C7));"";RECHERCHEX(E3;B3:B7;C3:C7))
Passons en revue la formule :
Fonction RECHERCHEX
Tout d’abord, nous avons notre fonction RECHERCHEX originale :
=RECHERCHEX("2021-D";B3:B7;C3:C7)
Fonction ESTVIDE
Ensuite, nous pouvons utiliser ESTVIDE pour vérifier si le résultat de la fonction RECHERCHEX est vide.
=ESTVIDE(RECHERCHEX(E3;B3:B7;C3:C7))
Notes :
- La fonction ESTVIDE renvoie VRAI si une valeur est vide. Les chaînes vides (« ») et 0 ne sont pas équivalentes à un blanc. Une cellule contenant une formule n’est pas vide, et c’est pourquoi nous ne pouvons pas utiliser F3 comme entrée pour la fonction ESTVIDE.
- Les formules peuvent renvoyer des blancs, mais ils sont convertis en zéro à l’étape finale du calcul.
- Par conséquent, nous pouvons imbriquer des formules dans ESTVIDE pour vérifier si leurs résultats sont des blancs plutôt que d’affecter les formules aux cellules avant d’appliquer ESTVIDE aux cellules.
Fonction SI
Nous pouvons ensuite utiliser la fonction SI pour tester si la combinaison de ESTVIDE et RECHERCHEX est VRAIE ou FAUSSE. Nous pouvons définir un processus (par exemple, sortir une chaîne vide) si la condition est VRAIE et un autre (par exemple, le résultat du RECHERCHEX s’il n’est pas vide) si le résultat est FAUX.
=SI(G3;"";F3)
En combinant tous ces concepts, on obtient notre formule originale :
=SI(ESTVIDE(RECHERCHEX(E3;B3:B7;C3:C7));"";RECHERCHEX(E3;B3:B7;C3:C7))RECHERCHEX avec SI et Chaîne Vide (« »)
Nous pouvons utiliser la chaîne vide comme critère pour vérifier si la valeur du RECHERCHEX est vide au lieu d’utiliser la fonction ESTVIDE :
=SI(RECHERCHEX(E3;B3:B7;C3:C7)="";"";RECHERCHEX(E3;B3:B7;C3:C7))
Note : un blanc peut être équivalent à zéro ou à une chaîne vide selon le calcul, mais les chaînes vides et les 0 ne sont pas des blancs.
RECHERCHEX avec SI et NBCAR
Une autre alternative à ESTVIDE est l’utilisation de la fonction NBCAR:
=SI(NBCAR(RECHERCHEX(E3;B3:B7;C3:C7))=0;"";RECHERCHEX(E3;B3:B7;C3:C7))
Examinons de plus près cette solution alternative :
Vérifier Si le Champ est Vide en Utilisant NBCAR
Nous pouvons utiliser la fonction NBCAR pour compter le nombre de caractères de la sortie du RECHERCHEX :
=NBCAR(RECHERCHEX(E3;B3:B7;C3:C7))
Si le nombre de caractères est égal à 0; cela signifie que la valeur est vide. Nous pouvons alors utiliser la fonction SI pour vérifier si la fonction NBCAR est égale à 0; et renvoyer une chaîne vide si c’est le cas :
=SI(G3=0;"";F3)
En combinant tous ces concepts, on obtient notre formule originale :
=SI(NBCAR(RECHERCHEX(E3;B3:B7;C3:C7))=0;"";RECHERCHEX(E3;B3:B7;C3:C7))Notez que les formules ci-dessus ne sont applicables que si la sortie est vide, ce qui est différent d’un résultat « pas de correspondance ». Si RECHERCHEX ne trouve pas de correspondance, il retournera l’erreur #N/A à la place, et dans ce cas, nous devons gérer l’erreur #N/A ; veuillez consulter l’article : « RECHERCHEX – Corriger l’erreur #NA »
