Mise en Forme Conditionnelle Basée sur le Résultat de RECHERCHEV – Excel et Google Sheets
Ce tutoriel présente plusieurs exemples de mise en forme conditionnelle basée sur le résultat d’une fonction RECHERCHEV dans Excel et Google Sheets. Si votre version d’Excel prend en charge RECHERCHEX, nous vous recommandons d’utiliser RECHERCHEX à la place.
Examinons un exemple dans lequel nous souhaitons appliquer une mise en forme conditionnelle basée sur le résultat d’une fonction RECHERCHEV.
Mise en Forme Basée sur la comparaison RECHERCHEV
Tout d’abord, nous allons appliquer une mise en forme conditionnelle au tableau des noms et des identifiants des étudiants (colonnes E-F) en examinant les notes de chaque étudiant (colonnes B-C) et en appliquant une couleur de remplissage de cellule ROUGE si leurs notes sont inférieures à 72/100. Le résultat est illustré ici, mais nous allons passer en revue les étapes ci-dessous.
=RECHERCHEV($F3;$B$3:$C$7;2;FAUX)<72
Voyons comment appliquer la formule ci-dessus dans la mise en forme conditionnelle.
Appliquer la mise en forme conditionnelle
- Sélectionnez la plage où la mise en forme conditionnelle sera appliquée.
- Dans le ruban, allez dans l’onglet Accueil > Styles > Mise en forme conditionnelle > Nouvelle règle.
- Dans le menu contextuel, sélectionnez le type de règle : Utiliser une formule pour déterminer pour quelles cellules le format sera appliqué.
- Dans la barre de formule, saisissez notre formule.
- Cliquez sur Format et définissez vos paramètres de mise en forme. Dans notre cas, nous choisirons une couleur de remplissage ROUGE. Cliquez sur OK.
- Cliquez maintenant sur OK et la règle de mise en forme conditionnelle est appliquée.
Maintenant que nous savons comment appliquer une mise en forme conditionnelle, examinons la formule.
Il peut être utile de commencer par saisir votre (vos) formule(s) de mise en forme conditionnelle dans les cellules pour vérifier qu’elle(s) fonctionne(nt) comme vous le souhaitez. C’est ce que nous allons faire ci-dessous.
Fonction RECHERCHEV
Tout d’abord, nous effectuons notre RECHERCHEV.
=RECHERCHEV($F3;$B$3:$C$7;2;FAUX)
Nous utilisons le symbole $ pour verrouiller les références des cellules. Ceci est essentiel pour créer une formule qui fonctionnera pour toutes les lignes.
Comparaison Logique
Ensuite, les résultats sont comparés au critère défini.
=H3<72
La mise en forme conditionnelle modifie la couleur de la cellule pour toutes les lignes contenant VRAI.
En combinant toutes les formules, on obtient la formule RECHERCHEV suivante :
=RECHERCHEV($F3;$B$3:$C$7;2;FAUX)<72Mise en Forme si RECHERCHEV est Vide
Dans l’exemple précédent, un étudiant n’a pas obtenu de note. Nous pouvons détecter et mettre en surbrillance ces cellules en ajoutant la fonction ESTVIDE :
=ESTVIDE(RECHERCHEV($F3;$B$3:$C$7;2;FAUX)) 
Voici comment la formule sera évaluée :
Mise en Forme si la Fonction RECHERCHEV est Comprise dans la Plage de Valeurs
Un autre scénario courant avec RECHERCHEV consiste à vérifier si la valeur est comprise dans une plage de valeurs donnée.
Pour ce faire, nous pouvons utiliser la fonction ET avec RECHERCHEV :
=ET(RECHERCHEV($F3;$B$3:$C$7;2;FAUX)>=72,RECHERCHEV($F3;$B$3:$C$7;2;FAUX)<=74)
Examinons la formule :
Limite inférieure
Tout d’abord, nous vérifions si le résultat de notre RECHERCHEV est supérieur ou égal à une limite inférieure donnée (par exemple, 72).
=H3>=72
Limite supérieure
Ensuite, nous vérifions si cette même valeur est inférieure ou égale à la limite supérieure (par exemple, 74).
=H3<=74
Fonction ET
Enfin, nous utilisons la fonction ET pour vérifier si les deux conditions sont VRAIES.
=ET(I3,J3)
En combinant les formules ci-dessus, nous obtenons notre formule originale :
=ET(RECHERCHEV($F3;$B$3:$C$7;2;FAUX)>=72,RECHERCHEV($F3;$B$3:$C$7;2;FAUX)<=74)Mise en Forme Conditionnelle – Conditions RECHERCHEV Multiples
Vous pouvez facilement ajouter plusieurs règles de mise en forme conditionnelle :
Les règles de mise en forme conditionnelle sont appliquées dans l’ordre (de haut en bas). Si la case Interrompre si vrai est cochée, si cette condition est remplie, aucune autre règle de mise en forme n’est testée ou appliquée.
Dans notre exemple particulier, le RECHERCHEV vide (par exemple, ligne 6) répond à deux conditions, rouge (par exemple, <72) et orange (par exemple, ESTVIDE). Comme la règle ESTVIDE est appliquée en premier et que la case Interrompre si vrai est cochée, la ligne 6 est surlignée en orange parce que la condition ESTVIDE est remplie et que les règles suivantes ne sont pas testées.
Mise en Forme Conditionnelle Basée sur le Résultat RECHERCHEV dans Google Sheets
Toutes les formules présentées ci-dessus fonctionnent de la même manière dans Google Sheets, sauf si la table de recherche se trouve dans une autre feuille. Dans ce cas, nous devons utiliser une plage nommée ou la fonction INDIRECT afin de référencer des plages d’autres feuilles dans la mise en forme conditionnelle.
=ESTVIDE(RECHERCHEV($C3;INDIRECT("Notes!B3:C7");2;FAUX))Voici les étapes à suivre pour appliquer la mise en forme conditionnelle dans Google Sheets :
- Sélectionnez la plage, puis allez dans l’onglet Format > Mise en forme conditionnelle
- Dans la barre latérale, allez dans Règles de mise en forme conditionnelle et sélectionnez La formule personnalisée est
- Saisissez notre formule dans la barre de formule, définissez le style de mise en forme et cliquez sur OK :
