VBA – einen Bereich einem Array zuweisen

In diesem Tutorial zeigen wir Ihnen, wie Sie ein Array mit einem Zellenbereich auffüllen können.

Einen Bereich einem Array zuweisen

Wir können ein Variant-Array ganz einfach mit einem Zellenbereich auffüllen.

Werte aus einer einzelnen Spalte zuweisen

In diesem Beispiel wird eine Schleife durch den Bereich („A1:A10“) durchlaufen, wobei die Zellenwerte einem Array zugewiesen werden:

Sub TestArrayWerteEinzel()
'Das Array als Variant-Array deklarieren
   Dim arBereich() As Variant

'Die Ganzzahlvariable zum Speichern der Anzahl der Zeilen deklarieren
   Dim iZeile As Integer

'Der Array-Variablen einen Bereich zuweisen
   arBereich = Range("A1:A10")

'Die Zeilen 1 bis 10 in einer Schleife durchlaufen
   For iZeile = 1 To UBound(arBereich)

'das Ergebnis im Direktfenster anzeigen
      Debug.Print arBereich(iZeile , 1)
   Next iZeile 
End Sub

UBound wird verwendet, um die obere Grenze des Arrays festzulegen (z. B. 10), damit die Schleife weiß, dass sie 10 Mal durchlaufen soll.

Die Funktion Debug.Print funktion zeigt Ihnen die im Array enthaltenen Werte im Direktfenster an.

Werte aus mehreren Spalten zuweisen

Sub TestArrayWerteMehrfach()
'Das Array als Variant-Array deklarieren
   Dim arBereich() As Variant 

'Die Ganzzahlvariable zum Speichern der Anzahl der Zeilen deklarieren
   Dim iZeile As Integer

'Die Ganzzahlvariable zum Speichern der Anzahl der Spalten deklarieren
   Dim iSpalte as Integer

'Der Array-Variablen einen Bereich zuweisen
   arBereich = Range("A1:C10")

'Die Zeilen - 1 bis 10 in einer Schleife durchlaufen
   For iZeile = 1 To UBound(arBereich,1)

'Während die Schleife jetzt bei Zeile 1 ist, die 3 Spalten durchlaufen
      For iSpalte = 1 To UBound(arBereich,2)

'das Ergebnis im Direktfenster anzeigen
         Debug.Print arBereich(iZeile, iSpalte)
      Next iSpalte
   Next iZeile 
End Sub

Im obigen Code haben wir das Array mit den Werten in Range(„A1:C10“) aufgefüllt.

UBound wird erneut verwendet, aber dieses Mal wird es zweimal benötigt, einmal zum Durchlaufen der Zeilen und dann noch einmal zum Durchlaufen der Spalten.

Die Funktion Debug.Print zeigt Ihnen die im Array enthaltenen Werte im Direktfenster an.