BUSCARX Texto – Excel y Google Sheets
Descargar el Libro de Ejemplo
Este tutorial demostrará cómo utilizar la función BUSCARX con texto en Excel.
BUSCARX con texto
Para buscar una cadena de texto, puedes introducir el texto en la función BUSCARX entre comillas.
=BUSCARX("Sub 2";B3:B7;C3:C7)
BUSCARX con texto en celdas
O bien, puede hacer referencia a una celda que contenga texto.
=BUSCARX(E3;B3:B7;C3:C7)
BUSCARX con varios textos
Si desea buscar una serie de textos, introduzca la referencia del rango en la fórmula, y se creará una fórmula dinámica de «Array «.
=BUSCARX(E3:E4;B3:B7;C3:C7)
La fórmula se «derramará» para realizar los cálculos en toda la matriz de valores. Alternativamente, puede hacer referencia a una sola celda, bloquear las referencias de celda y copiar la fórmula hacia abajo.
=BUSCARX(E3;$B$3:$B$7;$C$3:$C$7)
Nota: Asegúrate de que los argumentos 2º y 3º están en referencias absolutas añadiendo signos de dólar delante de la letra de la columna y el número de la fila (o puedes poner el cursor en la referencia mientras estás en la fórmula y pulsar F4). Esto fijará las referencias mientras arrastras o copias la fórmula.
BUSCARX con el último texto
Por defecto, la función BUSCARX buscará una coincidencia exacta desde la parte superior de la lista hacia abajo (es decir, enfoque Arriba-Abajo). Podemos invertir esto aplicando un valor de -1 al último argumento: modo_de-búsqueda. Podemos encontrar la última aparición de un texto dentro de una lista aplicando -1 al último argumento de la función BUSCARX.
=BUSCARX(E3;B3:B7;C3:C7;;;-1)
BUSCARX con función IGUAL
No es obvio en los ejemplos anteriores, pero el proceso de comparación de la función BUSCARX no distingue entre mayúsculas y minúsculas. Esto significa que el texto coincidirá independientemente de las mayúsculas o minúsculas. Podemos utilizar la Función IGUAL para realizar una coincidencia que distinga entre mayúsculas y minúsculas.
=BUSCARX(VERDADERO;IGUAL(E3;B3:B7);C3:C7)
Visualicemos cómo funciona la fórmula anterior:
La función IGUAL realiza una comparación entre dos valores que distingue entre mayúsculas y minúsculas. En nuestro ejemplo, se crea una matriz, comparando el valor de búsqueda (ver Columna C) y cada uno de los valores de la matriz de búsqueda (ver Columna B). La función IGUAL devolverá VERDADERO si los textos comparados son iguales y FALSO si son diferentes (véase la columna D).
En nuestra fórmula BUSCARX se ve así:
Nota: Esto sólo funcionará si hay un array de entrada (B3:B7 en la fórmula BUSCARX). La Función IGUAL también devolverá una salida de matriz como se visualiza en la Columna D. La salida del arreglo de la Función IGUAL se usa entonces como el arreglo de búsqueda para la Función BUSCARX. Buscaremos la primera ocurrencia del valor VERDADERO, que significa una coincidencia exacta, y devolveremos el estado correspondiente.
BUSCARX con coincidencia parcial
El proceso de coincidencia en los ejemplos anteriores se hace coincidiendo textos o frases enteras, pero también podemos realizar una coincidencia parcial en BUSCARX.
BUSCARX con comodines
El método más sencillo para realizar una coincidencia parcial es utilizar comodines. Tenemos que cambiar el 5º argumento: modo_de_coincidencia a 2 para permitirlo.
=BUSCARX("*"&E3&"*";B3:B7;C3:C7;;2)
Nota: El comodín asterisco representa cualquier número de cualquier carácter. Añadiendo el asterisco al principio y al final, buscamos cualquier texto que contenga «RS».
BUSCARX con función HALLAR
Otra forma de realizar una coincidencia parcial es anidar una función HALLAR dentro del BUSCARX. Para que esto funcione, debemos encerrar la Función HALLAR utilizando la Función ESNUMERO.
=BUSCARX(VERDADERO;ESNUMERO(HALLAR(E3;B3:B7));C3:C7;;2)
Visualicemos cómo funciona la fórmula:
La función BUSCAR busca un texto a partir de otro texto. Devolverá un número de posición si encuentra el texto buscado. En caso contrario, devolverá un error. Como tenemos una matriz de entrada (B3:B7), realizará la búsqueda para cada uno de los valores dentro de la matriz de entrada y devolverá una matriz de salida (Columna C abajo).
Así es como se ve en nuestra fórmula:
La salida de la matriz de la función HALLAR alimenta a la función ESNUMERO, que comprueba si los valores devueltos por la función HALLAR son números. Si un valor es un número, devolverá VERDADERO. En caso contrario, FALSO. (Por favor, vea la columna D más abajo)
Así es como se ve el resultado del ESNUMERO en la fórmula:
Ahora tenemos un array de salida de valores VERDADERO y FALSO, que se utilizan como array de búsqueda para la función BUSCARX. Buscaremos VERDADERO como la coincidencia parcial.
BUSCARX con función ENCONTRAR
Las funciones HALLAR y ENCONTRAR son casi la misma función. Una diferencia importante es que la función HALLAR no distingue entre mayúsculas y minúsculas, mientras que la función ENCONTRAR distingue entre mayúsculas y minúsculas.
Para realizar una coincidencia parcial que distinga entre mayúsculas y minúsculas, utilizaremos la combinación de la Función ENCONTRAR y la Función ESNUMERO.
=BUSCARX(VERDADERO;ESNUMERO(ENCONTRAR(E3;B3:B7));C3:C7;;2)
Problema de coincidencia parcial de BUSCARX
Los anteriores métodos de concordancia parcial discutidos en las secciones anteriores tienen un defecto importante. No pueden distinguir una coincidencia de texto exacta dentro de una frase dada.
El proceso de concordancia parcial que se expone a continuación no puede distinguir el término EPA del «epa» de la palabra «Separate»
BUSCARX con coincidencia parcial exacta
Si las palabras están separadas por espacios, podemos añadir espacios para realizar una coincidencia parcial exacta.
=BUSCARX("* "&E3&" *";" "&B3:B7&" ";C3:C7;;2)
Nota: Añadimos espacios antes y después de E3, y también hacemos lo mismo para la matriz de búsqueda en B3:B7. De este modo, las palabras tendrán espacios al principio y al final, que se utilizarán para distinguir una coincidencia exacta de términos dentro de las frases.
BUSCARX Problema de Texto
Uno de los problemas más comunes en la coincidencia de textos son los espacios no deseados. Los espacios se tratan como parte de los textos. Por lo tanto, si hay espacios extra, que son difíciles de notar, la función BUSCARX devolverá un error. Asegúrese de que no hay espacios no deseados en el valor de búsqueda y en la matriz de búsqueda. El valor de búsqueda (E3) en el ejemplo siguiente tiene un espacio extra entre el «Sub» y el «2»
BUSCARX con la función ESPACIOS
Podemos utilizar la función ESPACIOS para resolver los espacios extra. Podemos aplicarla tanto al valor de la búsqueda como a toda la matriz de búsqueda.
=BUSCARX(ESPACIOS(E3);ESPACIOS(B3:B7);C3:C7)
Nota: La función ESPACIOS elimina los espacios extra entre las palabras hasta que haya un límite de un espacio entre ellas, y se eliminan los espacios antes de la primera palabra y después de la última de un texto o frase.
