BUSCARV – Varias Hojas de Cálculo a la Vez – Excel y Google Sheets
Descargar el Libro de Ejemplo
Este tutorial mostrará cómo realizar un BUSCARV en múltiples hojas en Excel y Google Sheets. Si tu versión de Excel admite BUSCARX, te recomendamos que utilices BUSCARX en su lugar.
La función BUSCARV sólo puede realizar una búsqueda en un único conjunto de datos. Si queremos realizar una búsqueda entre múltiples conjuntos de datos que están almacenados en diferentes hojas, podemos combinar todos los conjuntos de datos en un solo conjunto o utilizar la función SI.ERROR junto con BUSCARV para realizar múltiples búsquedas en una sola fórmula. Este último método es más sencillo en Excel, mientras que el primero lo es en Google Sheets.
BUSCARV con SI.ERROR
La función BUSCARV (y otras fórmulas de búsqueda) devuelve un error si no encuentra una coincidencia, y normalmente utilizamos la función SI.ERROR para sustituir el error por un valor personalizado. En lugar de un valor personalizado, usaremos el SI.ERROR para realizar otro BUSCARV desde otra hoja si el primer BUSCARV no puede encontrar una coincidencia en la primera hoja.
BUSCARV – 2 hojas a la vez
=SI.ERROR(BUSCARV(B3;'Dept. A'!$B$3:$C$7;2;FALSO);BUSCARV(B3;'Dept. B'!$B$3:$C$7;2;FALSO))
Repasemos la fórmula:
Función BUSCARV
Aquí está el primer BUSCARV:
=BUSCARV(B3;'Dept. A'!$B$3:$C$7;2;FALSO)
Nota: La función BUSCARV busca el valor de búsqueda de la primera columna de la tabla y devuelve el valor correspondiente de la columna definida por el indicador_columnas (es decir, el 3er argumento). El último argumento define el tipo de coincidencia (es decir, Verdadero – Coincidencia aproximada, Falso – Coincidencia exacta). Aquí está el BUSCARV para la 2da Hoja:
=BUSCARV(B3;'Dept. B'!$B$3:$C$7;2;FALSO)
Función SI.ERROR
Combinamos los resultados de los 2 BUSCARVs utilizando la función SI.ERROR. Comprobamos el valor del primer BUSCARV (por ejemplo, Dept A). Si el valor es un error, se devuelve el valor correspondiente del 2do BUSCARV en su lugar.
=SI.ERROR(E3;F3)
Nota: La función SI.ERROR comprueba un valor (es decir, el 1er argumento) si es un error (por ejemplo, #N/D, #REF!). Si es un error, entonces devolverá el valor de su último argumento en lugar del error. Si no es un error, devolverá el valor que se está comprobando. Combinando todos estos conceptos se obtiene nuestra fórmula original
=SI.ERROR(BUSCARV(B3;'Dept. A'!$B$3:$C$7;2;FALSO);BUSCARV(B3;'Dept. B'!$B$3:$C$7;2;FALSO))BUSCARV – Más de 2 hojas a la vez
Para más de dos hojas, necesitamos añadir un BUSCARV y un SI.ERROR por hoja adicional a la fórmula anterior. Esta es la fórmula para 3 hojas:
=SI.ERROR(SI.ERROR(BUSCARV(B3;'Dept. A'!$B$3:$C$7;2;FALSO);
BUSCARV(B3;'Dept. B'!$B$3:$C$7;2;FALSO));
BUSCARV(B3;'Dept. C'!$B$3:$C$7;2;FALSO))
BUSCARV – Varias Hojas a la Vez en Google Sheets
Aunque la combinación de SI.ERROR y BUSCARV funciona igual en Google Sheets, es más sencillo combinar los conjuntos de datos en uno solo.
BUSCARV con corchetes {} (Google Sheets)
Podemos combinar los conjuntos de datos en uno solo utilizando las llaves.
=BUSCARV(B3;{'Dept. A'!$B$3:$C$7;'Dept. B'!$B$3:$C$7;'Dept. C'!$B$3:$C$7};2;FALSO)
Desglosemos y visualicemos la fórmula: Apila todos los conjuntos de datos verticalmente separando los rangos de celdas con el punto y coma dentro de las llaves:
={'Dept. A'!$B$3:$C$7;'Dept. B'!$B$3:$C$7;'Dept. C'!$B$3:$C$7}
Nota: Las llaves en Google Sheets también pueden utilizarse para crear una matriz a partir de rangos de celdas. El punto y coma se utiliza para apilar los valores verticalmente, mientras que la coma se utiliza para apilar los valores horizontalmente. Si los rangos de celdas se apilan verticalmente, debemos asegurarnos de que el número de columnas para cada uno de los rangos de celdas es el mismo. De lo contrario, no funcionará. En horizontal, el número de filas debe ser el mismo. El array resultante se utiliza como entrada para el 2do argumento del BUSCARV:
=BUSCARV(E3;$B$3:$C$17;2;FALSO)
Combinando todo esto resulta nuestra fórmula original
=BUSCARV(B3;{'Dept. A'!$B$3:$C$7;'Dept. B'!$B$3:$C$7;'Dept. C'!$B$3:$C$7};2;FALSO)
