Devolver la Dirección del Valor Más Alto del Rango – Excel y Google Sheets

Este tutorial demostrará cómo encontrar y utilizar la dirección de la celda del valor más alto en un rango de celdas en Excel y Google Sheets.

 

 

Identificar el Valor Más Alto en un Rango

En primer lugar, vamos a mostrar cómo encontrar el valor más alto en un rango de celdas mediante el uso de la Función MAX:

Este ejemplo identificará la puntuación más alta de una lista:

=MAX(D3:D8)

 

Encontrar Otra Información Sobre la Puntuación Más Alta

Para mostrar más información sobre la puntuación más alta de una lista, podemos utilizar una combinación de las funciones INDICE y COINCIDIR.

La fórmula final para encontrar el nombre del Jugador con la Puntuación más alta es:

=INDICE(B3:B8;COINCIDIR(MAX(D3:D8);D3:D8;0))

 

Para explicar esto en pasos, primero identificaremos exactamente qué celda contiene la Puntuación más alta en el rango de datos:

=COINCIDIR(MAX(D3:D8);D3:D8;0)

Esta fórmula utiliza la Función COINCIDIR para identificar la primera celda de la lista de Puntuaciones que coincide con el valor de la Puntuación más alta

=COINCIDIR(8;{2;4;6;8;3;5};0)

Encuentra la primera coincidencia exacta en la 4ª celda y así produce el resultado de 4:

=4

Volviendo a la fórmula completa:

=INDICE(B3:B8;COINCIDIR(MAX(D3:D8);D3:D8;0))

Ahora añadimos la lista de nombres de Jugadores y sustituimos el valor de la Fórmula MATCH:

=INDICE({"A";"B";"C";"D";"E";"F"};4)

Ahora la Función INDICE devuelve el valor de la 4ª celda de la lista de nombres de Jugadores

="D"

Tenga en cuenta que si más de una celda contiene una puntuación de 8, sólo la primera coincidencia será identificada por esta fórmula.

Se puede mostrar información adicional sobre la fila de datos con la Puntuación más alta adaptando esta fórmula para mostrar valores de otras columnas.

Para mostrar la Fecha de la Puntuación más alta, podemos escribir:

=INDICE(C3:C8;COINCIDIR(MAX(D3:D8);D3:D8;0))

 

Identificar la Dirección de Celda del Valor Más Alto de un Rango

Podemos extender la lógica del ejemplo anterior para mostrar la dirección de celda de la Puntuación más alta utilizando la Función CELDA junto con las Funciones INDICE, COINCIDIR y MAX que ya se utilizaron:

=CELDA("ADDRESS";INDICE(D3:D8;COINCIDIR(MAX(D3:D8);D3:D8;0)))

 

Las partes INDICE y COINCIDIR de la fórmula se utilizarían normalmente para mostrar el valor de una celda, pero utilizaremos la Función CELDA para mostrar una característica diferente. Utilizando el argumento «ADDRESS», y a continuación la fórmula INDICE-COINCIDIR anterior, podemos producir una referencia de celda que identifique la Puntuación más alta .

Esta referencia de celda puede utilizarse como entrada en otras fórmulas utilizando la Función INDIRECTO:

=INDIRECTO(G2)

 

Devolver la Dirección del Valor Más Alto del Rango en Google Sheets

Estas fórmulas funcionan exactamente igual en Google Sheets que en Excel.