Suma con Función BUSCARV – Excel y Google Sheets

Este tutorial demostrará cómo sumar los resultados de múltiples funciones BUSCARV en una fórmula en Excel y Google Sheets.

 

SUMA con BUSCARV

La función BUSCARV busca un solo valor, pero al crear una fórmula de matriz, puede buscar y sumar múltiples valores a la vez.

Este ejemplo mostrará cómo calcular el total de ingresos por ventas de una tienda específica durante 3 meses utilizando una función de matriz con SUMA y BUSCARV:

=SUMA(BUSCARV(P3;B3:N6;{2,3,4};FALSO))

 

 

Esta fórmula de matriz es equivalente a utilizar las siguientes 3 funciones BUSCARV regulares para sumar los ingresos de los meses de enero, febrero y marzo.

=BUSCARV(P3;B3:N6;2;FALSO)+BUSCARV(P3;B3:N6;3;FALSO)+BUSCARV(P3;B3:N6;4;FALSO)

Podemos combinar estas funciones haciendo lo siguiente: Primero, configuramos la función BUSCARV para que devuelva las columnas 2, 3 y 4 como salida de un array (rodeado de paréntesis):

=BUSCARV(P3;B3:N6;{2,3,4};FALSO)

Esto producirá el resultado de la matriz:

{98, 20, 76}

A continuación, para sumar el resultado de la matriz, utilizamos la función SUMA.

¡¡¡Importante!!! Si estás utilizando las versiones de Excel 2019 o anteriores, debes introducir la fórmula pulsando CTRL + SHIFT + ENTER para crear la fórmula de la matriz. Sabrás que lo has hecho correctamente, cuando aparezcan los corchetes alrededor de la fórmula. Esto no es necesario en Excel 365 (o versiones más nuevas de Excel).

 

Usando Tamaños Mayores de Arrays en una Función BUSCARV

Podemos ampliar el tamaño del array de entrada para representar más datos.

Este siguiente ejemplo calculará el Total de Ingresos por Ventas de una Tienda específica durante 12 meses utilizando una función de matriz que contiene la Función SUMA para combinar 12 usos de la Función BUSCARV en una celda.

{=SUMA(BUSCARV(P3;B3:N6;{2,3,4,5,6,7,8,9,10,11,12,13};FALSO))}

 

Otras funciones de resumen y BUSCARV

Se pueden utilizar otras funciones de resumen del mismo modo que la función SUMA para producir estadísticas de resumen alternativas.

or ejemplo, podemos utilizar las funciones MAX, MIN, PROMEDIO, MEDIANA, SUMA y CONTAR para resumir los ingresos por ventas de enero a marzo:

=MAX(BUSCARV(J3;B3:H6;{2,3,4};FALSO))

=MIN(BUSCARV(J3;B3:H6;{2,3,4};FALSO))

=PROMEDIO(BUSCARV(J3;B3:H6;{2,3,4};FALSO))

=MEDIANA(BUSCARV(J3;B3:H6;{2,3,4};FALSO))

=SUMA(BUSCARV(J3;B3:H6;{2,3,4};FALSO))

=CONTAR(BUSCARV($J3;$B$3:$H$6;{2,3,4};FALSO))

 

Bloqueo de las referencias de celdas

Para que nuestras fórmulas sean más fáciles de leer, hemos mostrado las fórmulas sin referencias de celdas bloqueadas:

=SUMA(BUSCARV(P3;B3:N6;{2,3,4};FALSO))

Pero estas fórmulas no funcionarán correctamente cuando se copien y peguen en otro lugar del archivo. En su lugar, debes utilizar referencias de celdas bloqueadas como esta

=SUMA(BUSCARV(P3;$B$3:$N$6;{2,3,4};FALSO))

Lea nuestro artículo sobre el bloqueo de referencias de celdas para obtener más información.

 

Resultados de SUMA BUSCARV en Google Sheets

Estas fórmulas funcionan igual en Google Sheets que en Excel, salvo que es necesario utilizar la función ARRAYFORMULA en Google Sheets para que evalúe los resultados correctamente. Esto se puede añadir automáticamente pulsando las teclas CTRL + SHIFT + ENTER mientras se edita la fórmula.

=ARRAYFORMULA(SUMA(BUSCARV(P5;B5:N8;{2;3;4};FALSO)))