Buscar por Palabras Clave – Excel y Google Sheets

Este tutorial mostrará cómo buscar por palabras clave en Excel y Google Sheets.

 

 

Buscar por Palabras Clave

Para categorizar celdas de texto basándose en las palabras clave que contienen, puede utilizar las funciones HALLAR, ESNUMERO, COINCIDIR e INDICE combinadas.

{=INDICE(E3:E8;COINCIDIR(VERDADERO;ESNUMERO(HALLAR(F3:F8;B3));0))}

 

Nota: Esta es una fórmula de matriz. Cuando utilices Excel 2019 y versiones anteriores, debes introducir la fórmula de matriz pulsando CTRL + MAYÚS + INTRO (en lugar de INTRO), indicando a Excel que la fórmula es una fórmula de matriz. Sabrás que es una fórmula de matriz por las llaves que aparecen alrededor de la fórmula (ver imagen superior). En versiones posteriores de Excel y Excel 365, puedes simplemente pulsar ENTER en su lugar.

Veamos cómo funciona esta fórmula.

Función HALLAR

Típicamente, la Función HALLAR busca una cadena de texto dentro de un valor de celda, devolviendo la posición donde se encuentra el texto.

 

Sin embargo, si utiliza una fórmula de matriz e introduce una matriz de valores para buscar, la función HALLAR devolverá una matriz de coincidencias.

 

Como se muestra arriba, para la celda B3 («toyota rav»), devolverá una matriz como esta:

{#¡VALOR!;8;#¡VALOR!;#¡VALOR!;#¡VALOR!;#¡VALOR!}

lo que significa que sólo encontró una de las palabras clave («rav») en la cadena, en la posición 8.

 

Función ESNUMERO

La función ESNUMERO traduce la matriz dada por la función HALLAR a los valores VERDADERO y FALSO.

 

Función COINCIDIR

Con la función COINCIDIR, encontramos la posición del valor VERDADERO en nuestra matriz ESNUMERO de arriba.

=COINCIDIR(VERDADERO;ESNUMERO(HALLAR(F3:F8;B3));0)

 

Para «toyota rav», el valor VERDADERO es el segundo valor de la matriz.

 

Función INDICE

Por último, utilizamos el resultado de la función COINCIDIR para determinar la fila de Categoría que necesitamos con la función INDICE.

=INDICE(F3:F8;C3)

 

La segunda fila de la lista Categorías es «Crossover & suv», así que esa es la Categoría que coincide con «toyota rav»

La sustitución de «C3» por la expresión COINCIDIR nos devuelve a nuestra fórmula original:

=INDICE(E3:E8;COINCIDIR(VERDADERO;ESNUMERO(HALLAR(F3:F8;B3));0))

Recordatorio: Esta es una fórmula de matriz. Al utilizar Excel 2019 y versiones anteriores, debes introducir la fórmula de matriz pulsando CTRL + MAYÚS + INTRO (en lugar de INTRO), indicando a Excel que la fórmula es una fórmula de matriz. Sabrás que es una fórmula de matriz por las llaves que aparecen alrededor de la fórmula (ver imagen superior). En versiones posteriores de Excel y Excel 365, puedes pulsar INTRO en su lugar.

 

Buscar por Palabras Clave en Google Sheets

Estas fórmulas funcionan exactamente igual en Google Sheets que en Excel.