UNIRCADENAS SI – Excel y Google Sheets

Este tutorial demostrará cómo concatenar los valores de las celdas basándose en criterios utilizando la función TEXTJOIN en Excel y Google Sheets.

 

La Función UNIRCADENAS

Los usuarios de Excel 2019+ tienen acceso a la Función UNIRCADENAS, que fusiona varias cadenas de texto, separando cada cadena con un delimitador especificado.

Nota: Los usuarios de Google Sheets pueden utilizar la Función TEXTJOIN (UNIRCADENAS), pero tienen una forma ligeramente diferente de introducir fórmulas de matriz. Ver la sección posterior sobre este tema.

Este ejemplo utilizará las funciones UNIRCADENAS y SI en una fórmula de matriz para crear una cadena de texto separada por comas de Nombres de Jugadores que se relacionan con un valor de Equipo de Rojo

{=UNIRCADENAS(", ";VERDADERO;(SI(C3:C8="Red";B3:B8;"")))}

Los usuarios de Excel 2019 tendrán que introducir esta fórmula como una función de matriz pulsando CTRL + SHIFT + ENTER. Los usuarios de versiones posteriores de Excel no necesitan seguir este paso.

Para explicar lo que hace esta fórmula, vamos a dividirla en pasos:

Esta es nuestra fórmula final:

=UNIRCADENAS(", ";VERDADERO;(SI(C3:C8="Red";B3:B8;"")))

En primer lugar, los valores del rango de celdas se añaden a la fórmula:

=UNIRCADENAS(", ";VERDADERO;(SI({"Red";"Blue";"Blue";"Red";"Blue";"Red"}="Red";{"A";"B";"C";"D";"E";"F"};"")))

A continuación se compara la lista de nombres de equipos con el valor Rojo:

=UNIRCADENAS(", ";VERDADERO;(SI({VERDADERO;FALSO;FALSO;VERDADERO;FALSO;VERDADERO};{"A";"B";"C";"D";"E";"F"};"")))

La función IF sustituye los valores VERDADERO por el Jugador, y los valores FALSO por «»

=UNIRCADENAS(", ";VERDADERO;({"A";"";"";"D";"";"F"}))

La función UNIRCADENAS combina entonces todos los valores de la matriz en una cadena de texto. Hemos ordenado a la función que ignore los valores en blanco y que añada el texto «, » entre cada valor. Esto produce el resultado final:

="A, D, F"

UNIRCADENAS SI – pre-Excel 2019

Como la Función UNIRCADENAS no está disponible antes de la versión de Excel 2019, tenemos que resolver este problema de una manera diferente. La Función CONCATENAR está disponible, pero no toma rangos de celdas como entradas ni permite operaciones de array, por lo que nos vemos obligados a utilizar una columna auxiliar con una Función SI en su lugar.

El siguiente ejemplo muestra como usar una columna auxiliar para crear una cadena de texto separada por comas de Jugadores que se relacionan con un valor de Equipo Rojo:

=SI(C3="Red";B3&", ";"")&D4

El primer paso en este ejemplo es usar una Función SI para replicar la condición de Equipo = Rojo. Si la condición se cumple, se escribe el valor del Jugador y se sigue con el delimitador elegido «, «:

=SI(C3="Red";B3&", ";"")

A continuación, podemos crear una columna que acumule una lista de estos valores en una celda haciendo también referencia a la celda de abajo:

=D3&E4

Esta fórmula utiliza el carácter & para unir dos valores. Ten en cuenta que la función CONCATENAR podría utilizarse para crear exactamente el mismo resultado, pero a menudo se prefiere el método &, ya que es más corto y deja más claro qué acción está realizando la fórmula.

Estas dos columnas de ayuda pueden combinarse en una fórmula:

=SI(C3="Red";B3&", ";"")&D4

Una celda de resumen puede entonces hacer referencia al primer valor de la columna de ayuda Lista de jugadores:

=D3

Si el valor final «,» no es necesario, debe añadirse a la fórmula una función SI anidada adicional:

=SI(C3="Red";SI(D4="";B3;B3&", ");"")&D4

La parte adicional de la fórmula es la función SI de abajo:

SI(D4="";B3;B3&", ")

Esta parte de la fórmula comprueba el valor de la celda que está debajo. Si está vacía, entonces esta celda debe ser el último Jugador de la lista y el nombre se escribe sin delimitador. Si la celda de abajo contiene un valor, entonces esta celda no es el último Jugador de la lista y entonces se añade el delimitador «, «.

 

TEXTJOIN SI en Google Sheets

Estas fórmulas funcionan igual en Google Sheets que en Excel, excepto que en Google Sheets es necesario utilizar la función ARRAYFORMULA para que evalúe los resultados correctamente. A diferencia de Excel, en Google Sheets, la función TEXTJOIN mantiene el mismo nombre en su versión Español. Se puede añadir automáticamente pulsando las teclas CTRL + SHIFT + ENTER mientras se edita la fórmula (o añadiendo manualmente

=ARRAYFORMULA(TEXTJOIN(", ";VERDADERO;(SI(C3:C8="Red";B3:B8;""))))