Contar el Total de Palabras en una Celda – Excel y Google Sheets
Descargar el Libro de Ejemplo
Este tutorial te enseñará a contar palabras en una celda en Excel y Google Sheets.
Contar Palabras
No hay una función incorporada en Excel para contar el número de palabras en una celda. Sin embargo, podemos contar el número de espacios, lo que nos puede decir cuántas palabras hay en una celda:
=LARGO(ESPACIOS(B3))-LARGO(SUSTITUIR(B3;" ";""))+1
Veamos cómo funciona esta fórmula.
Eliminar Todos los Espacios
Primero, usamos la Función SUSTITUIR para eliminar todos los espacios de la cadena de texto.
=SUSTITUIR(B3;" ";"")
A continuación, determinamos la longitud de esta cadena sin espacios con la Función LARGO.
=LARGO(C3) or =LARGO(SUSTITUIR(B3;" ";""))
Compararemos la longitud de la cadena antes y después de eliminar los espacios, para contar cuántos espacios contiene la celda.
Eliminar los Espacios Sobrantes
A continuación, queremos expresar esta cadena como lo haríamos normalmente (es decir, que sólo contenga espacios simples entre las palabras). La Función ESPACIOS elimina los espacios sobrantes de una cadena de texto, dejando un único espacio entre cada palabra, por lo que se excluirán todos los espacios iniciales, finales y repetidos.
=ESPACIOS(B3)
A continuación, determinamos la longitud de este texto ordenado normalmente con la Función LARGO.
=LARGO(E3) or =LARGO(ESPACIOS(B3))
Hallando la diferencia entre las dos longitudes (con y sin espacios) y sumando uno (ya que no hay espacio después de la última palabra) nos da el recuento de palabras de la celda:
=F3-D3+1
Combinando estos pasos obtenemos la fórmula:
=LARGO(ESPACIOS(B3))-LARGO(SUSTITUIR(B3;" ";""))+1
Contar el Total de Palabras en una Celda en Google Sheets
Todos los ejemplos anteriores funcionan exactamente igual en Google Sheets que en Excel.
