Combinaison des Fonctions RECHERCHEV et EQUIV – Excel et Google Sheets

Ce tutoriel montre comment extraire des données de plusieurs colonnes à l’aide des fonctions EQUIV et RECHERCHEV dans Excel et Google Sheets.

 

Pourquoi combiner RECHERCHEV et EQUIV?

Traditionnellement, lorsque vous utilisez la fonction RECHERCHEV, vous saisissez un numéro d’index de colonne pour déterminer la colonne dans laquelle extraire les données. Cela présente deux problèmes :

• Si vous souhaitez extraire des valeurs de plusieurs colonnes, vous devez saisir manuellement le numéro d’index de chaque colonne
• Si vous insérez ou supprimez des colonnes, votre numéro d’index de colonne ne sera plus valide.

Pour rendre votre fonction RECHERCHEV dynamique, vous pouvez trouver le numéro d’index de colonne avec la fonction EQUIV.

=RECHERCHEV(G3;B3:E5;EQUIV(H2;B2:E2;0);FAUX)

Voyons comment cette formule fonctionne.

Fonction EQUIV

La fonction EQUIV renvoie le numéro d’index de colonne de l’en-tête de colonne souhaité.

Dans l’exemple ci-dessous, le numéro d’index de la colonne « Age » est calculé par la fonction EQUIV :

=EQUIV("Âge"; B2:E2; 0)

« Age » est le 2ème en-tête de colonne, donc 2 est retourné.

Remarque : Le dernier argument de la fonction EQUIV doit être défini sur 0 pour effectuer une correspondance exacte.

Fonction RECHERCHEV

Maintenant, vous pouvez simplement insérer le résultat de la fonction EQUIV dans votre fonction RECHERCHEV :

=RECHERCHEV(G3;B3:E5;H3;FAUX)

En remplaçant l’argument de l’indice de colonne par la fonction EQUIV, nous obtenons notre formule originale :

=RECHERCHEV(G3;B3:E5;EQUIV(H2;B2:E2;0);FAUX)

Insertion et Suppression de Colonnes

Désormais, lorsque vous insérez ou supprimez des colonnes dans la plage de données, le résultat de votre formule ne change pas.

Dans l’exemple ci-dessus, nous avons ajouté la colonne Professeur à la plage, mais nous voulons toujours connaître l’âge de l’élève. Le résultat de la fonction EQUIV indique que « Age » est maintenant le troisième élément de la plage d’en-tête, et la fonction RECHERCHEV utilise 3 comme index de colonne.

Verrouillage des Références de Cellule

Pour faciliter la lecture de nos formules, nous avons présenté les formules sans les références de cellule verrouillées :

=RECHERCHEV(G3;B3:E5;EQUIV(H2;B2:E2;0);FAUX)

Mais ces formules ne fonctionneront pas correctement lorsqu’elles seront copiées et collées ailleurs dans votre fichier. Vous devez plutôt utiliser des références de cellules verrouillées comme ceci :

=RECHERCHEV($G3;$B$3:$E$5;EQUIV(H$2;$B$2:$E$2;0);FAUX)

Lisez notre article sur le verrouillage des références de cellule pour en savoir plus.

Combinaison de RECHERCHEV et EQUIV dans Google Sheets

Ces formules fonctionnent exactement de la même manière dans Google Sheets que dans Excel.