Este tutorial mostrará cómo buscar valores mínimos y máximos en Excel y Google Sheets.

INDICE-COINCIDIR con MIN

Podemos utilizar la combinación de INDICE, COINCIDIR y MIN para buscar el número más bajo.

=INDICE(B3:B7;COINCIDIR(MIN(C3:C7);C3:C7;0))

Repasemos la fórmula:

Función MIN

La función MIN devuelve el número más pequeño de una lista. Ignora los valores no numéricos (por ejemplo, celdas vacías, cadenas de texto o valores booleanos).

=MIN(C3:C7)

Función COINCIDIR

A continuación, el resultado de la función MIN se introduce como valor de búsqueda para la función COINCIDIR con el fin de encontrar la posición o coordenada del valor más bajo de la lista.

=COINCIDIR(E3,C3:C7,0)

Nota: Establecemos el 3er argumento(tipo_de_coincidencia) de la Función COINCIDIR a 0, lo que significa coincidencia exacta.

Función INDICE

La coordenada de salida de la función COINCIDIR se introduce en la función INDICE para extraer el valor correspondiente de la lista que nos interesa (por ejemplo, B3:B7).

=INDICE(B3:B7,F3)

Nota: Si el 1er argumento (es decir, matriz) de la Función INDICE es una lista 1D, el 2do argumento (es decir, núm_fila) puede convertirse en la coordenada de la fila o la coordenada de la columna dependiendo de la disposición de la lista 1D. Si es una lista vertical, entonces se convierte en la coordenada de la fila, y si es una lista horizontal, entonces es la coordenada de la columna. En conjunto, la Función MIN extrae el valor más bajo, la Función COINCIDIR busca el valor más bajo y devuelve su posición y la Función INDICE extrae el valor correspondiente de la lista que nos interesa. Combinando todas ellas en una sola fórmula se obtiene nuestra fórmula original

=INDICE(B3:B7;COINCIDIR(MIN(C3:C7);C3:C7;0))

BUSCARV con MIN

También podemos utilizar la función BUSCARV en lugar de la fórmula INDICE-COINCIDIR como fórmula de búsqueda, pero tenemos que cambiar la estructura de nuestra tabla haciendo que la columna de búsqueda (por ejemplo, Ingresos totales) sea la primera columna. Al igual que con el INDICE-COINCIDIR, introduciremos la función MIN como el valor de búsqueda para VLOOKUP.

=BUSCARV(MIN(B3:B7);B3:C7;2;FALSO)

 

Nota: La función BUSCARV busca el valor_buscado de la primera columna de la tabla y devuelve el valor correspondiente de la columna definida por el índice de la columna (es decir, el 3er argumento).

BUSCARX con MIN

Otra alternativa para la fórmula de búsqueda es la Función BUSCARX, que es la solución más conveniente, pero requiere una versión más reciente de Excel. Esta solución requiere el menor número de funciones y no es necesario reestructurar los datos. Podemos anidar la Función MIN en BUSCARX para buscar el valor más bajo.

=BUSCARX(MIN(C3:C7),C3:C7,B3:B7)

Nota: Por defecto, la función BUSCARX busca una coincidencia exacta desde la parte superior de la matriz de búsqueda (2do argumento) hacia abajo (es decir, de arriba hacia abajo). Una vez que encuentra una coincidencia, devuelve el valor correspondiente de la matriz de retorno (3er argumento). En caso contrario, devuelve un error. Como se ha comentado anteriormente, la estructura de las soluciones es la misma. Por lo tanto, utilizaremos una de las fórmulas de búsqueda (es decir, BUSCARX) al pasar a las secciones siguientes.

BUSCARX con K.ESIMO.MENOR

Si desea buscar el segundo o tercer valor más pequeño, puede utilizar la función K.ESIMO.MENOR. En este ejemplo, utilizaremos la función K.ESIMO.MENOR para extraer el valor más bajo.

=BUSCARX(K.ESIMO.MENOR(C3:C7;1);C3:C7;B3:B7)

Repasemos la fórmula:

Función K.ESIMO.MENOR

Podemos devolver el valor más bajo estableciendo el 2do argumento de la función K.ESIMO.MENOR en 1, lo que significa la 1era entrada si la lista está en orden ascendente.

=K.ESIMO.MENOR(C3:C7,1)

Nota: en su lugar podríamos utilizar 2 para el 2º más pequeño o 3 para el 3º más pequeño. Entonces, el resultado de la función K.ESIMO.MENOR será el valor_buscado de nuestra fórmula de búsqueda, que en este caso es la función BUSCARX:

La combinación de las dos funciones da como resultado nuestra fórmula original:

=BUSCARX(K.ESIMO.MENOR(C3:C7;1);C3:C7;B3:B7)

Buscar el valor más alto

También podemos encontrar el valor más alto utilizando los opuestos de MIN y K.ESIMO.MENOR: la función MAX y la función K.ESIMO.MAYOR, respectivamente.

BUSCARX con MAX

Podemos anidar la Función MAX como el valor de búsqueda para la Función XLOOKUP para buscar el valor más alto.

=BUSCARX(MAX(C3:C7);C3:C7;B3:B7)

Repasemos la fórmula:

Función MAX

Necesitamos la función MAX para devolver el mayor valor de la lista.

El resultado de la Función MAX se introduce en el BUSCARX, que extraerá el valor que nos interesa:

Combinando los dos juntos, tenemos nuestra fórmula original:

=BUSCARX(MAX(C3:C7);C3:C7;B3:B7)

BUSCARX con K.ESIMO.MAYOR

La alternativa a la función MAX es la función K.ESIMO.MAYOR. La función K.ESIMO.MAYOR devolverá el enésimo número más grande de una lista. En este ejemplo devolveremos el mayor.

=BUSCARX(K.ESIMO.MAYOR(C3:C7;1);C3:C7;B3:B7)

 

Desglosemos y visualicemos la fórmula:

Función K.ESIMO.MAYOR

Al establecer el 2do argumento de la función K.ESIMO.MAYOR en 1, podemos extraer el valor más grande de la lista.

El resultado de la función K.ESIMO.MAYOR se utiliza entonces como valor de búsqueda del BUSCARX:

Combinando las dos funciones se obtiene nuestra fórmula original

=BUSCARX(K.ESIMO.MAYOR(C3:C7;1);C3:C7;B3:B7)

Buscar el enésimo valor más bajo/más alto

BUSCARX con K.ESIMO.MENOR n-ésimo valor más bajo

Podemos cambiar el 2do argumento de la función K.ESIMO.MAYOR a mayor que 1 para encontrar el enésimo valor más bajo de la lista.

=BUSCARX(K.ESIMO.MENOR(C3:C7;2);C3:C7;B3:B7)

BUSCARX con K.ESIMO.MAYOR n-ésimo valor más grande

También podemos hacer lo mismo para el enésimo valor más grande utilizando la función K.ESIMO.MAYOR.

=BUSCARX(K.ESIMO.MAYOR(C3:C7;2);C3:C7;B3:B7)

Buscar Min/Max con condiciones

En escenarios complicados donde hay criterios para extraer el valor mínimo/máximo, podemos utilizar las variantes SI de los MIN y MAX: MIN.SI.CONJUNTO y MAX.SI.CONJUNTO.

BUSCARX con MIN.SI.CONJUNTO

Los criterios utilizados en el MIN.SI.CONJUNTO deben aplicarse también como criterios «Y» para el proceso de búsqueda.

=BUSCARX(MIN.SI.CONJUNTO(D3:D7;C3:C7;"A")&"A";D3:D7&C3:C7;B3:B7)

Repasemos la fórmula:

Función MIN.SI.CONJUNTO

La función MIN.SI.CONJUNTO devuelve el número más pequeño que cumple los criterios dados (por ejemplo, Departamento).

Nota: La función MIN.SI.CONJUNTO requiere al menos tres argumentos: el rango_mínimo (1er argumento), el rango_de_criterios1 (2do argumento) y los criterios1 (3er argumento). Los demás argumentos son opcionales si hay más de un conjunto de rango_de_criterios y criterios. Una propiedad importante de la función MIN.SI.CONJUNTO es que los argumentos de rango (es decir, rango_mín, rango_de_criterios) deben ser rangos de celdas y no pueden ser constantes de matrices (por ejemplo, {1;2;3}) o salidas de matrices de otras funciones (por ejemplo, SECUENCIA(3)).

Criterio «Y» de búsqueda

En esencia, tenemos que buscar el valor más bajo que satisfaga nuestros criterios. Esto también significa que nuestro proceso de búsqueda debe satisfacer los criterios. Por lo tanto, nuestro escenario se convierte en una búsqueda con múltiples criterios (por ejemplo, Ingresos totales y Departamento), donde todos los criterios deben ser satisfechos (es decir, Criterios Y).

La forma más común de aplicar los Criterios Y es concatenando los criterios utilizando el Operador &, que une dos valores en un solo texto. También tenemos que concatenar las listas donde se buscarán los valores de búsqueda.

=G3&"A"

Los criterios concatenados se convierten en el nuevo valor de búsqueda (por ejemplo, H3) y las listas concatenadas se convierten en la nueva matriz de búsqueda (por ejemplo, E3:E7).

=BUSCARX(H3;E3:E7;B3:B7)

Combinando todo esto se obtiene nuestra fórmula original:

=BUSCARX(MIN.SI.CONJUNTO(D3:D7;C3:C7;"A")&"A";D3:D7&C3:C7;B3:B7)

BUSCARX con MAX.SI.CONJUNTO

También aplicamos los mismos conceptos del apartado anterior (es decir, BUSCARX con MIN.SI.CONJUNTO) para buscar el valor más alto que cumpla los criterios dados.

=BUSCARX(MAX.SI.CONJUNTO(D3:D7;C3:C7;"A")&"A";D3:D7&C3:C7;B3:B7)

Nota: La función MAX.SI.CONJUNTO funciona de forma similar a la función MIN.SI.CONJUNTO.

Búsqueda de valores mínimos y máximos en Google Sheets

Las fórmulas funcionan de la misma manera en Google Sheets, excepto que la función BUSCARX no existe en Google Sheets.