Formule Médiane Si – Excel et Google Sheets

Ce tutoriel montre comment calculer la valeur médiane qui répond à certains critères dans Excel et Google Sheets.

 

Fonction MEDIANE

La fonction MEDIANE calcule la valeur médiane d’une plage de valeur.

=MEDIANE(C2:C10)

Cependant, il n’existe pas de fonction intégrée « Mediane Si » permettant de calculer la valeur médiane uniquement pour les nombres qui répondent à certains critères.

Remarque : vous connaissez peut-être la fonction MOYENNE.SI.ENS qui calcule la moyenne des nombres répondant à certains critères. Il n’existe pas d’alternative équivalente au calcul de la médiane.

Médiane Si – Formule de Tableau

Ainsi, pour calculer une formule « Médiane Si », nous devons utiliser une formule de tableau avec la fonction SI dans la fonction MEDIANE :

=MEDIANE(SI($A$2:$A$10=$E2; $C$2:$C$10))

Examinons cette formule…

Excel 2019 et Versions Antérieures

Dans Office 365 et les versions d’Excel postérieures à 2019, vous pouvez simplement entrer la formule ci-dessus comme vous le feriez normalement (en appuyant sur ENTRÉE).

Cependant, pour Excel 2019 et les versions antérieures, vous devez entrer la formule en appuyant sur CTRL + MAJ + ENTRÉE. Après avoir fait cela, vous remarquerez que des crochets apparaissent autour de la formule :

{=MEDIANE(SI($A$2:$A$10=$E2; $C$2:$C$10))}

Important : n’écrivez pas ces accolades vous-même, elles seront saisies automatiquement lorsque vous confirmez la formule avec CTRL + MAJ + ENTRÉE.

Comment Fonctionne cette Formule ?

Rappelez-vous qu’il s’agit de notre formule :

=MEDIANE(SI($A$2:$A$10=$E2; $C$2:$C$10))

La formule fonctionne en évaluant les critères de chaque valeur comme VRAI ou FAUX.

=MEDIANE(SI({FAUX;VRAI;FAUX;FAUX;VRAI;FAUX;VRAI;VRAI;FAUX}; {1287;1205;1243;1482;1261;1042;1090;1748;1909}))

La fonction SI remplace VRAI par les valeurs réelles.

=MEDIANE({FAUX;1205;FAUX;FAUX;1261;FAUX;1090;1748;FAUX})

Maintenant, la fonction MEDIANE ignore les valeurs FAUX et calcule la médiane des valeurs restantes (1233 est la moyenne des deux valeurs intermédiaires : 1205 et 1261).

Fonction Médiane Si – Critères Multiples

Vous pouvez également calculer une médiane sur la base de plusieurs critères en utilisant la logique booléenne.

Prenons un nouvel ensemble de données avec les colonnes Emplacement, Année et Inventaire :

Voici maintenant la formule pour calculer la médiane en fonction de plusieurs critères :

=MEDIANE(SI((A2:A4="B")*(B2:B4=2008);C2:C4))

Remarquez que nous multiplions ici deux ensembles de critères ensemble :

(A2:A4="B")*(B2:B4=2008)

Si les deux critères sont VRAIS, le calcul sera VRAI, mais si un (ou plusieurs) critère(s) est (sont) FAUX, le calcul sera FAUX.

Formule Médiane Si dans Google Sheets

Tous les exemples ci-dessus fonctionnent de la même manière dans Google Sheets, sauf que votre formule doit être contenue dans la fonction ARRAYFORMULA (car il s’agit d’une formule de tableau).

=ARRAYFORMULA(MEDIAN(SI($A$2:$A$10=$E2, $C$2:$C$10)))