Ce tutoriel montre comment rechercher des valeurs min/max dans Excel et Google Sheets.

INDEX-MATCH avec MIN

Nous pouvons utiliser la combinaison de INDEX, EQUIV et MIN pour rechercher le nombre le plus bas.

=INDEX(B3:B7;EQUIV(MIN(C3:C7);C3:C7;0))

Passons en revue la formule :

Fonction MIN

La fonction MIN renvoie le plus petit nombre d’une liste. Elle ignore les valeurs non numériques (par exemple, les cellules vides, les chaînes de texte ou les valeurs booléennes).

=MIN(C3:C7)

Fonction EQUIV

Ensuite, le résultat de la fonction MIN est entré comme valeur de recherche pour la fonction EQUIV afin de trouver la position ou la coordonnée de la valeur la plus basse de la liste.

=EQUIV(E3;C3:C7;0)

Remarque : nous avons défini le troisième argument( type ) de la fonction EQUIV sur 0, ce qui signifie qu’on souhaite obtenir une correspondance exacte.

Fonction INDEX

La coordonnée de sortie de la fonction EQUIV est ensuite transmise à la fonction INDEX pour extraire la valeur correspondante de la liste qui nous intéresse (par exemple, B3:B7).

=INDEX(B3:B7;F3)

Remarque : si le premier argument (c’est-à-dire le tableau) de la fonction INDEX est une liste à une seule dimension, le deuxième argument (c’est-à-dire le numéro de ligne) peut devenir la coordonnée de la ligne ou de la colonne en fonction de la disposition de la liste (horizontale ou verticale). S’il s’agit d’une liste verticale, il devient la coordonnée de ligne, et s’il s’agit d’une liste horizontale, il s’agit de la coordonnée de colonne.

Globalement, la fonction MIN extrait la valeur la plus basse, la fonction MATCH recherche la valeur la plus basse et renvoie sa position et la fonction INDEX extrait la valeur correspondante de la liste qui nous intéresse. En combinant toutes ces fonctions en une seule formule, on obtient notre formule originale :

=INDEX(B3:B7;EQUIV(MIN(C3:C7);C3:C7;0))

RECHERCHEV Avec MIN

Nous pouvons également utiliser la fonction RECHERCHEV au lieu de la formule INDEX-EQUIV comme formule de consultation, mais nous devons modifier la structure de notre tableau en faisant de la colonne de consultation (par exemple, le revenu total) la première colonne.

Comme pour la formule INDEX-EQUIV, nous allons saisir la fonction MIN comme valeur de recherche dans la fonction RECHERCHEV.

=RECHERCHEV(MIN(B3:B7);B3:C7;2;FAUX)

Remarque : La fonction RECHERCHEV recherche la valeur de référence dans la première colonne du tableau et renvoie la valeur correspondante dans la colonne définie par l’index de la colonne (c’est-à-dire le troisième argument).

RECHERCHEX Avec MIN

Une autre alternative pour la formule de consultation est la fonction RECHERCHEX, qui est la solution la plus pratique, mais qui nécessite une version plus récente d’Excel. Cette solution nécessite le plus petit nombre de fonctions et il n’est pas nécessaire de restructurer les données.

Nous pouvons imbriquer la fonction MIN dans la fonction RECHERCHEX pour rechercher la valeur la plus basse.

=RECHERCHEX(MIN(C3:C7);C3:C7;B3:B7)

Remarque : par défaut, la fonction RECHERCHEX recherche une correspondance exacte en partant du haut du tableau de recherche (2^e argument) vers le bas (c’est-à-dire de haut en bas). Lorsqu’elle trouve une correspondance, elle renvoie la valeur correspondante dans le tableau de retour (3^e argument). Sinon, elle renvoie une erreur.

Comme nous l’avons vu précédemment, la structure des solutions est la même. Par conséquent, nous utiliserons l’une des formules de recherche (c’est-à-dire RECHERCHEX) dans les sections suivantes.

RECHERCHEX Avec PETITE.VALEUR

Si vous souhaitez rechercher la 2ème ou 3ème plus petite valeur, vous pouvez utiliser la fonction SMALL. Dans l’exemple ci-dessous, nous allons utiliser la fonction PETITE.VALEUR pour extraire la plus petite valeur.

=RECHERCHEX(PETITE.VALEUR(C3:C7;1);C3:C7;B3:B7)

 

Passons en revue la formule :

Fonction PETITE.VALEUR

Nous pouvons retourner la valeur la plus basse en donnant la valeur 1 au 2^ème argument de la fonction PETITE.VALEUR, ce qui signifie la 1^ère entrée lorsque la liste est en ordre croissant.

=PETITE.VALEUR(C3:C7;1)

Remarque : nous pourrions utiliser 2 pour le deuxième plus petit ou 3 pour le troisième plus petit.

Ensuite, le résultat de la fonction PETITE.VALEUR sera la valeur de référence de notre formule de recherche, qui dans ce cas est la fonction RECHERCHEX:

En combinant les deux fonctions, on obtient notre formule originale :

=RECHERCHEX(PETITE.VALEUR(C3:C7;1);C3:C7;B3:B7)

Recherche de la Valeur la Plus Élevée

Nous pouvons également trouver la valeur la plus élevée en utilisant les opposés de MIN et SMALL : la fonction MAX et la fonction LARGE, respectivement.

RECHERCHEX Avec MAX

Nous pouvons imbriquer la fonction MAX comme valeur de recherche dans la fonction RECHERCHEX afin de rechercher la valeur la plus élevée.

=RECHERCHEX(MAX(C3:C7);C3:C7;B3:B7)

Passons en revue la formule :

Fonction MAX

Nous avons besoin de la fonction MAX pour retourner la plus grande valeur de la liste.

Le résultat de la fonction MAX est ensuite transmis à la fonction RECHERCHEX, qui extrait la valeur qui nous intéresse :

En combinant les deux, nous obtenons notre formule originale :

=RECHERCHEX(MAX(C3:C7);C3:C7;B3:B7)

RECHERCHEX Avec GRANDE.VALEUR

L’alternative à la fonction MAX est la fonction GRANDE.VALEUR. La fonction GRANDE.VALEUR renvoie le nième plus grand nombre d’ une liste. Dans cet exemple, nous allons retourner le plus grand.

=RECHERCHEX(GRANDE.VALEUR(C3:C7;1);C3:C7;B3:B7)

Décomposons et visualisons la formule :

Fonction GRANDE.VALEUR

En donnant la valeur 1 au deuxième argument de la fonction GRANDE.VALEUR, nous pouvons extraire la plus grande valeur de la liste.

Le résultat de la fonction GRANDE.VALEUR est ensuite utilisé comme valeur de recherche dans le RECHERCHEX :

En combinant les deux fonctions, on obtient notre formule originale :

=RECHERCHEX(GRANDE.VALEUR(C3:C7;1);C3:C7;B3:B7)

Recherche de la Nième Valeur la Plus Basse/ La Plus Haute

RECHERCHEX Avec PETITE.VALEUR Nième Valeur la Plus Basse

Nous pouvons changer le 2^ème argument de la fonction PETITE.VALEUR pour qu’il soit supérieur à 1 afin de trouver la Nième valeur la plus basse de la liste.

=RECHERCHEX(PETITE.VALEUR(C3:C7;2);C3:C7;B3:B7)

RECHERCHEX Avec GRANDE.VALEUR Nième Valeur la Plus Grande

Nous pouvons également faire la même chose pour la Nième plus grande valeur en utilisant la fonction GRANDE.VALEUR.

=RECHERCHEX(GRANDE.VALEUR(C3:C7;2);C3:C7;B3:B7)

Recherche Min/Max Conditionnelle

Dans les scénarios compliqués où il existe des critères pour extraire la valeur min/max, nous pouvons utiliser les variantes SI de MIN et MAX : MIN.SI.ENS et MAX.SI.ENS.

RECHERCHEX Avec MIN.SI.ENS

Les critères utilisés dans les MIN.SI.ENS doivent également être appliqués comme critères « ET » dans le processus de recherche.

=RECHERCHEX(MIN.SI.ENS(D3:D7;C3:C7;"A")&"A";D3:D7&C3:C7;B3:B7)

 

Passons en revue la formule :

Fonction MIN.SI.ENS

La fonction MIN.SI.ENS renvoie le plus petit nombre qui répond aux critères donnés (par exemple, le département).

Remarque : La fonction MIN.SI.ENS requiert au moins trois arguments : plage_min (1^er argument), plage_critères1 (2^ème argument) et le critères1 (3^ème argument). Les autres arguments sont facultatifs s’il y a plus d’un ensemble de plage de critères et de critères. Une propriété importante de la fonction MIN.SI.ENS est que les arguments de plage (c’est-à-dire plage_min, plage_critères) doivent être des plages de cellules et ne peuvent pas être des constantes de tableau (par exemple, {1;2;3}) ou des sorties de tableau d’autres fonctions (par exemple, SEQUENCE(3)).

Recherche « ET » Critères

En fait, nous devons rechercher la plus petite valeur qui satisfait à nos critères. Cela signifie également que notre processus de recherche doit également satisfaire les critères. Par conséquent, notre scénario devient une recherche avec plusieurs critères (par exemple, le revenu total et le département), où tous les critères doivent être satisfaits (ce qui correspond à l’opérateur logique « ET »).

La façon la plus courante d’appliquer l’opérateur ET est de concaténer les critères à l’aide du symbole « & », qui assemble deux valeurs en un seul texte. Nous devons également concaténer les listes dans lesquelles les valeurs de recherche seront recherchées.

=G3&"A"

Les critères concaténés deviennent la nouvelle valeur de recherche (par exemple, H3) et les listes concaténées deviennent le nouveau tableau de recherche (par exemple, E3:E7).

=RECHERCHEX(H3;E3:E7;B3:B7)

En combinant tout cela, on obtient notre formule originale :

=RECHERCHEX(MIN.SI.ENS(D3:D7;C3:C7;"A")&"A";D3:D7&C3:C7;B3:B7)

RECHERCHEX Avec MAX.SI.ENS

Nous appliquons également les mêmes concepts que dans la section précédente (c’est-à-dire RECHERCHEX avec MIX.SI.ENS) pour rechercher la valeur la plus élevée qui répond aux critères donnés.

=RECHERCHEX(MAX.SI.ENS(D3:D7;C3:C7;"A")&"A";D3:D7&C3:C7;B3:B7)

Remarque : la fonction MAX.SI.ENS fonctionne de la même manière que la fonction MIN.SI.ENS.

Recherche des Valeurs Min/Max dans Google Sheets

Les formules fonctionnent de la même manière dans Google Sheets, sauf que la fonction RECHERCHEX n’existe pas dans Google Sheets.