Comment Calculer les Heures Travaillées – Excel et Google Sheets

Ce tutoriel montre comment calculer les heures travaillées dans Excel et Google Sheets.

Calculer les Heures avec une Formule Simple

Dans Excel, les heures sont stockées sous forme de valeurs décimales. Sachant cela, vous pouvez simplement soustraire l’heure de début de l’heure de fin pour trouver le nombre d’heures travaillées. (Remarque : nous multiplions par 24 pour convertir les valeurs décimales en heures).

=(D3-C3)*24

Dans l’exemple précédent, nous avons affiché les heures sous forme de valeurs décimales pour montrer comment elles sont stockées. Pour ce faire, nous avons changé le formatage en « Nombre ») :

 

Fonction MOD

Si l’heure de fin est antérieure à l’heure de début (ex. équipe de nuit), la formule renverra un nombre négatif. Pour résoudre ce problème, utilisez la fonction MOD.

=MOD(D3-C3,1)*24

Comme pour la formule simple, nous devons multiplier la valeur calculée par la fonction MOD par 24 pour obtenir les heures travaillées.

Calcul des Heures Supplémentaires

Nous pouvons utiliser le même type de formule pour calculer les heures supplémentaires.

Dans l’exemple ci-dessus, l’horaire standard est de 8 heures.

La formule suivante permet de calculer le temps normal travaillé dans la journée.

=SI((D3-C3)*24>$H$13;$H$13;(D3-C3)*24)

Si l’employé a travaillé plus de 8 heures, la formule ne retournera qu’un maximum de 8 heures.

Pour calculer les heures supplémentaires, nous pouvons obtenir le reste des heures travaillées en utilisant la formule ci-dessous :

=SI((D3-C3)*24>$H$13;((D3-C3)*24)-$H$13;0)

Calculer les Heures Travaillées dans une Feuille de Temps Hebdomadaire

Nous pouvons utiliser les fonctions SI, SOMME et MAX pour calculer les heures travaillées dans une semaine, réparties entre les heures normales et les heures supplémentaires.

 

Calculer les Heures Supplémentaires

Les heures supplémentaires sont calculées dès qu’une personne travaille plus de 40 heures par semaine.

=SI(SOMME($E$4:E4)>40;SOMME($E$4:E4)-40;0)

La première partie de la première plage de la fonction SOMME est un absolu, tandis que la deuxième partie ne l’est pas. En copiant cette formule vers le bas du tableau, vous remarquerez que la fonction SOMME additionne toutes les heures travaillées de la colonne E. Plus la plage SOMME est étendue, plus le nombre d’heures travaillées augmente. Une fois que la SOMME dépasse 40 heures, les heures supplémentaires sont ajoutées dans la colonne Heures supplémentaires, comme un total croissant.

Calcul des Heures Normales

Les heures normales sont calculées sur la base du total des heures et des heures supplémentaires effectuées.

=MAX(E4-G4;0)

Nous utilisons la fonction MAX pour ne pas nous retrouver avec des heures négatives lorsque l’employé a effectué des heures supplémentaires, car si le résultat est négatif, la fonction MAX renvoie un zéro.

Calculer les Heures Travaillées dans une Feuille de Temps Hebdomadaire par Projet

En poussant le calcul ci-dessus un peu plus loin, nous pouvons diviser les heures travaillées par le projet sur lequel l’employé a travaillé en utilisant la fonction SOMME.SI

=SOMME.SI($H$4:$H$10;H4;$F$4:$F$10)

La fonction SOMME.SI additionne les heures régulières de la colonne F en fonction des critères sélectionnés dans la colonne H – dans le cas de la formule ci-dessus, elle recherche le projet ABC et additionne les heures régulières pour ce projet.

 

Calcul des Heures Travaillées dans Google Sheets

Tous les exemples Excel ci-dessus fonctionnent de la même manière dans Google Sheets.