Enviar Correo Electrónico Desde Excel con una Fórmula (¡Sin Macros!)

Este tutorial demuestra cómo enviar un correo electrónico desde Excel con una fórmula (no se necesitan macros).

 

En Excel, puedes enviar un correo electrónico ejecutando una macro, pero si prefieres no usar VBA, sigue leyendo.

Crear una Fórmula de Hipervínculo

En Excel, es posible hacer clic en una celda y enviar un correo electrónico automáticamente. Esto se puede hacer con una fórmula utilizando la función HIPERVINCULO. Puedes crear una fórmula de hipervínculo que utilice el comando mailto y rellene automáticamente campos como To(para), Subject(asunto), cc y el Body(cuerpo) de un correo electrónico.

=HIPERVINCULO("mailto:"&C3&"?"&"subject="&SI(D3=1;$I$3;SI(D3=2;$I$4;$I$5))&"&cc=abclimited@abc.com"&"&body="&SI(D3=1;$J$3;SI(D3=2;$J$4;$J$5))&" "&$J$7;"Enviar Email")

 

La fórmula HIPERVINCULO se compone de las siguientes partes

Ubicación del Vínculo

Ubicación_del_vínculo es la primera parte de la fórmula. Este ejemplo establece el mailto, el asunto y el cuerpo.

Mail To

La parte «mailto:» de la fórmula establece el destinatario del correo electrónico. Tiene que ser una dirección de correo electrónico válida introducida en la fórmula – o, en este ejemplo – vinculada a una celda (C3) que contenga una dirección de correo electrónico válida.

"mailto:"&C3

Subject (Asunto)

El «?subject=» puede tener texto entre el signo de igual y las comillas, estar vinculado a una celda o contener una fórmula. En este ejemplo, hay una fórmula para comprobar el estado de un pedido. Si el estado es 1, utiliza «Gracias por su pedido» de la celda I3.

Para ello, utiliza la siguiente sentencia SI para la parte del asunto de la fórmula.

"subject="&SI(D3=1;$I$3;SI(D3=2;$I$4;$I$5))

Ten en cuenta que tiene que haber un símbolo ? antes de la palabra «subject»

CC

Si quiere añadir una cc a su correo electrónico, insértela en la fórmula después del asunto entre comillas. Necesita un ampersand(&) antes de la «cc». Puedes escribir la dirección de correo electrónico para hacer una copia del mismo, o puedes vincularla a una celda externa como con el asunto y el cuerpo del correo electrónico.

"&cc=abclimited@abc.com"

Body (Cuerpo)

La parte «&body=» de la fórmula puede contener texto adicional antes de la comilla de cierre. También puede crear una sentencia SI personalizada con una fórmula:

"&body="&SI(D3=1;$J$3;SI(D3=2;$J$4;$J$5))&" "&$J$7

Esta sentencia SI mira el estado del pedido, y luego añade un mensaje al final del cuerpo del correo electrónico(¡Un gusto hacer negocios con usted!).

Al igual que con la cc, necesita un ampersand(&) antes de la palabra «body» El mensaje al final (en la celda J7) contiene el texto:

"%0A%0AUn gusto hacer negocios con usted! %0A %0A Saludos cordiales%0A ABC Limited"

donde el «%0A » añade líneas en blanco. El texto del correo electrónico se muestra de la siguiente manera:

 

 

Nota: En la fórmula, las celdas que hacen referencia a las columnas de búsqueda (para el asunto y el cuerpo del texto) se han puesto en las fórmulas como direcciones de celdas absolutas (o «bloqueadas»). Esto le permite copiar la fórmula al resto de los registros del pedido.

Nombre Descriptivo

La parte final de la fórmula es lo que se muestra en la celda hipervinculada en Excel – es el texto sobre el que se hace clic para crear el correo electrónico. En este ejemplo se utiliza el texto «Enviar correo electrónico», pero se puede introducir cualquier texto, siempre que esté entre comillas.

Vea la fórmula en el Cuadro de diálogo de la función haciendo clic en la fórmula y, a continuación, en el cuadro Insertar función de la barra de fórmulas.

La Ubicación_del_vínculo y el Nombre_descriptivo aparecen en los argumentos de la función.

Por lo tanto, la fórmula:

=HIPERVINCULO("mailto:"&C3&"?"&"subject="&SI(D3=1;$I$3;SI(D3=2;$I$4;$I$5))&"&cc=abclimited@abc.com"&"&body="&SI(D3=1;$J$3;SI(D3=2;$J$4;$J$5))&" "&$J$7;"Enviar Email")

produce este correo electrónico:

 

Copiar la Fórmula Hacia Abajo

Dado que la fórmula utiliza direcciones de celdas absolutas para referirse a las celdas de «búsqueda» de asunto y cuerpo, sólo necesita escribir la fórmula completa una vez. Luego, copie la primera celda hacia abajo en el resto de las filas de su rango.

Haga clic en cualquiera de los hipervínculos «Enviar correo electrónico» para enviar un correo electrónico personalizado al cliente.