Sumar Si – Múltiples Hojas – Excel y Google Sheets

Written by

Editorial Team

Reviewed by

Steve Rynearson

Translated by

Dennis Madrid

Last updated on febrero 8, 2023

Este tutorial mostrará cómo utilizar las funciones SUMAPRODUCTO y SUMAR.SI.CONJUNTO para sumar datos que cumplen ciertos criterios en varias hojas de Excel y Google Sheets.

Sumarsi multiples hojas

Suma regular a través de múltiples hojas

A veces los datos pueden abarcar varias hojas de trabajo en un archivo de Excel. Esto es común para los datos que se recogen periódicamente. Cada hoja de un libro de trabajo puede contener datos para un periodo de tiempo determinado. Queremos una fórmula que sume los datos contenidos en dos o más hojas. La función SUMA permite sumar fácilmente los datos de varias hojas utilizando una fórmula referencia 3D:

=SUMA(Hoja1:Hoja2!A1)

Función suma referencia 3d

Sin embargo, esto no es posible con la Función SUMAR.SI.CONJUNTO. En su lugar debemos utilizar una fórmula más complicada.

Suma de varias hojas

Este ejemplo sumará el Número de Entregas Previstas para cada Cliente a través de múltiples hojas de trabajo, cada una con datos relativos a un mes diferente, utilizando las Funciones SUMAR.SI.CONJUNTO, SUMAPRODUCTO, e INDIRECTO:

=SUMAPRODUCTO(SUMAR.SI.CONJUNTO(INDIRECTO("'"&F3:F6&"'!"&"D3:D7"),INDIRECTO("'"&F3:F6&"'!"&"C3:C7"),H3))

Sumar varias hojas

Veamos esta fórmula.

Paso 1: Crear una fórmula SUMAR.SI.CONJUNTO para una sola hoja de entrada:

Usamos la Función SUMAR.SI.CONJUNTO para sumar el Número de Entregas Previstas por Cliente para una sola hoja de datos de entrada:

=SUMAR.SI.CONJUNTO(D3:D7,C3:C7,H3)

Función sumarsiconjunto

Paso 2: Añadir una referencia de hoja a la fórmula

Mantenemos el resultado de la fórmula igual, pero especificamos que los datos de entrada están en la hoja llamada ‘Paso 2’

=SUMAR.SI.CONJUNTO('Paso 2'!D3:D7;'Paso 2'!C3:C7;H3)

Función sumarsiconjunto referencia

Paso 3: Anidar dentro de una función SUMAPRODUCTO

Para preparar la fórmula para realizar cálculos SUMAR.SI.CONJUNTO en varias hojas y luego sumar los resultados, añadimos una función SUMPRODUCTO alrededor de la fórmula

=SUMAPRODUCTO(SUMAR.SI.CONJUNTO('Paso 3'!D3:D7;'Paso 3'!C3:C7;H3))

Función sumarsiconjunto sumaproducto

Si se utiliza la función SUMAR.SI.CONJUNTO en una hoja, se obtiene un único valor. A través de múltiples hojas, la función SUMAR.SI.CONJUNTO produce un array de valores (uno por cada hoja de cálculo). Utilizamos la función SUMPRODUCTO para sumar los valores de esta matriz.

Paso 4: Reemplazar la referencia de la hoja con una lista de nombres de hojas

Deseamos reemplazar la parte del Nombre de la Hoja de la fórmula con una lista de datos que contenga los valores Ene, Feb, Mar y Abr. Esta lista se almacena en las celdas F3:F6. La Función INDIRECTO para asegurar que la lista de texto que muestra los Nombres de las Hojas sea tratada como parte de una referencia de celda válida en la Función SUMAR.SI.CONJUNTO.

=SUMAPRODUCTO(SUMAR.SI.CONJUNTO(INDIRECTO("'"&F3:F6&"'!"&"D3:D7");INDIRECTO("'"&F3:F6&"'!"&"C3:C7");H3))

Sumar varias hojas

En esta fórmula, la referencia de rango escrita anteriormente:

'Paso 3'!D3:D7

Se sustituye por

INDIRECTO("'"&F3:F6&"'!"&"D3:D7")

Las comillas dificultan la lectura de la fórmula, por lo que aquí se muestra con espacios añadidos:

INDIRECTO ( " ' " & F3:F6 & " ' ! " & "D3:D7" )

Esta forma de referenciar una lista de celdas también nos permite resumir los datos de varias hojas que no siguen un estilo de lista numérica. Una referencia 3D estándar requeriría que los nombres de las hojas fueran del estilo Entrada1, Entrada2, Entrada3, etc., pero el ejemplo anterior permite utilizar una lista de cualquier nombre de hoja y tenerlos referenciados en una celda separada.

Bloqueo de las referencias de celdas

Para que nuestras fórmulas sean más fáciles de leer, hemos mostrado las fórmulas sin referencias de celdas bloqueadas:

=SUMPRODUCTO(SUMAR.SI.CONJUNTO(INDIRECTO("'"&F3:F6&"'!"&"D3:D7"),INDIRECTO("'"&F3:F6&"'!"&"C3:C7"),H3))

Pero estas fórmulas no funcionarán correctamente cuando se copien y peguen en otro lugar del archivo. En su lugar, debes utilizar referencias de celdas bloqueadas como esta

=SUMPRODUCT(SUMIFS(INDIRECT("'"&$F$3:$F$6&"'!"&"D3:D7"),INDIRECT("'"&$F$3:$F$6&"'!"&"C3:C7"),H3))

Lee nuestro artículo sobre el bloqueo de referencias de celdas para obtener más información.

SUMAR.SI.CONJUNTO en varias hojas de cálculo en Google Sheets

Actualmente no es posible utilizar la función INDIRECTO para hacer referencia a una lista de hojas en una función SUMPRODUCTO y SUMAR.SI.CONJUNTO en Google Sheets. En su lugar, se pueden realizar cálculos SUMAR.SI.CONJUNTO por separado para cada hoja de entrada y sumar los resultados:

=SUMAR.SI.CONJUNTO(Ene!D3:D7;Ene!C3:C7;H3)
+SUMAR.SI.CONJUNTO(Feb!D3:D7;Feb!C3:C7;H3)
+SUMAR.SI.CONJUNTO(Mar!D3:D7;Mar!C3:C7;H3)
+SUMAR.SI.CONJUNTO(Abr!D3:D7;Abr!C3:C7;H3)

Función sumarsiconjunto gsheets