WENN-Formel – Wenn-Dann-Anweisungen – Excel & Google Sheets

Dieses Tutorial zeigt Ihnen, wie Sie die WENN-Funktion in Excel und Google Sheets verwenden können, um Wenn-Dann-Anweisungen zu erstellen.

Die WENN-Funktion im Überblick

Die WENN-Funktion prüft, ob eine Bedingung erfüllt ist. Wenn sie WAHR ergibt, wird das eine ausgeführt und wenn sie FALSCH ergibt, wird das andere ausgeführt.

So verwenden Sie die WENN-Funktion

Hier ist ein sehr einfaches Beispiel, damit Sie sehen können, was ich meine. Versuchen Sie, Folgendes in Excel einzugeben:

=WENN( 2 + 2 = 4; "Es ist wahr"; "Es ist falsch!")

Da 2 + 2 tatsächlich gleich 4 ist, gibt Excel „Es ist wahr!“ zurück. Wenn wir dies verwenden:

=WENN( 2 + 2 = 5; "Es ist wahr"; "Es ist falsch!")

wird Excel jetzt „Es ist falsch!“ zurückgeben, weil 2 + 2 nicht gleich 5 ist.

Hier sehen Sie, wie Sie die WENN-Anweisung in einer Kalkulationstabelle verwenden können.

=WENN(C4-D4>0;C4-D4;0)

Sie betreiben eine Sportbar und haben für verschiedene Kunden individuelle Limits für die Rechnung festgelegt. Sie haben diese Tabelle eingerichtet, um zu prüfen, ob jeder Kunde sein Limit überschritten hat. In diesem Fall wird ihm der Geldhahn zugedreht, bis er seine Rechnung bezahlt.

Sie prüfen, ob C4-D4 (aktueller Betrag der Rechnung abzüglich des Limits) größer als 0 ist. Dies ist Ihre logische Prüfung. Wenn dies der Fall ist, gibt WENN „Ja“ zurück, d. h. Sie sollten sie ausschließen. Wenn dies nicht der Fall ist, gibt WENN „Nein“ zurück, d. h. Sie lassen sie weitertrinken.

Was kann WENN zurückgeben?

Oben haben wir eine Textzeichenfolge zurückgegeben, „Ja“ oder „Nein“. Sie können aber auch Zahlen oder sogar andere Formeln zurückgeben.

Nehmen wir an, einige Ihrer Kunden machen hohe Rechnungen. Um sie davon abzuhalten, werden Sie anfangen, von Kunden, die ihr Limit überschreiten, Zinsen zu verlangen.

Hierfür können Sie WENN verwenden:

=WENN(C4>D4;C4*0,03;0)

Wenn die Rechnung höher als das Limit ist, geben Sie die Rechnung multipliziert mit 0,03 zurück, was 3 % der Rechnung ergibt. Andernfalls geben Sie 0 zurück: Die Rechnung ist nicht überzogen, also werden keine Zinsen berechnet.

 

WENN mit UND verwenden

Sie können WENN mit der Excel-Funktion UND kombinieren, um mehr als eine Bedingung zu prüfen. Excel gibt nur WAHR zurück, wenn ALLE Prüfungen wahr sind.

Sie haben also Ihren Zinssatz eingeführt. Aber einige Ihrer Stammgäste beschweren sich. Sie haben in der Vergangenheit immer ihre Rechnungen bezahlt, warum gehen Sie jetzt so hart mit ihnen um? Sie haben eine Lösung parat: Bestimmten vertrauenswürdigen Kunden werden Sie keine Zinsen berechnen.

Sie fügen eine neue Spalte in Ihre Kalkulationstabelle ein, um vertrauenswürdige Kunden zu identifizieren und aktualisieren Ihre WENN-Anweisung mit einer UND-Funktion:

=WENN(UND(C4>D4; F4="Nein"); C4*0,03; 0)

Lassen Sie uns den UND-Teil separat betrachten:

UND(C4>D4; F4="Nein")

Beachten Sie die beiden Bedingungen:

• C4>D4: Überprüfung, ob das Rechnungslimit überschritten wurde (wie zuvor)
• F4=“Nein“: dies ist das neue Element, mit dem geprüft wird, ob die Person kein vertrauenswürdiger Kunde ist

Jetzt geben wir den Zinssatz nur dann an, wenn der Kunde seine Rechnung überzogen hat UND wir „Nein“ in der Spalte für vertrauenswürdige Kunden haben. Ihre Stammkunden sind wieder glücklich.

 

WENN mit ODER verwenden

Mit der ODER-Funktion können Sie mehr als eine Bedingung prüfen und WAHR zurückgeben, wenn eine der Bedingungen erfüllt ist.

Vielleicht ist das Überziehen der Rechnung nicht der einzige Grund, warum Sie den Kunden den Geldhahn zudrehen. Vielleicht erteilen Sie einigen Leuten aus anderen Gründen ein vorübergehendes Verbot, z. B. weil sie auf dem Gelände spielen.

Fügen Sie also eine neue Spalte hinzu, um Kunden mit Hausverbot zu identifizieren und aktualisieren Sie die Spalte „Gesperrt?“ mit einer ODER-Prüfung:

=WENN(ODER(C4>D4;E4="Ja"),"Ja";"Nein")

Betrachten Sie nur den ODER-Teil:

ODER(C4>D4;E4="Ja")

Es gibt zwei Bedingungen:

• C4>D4: Überprüfung, ob das Rechnungslimit überschritten wurde
• F4=“Ja“: der neue Teil, der prüft, ob die Person derzeit gesperrt ist

Diese wird als wahr gewertet, wenn sie über ihren Rechnungslimits liegen oder wenn ein „Ja“ in Spalte E steht. Wie Sie sehen können, ist Harry jetzt ausgeschlossen, obwohl er nicht über seinem Rechnungslimit liegt.

 

IF mit XODER verwenden

Die XODER-Funktion gibt WAHR zurück, wenn nur eine Bedingung erfüllt ist. Wenn mehr als eine Bedingung erfüllt sind (oder keine Bedingungen erfüllt sind), gibt Sie FALSCH zurück.

Ein Beispiel könnte dies verdeutlichen. Stellen Sie sich vor, Sie möchten Ihren Mitarbeitern monatliche Prämien auszahlen:

• Wenn sie mehr als 800 $ an Lebensmitteln oder mehr als 800 $ an Getränken verkaufen, erhalten sie einen halben Bonus
• Wenn sie in beiden Bereichen mehr als 800 $ verkaufen, erhalten sie einen vollen Bonus
• Wenn sie in beiden Bereichen weniger als 800 $ verkaufen, erhalten sie keinen Bonus.

Sie wissen bereits, wie Sie herausfinden können, ob sie die volle Prämie erhalten. Sie würden einfach WENN mit UND wie oben beschrieben verwenden.

=WENN(UND(C4>800;D4>800);"Ja";"Nein")

Aber wie würden Sie herausfinden, wer den halben Bonus bekommt? Hier kommt das XDEOR ins Spiel:

=WENN(XODER(C4>=800;D4>=800);"Yes";"Nein")

Wie Sie sehen, hat Woody mehr als 800 Dollar mit Getränken umgesetzt, aber nicht mit Lebensmitteln. Er bekommt also den halben Bonus. Bei Coach ist es genau umgekehrt. Diane und Carla haben beide mehr als 800 $ verkauft, also bekommen sie keinen halben Bonus (beide Argumente sind WAHR), und Rebecca hat bei beiden unter dem Schwellenwert umgesetzt (beide Argumente FALSCH), also ergibt die Formel wieder „Nein“.

WENN mit NICHT verwenden

Die NICHT-Funktion kehrt das Ergebnis einer logischen Prüfung um. Mit anderen Worten: Sie prüft, ob eine Bedingung nicht erfüllt ist.

Sie können sie mit WENN wie folgt verwenden:

=WENN(UND(C3>=1985;NICHT(D3="Steven Spielberg")); "Anschauen"; "Nicht anschauen")

Hier haben wir eine Tabelle mit Daten zu einigen Filmen aus den 1980er Jahren. Wir wollen Filme, die ab 1985 veröffentlicht wurden und bei denen Steven Spielberg die Regie nicht geführt hat, identifizieren.

Da NICHT in einer UND-Funktion verschachtelt ist, wertet Excel diese zuerst aus. Das Ergebnis wird dann als Teil der UND-Funktion verwendet.

Verschachtelte WENN-Anweisungen

Sie können auch eine WENN-Anweisung innerhalb Ihrer WENN-Anweisung zurückgeben. Dadurch können Sie komplexere Berechnungen durchführen.

Kehren wir zu unserer Kundentabelle zurück. Stellen Sie sich vor, Sie möchten die Kunden nach ihrem Schuldenstand bei Ihnen klassifizieren:

• $0: Keine
• Bis zu $500: Niedrig
• $500 bis $1000: Mittel
• Über $1000: Hoch

Dies können Sie durch „Verschachtelung“ von WENN-Anweisungen erreichen:

=WENN(C4=0;"Keine";WENN(C4<=500;"Niedrig";WENN(C4<=1000;"Mittel";WENN(C4>1000;"Hoch"))))

Es ist leichter zu verstehen, wenn Sie die WENN-Anweisungen in separate Zeilen setzen (ALT + ENTER unter Windows, STRG + COMMAND + ENTER auf Macs):

=
WENN(C4=0; "Keine";
WENN(C4<=500; "Niedrig";
WENN(C4<=1000;"Mittel",
WENN(C4>1000;"Hoch"; "Unbekannt"))))

WENN C4 gleich 0 ist, geben wir „Keine“ zurück. Andernfalls gehen wir zur nächsten WENN-Anweisung über. WENN C4 gleich oder kleiner als 500 ist, geben wir „Niedrig“ zurück. Andernfalls gehen wir zur nächsten WENN-Anweisung über… und so weiter.

Komplexe WENN-Anweisungen mit Hilfsspalten vereinfachen

Wenn Sie mehrere verschachtelte WENN-Anweisungen haben und auch noch Logikfunktionen einbauen, können Ihre Formeln sehr schwer zu lesen, zu testen und zu aktualisieren sein.

Dies ist besonders wichtig, wenn andere Personen die Kalkulationstabelle verwenden werden. Was in Ihrem Kopf Sinn macht, ist für andere vielleicht nicht so offensichtlich.

Hilfsspalten sind eine gute Möglichkeit, dieses Problem zu umgehen.

Sie sind ein Analyst in der Finanzabteilung eines großen Unternehmens. Sie wurden gebeten, eine Tabelle, die prüft, ob jeder Mitarbeiter Anspruch auf eine Betriebsrente hat, zu erstellen.

Hier sind die Kriterien:

Wenn Sie unter 55 Jahren sind, müssen Sie 30 Dienstjahre nachweisen, um in Frage zu kommen. Wenn Sie zwischen 55 und 59 Jahre alt sind, brauchen Sie 15 Dienstjahre. Und so weiter bis zum Alter von 65 Jahren, bei dem man unabhängig von der Dauer der Betriebszugehörigkeit berechtigt ist.

Sie könnten dieses Problem mit einer einzigen, komplexen WENN-Anweisung lösen:

=WENN(ODER(F4>=65;UND(F4>=62;G4>=5);UND(F4>=60;G4>=10);UND(F4>=55;G4>=15);G4>30);"Berechtigt"; 
  "Nicht berechtigt")

Uff! Das ist schwer zu nachvollziehen, nicht wahr?

Ein besserer Ansatz könnte die Verwendung von Hilfsspalten sein. Wir haben hier fünf logische Prüfungen, die jeder Zeile in der Kriterientabelle entsprechen. Dies ist leichter zu erkennen, wenn wir die Formel mit Zeilenumbrüchen versehen, wie wir bereits besprochen haben:

=WENN(
ODER(
F4>=65;
UND(F4>=62;G4>=5);
UND(F4>=60;G4>=10);
UND(F4>=55;G4>=15);
G4>30
); "Berechtigt"; "Nicht berechtigt")

So können wir diese fünf Prüfungen in separate Spalten aufteilen und dann einfach prüfen, ob eine von ihnen wahr ist:

Jede Spalte in der Tabelle von E bis I enthält jedes unserer Kriterien separat. Dann haben wir in J4 die folgende Formel:

=WENN(ZÄHLENWENN(E4:I4;WAHR); "Berechtigt"; "Nicht berechtigt")

Hier haben wir eine WENN-Anweisung, und der logische Test verwendet ZÄHLENWENN, um die Anzahl der Zellen in E4:I4 zu zählen, die WAHR enthalten.

Wenn ZÄHLENWENN keinen WAHR-Wert findet, gibt sie 0 zurück, was von WENN als FALSCH interpretiert wird, so dass WENN „Nicht berechtigt“ zurückgibt.

Findet ZÄHLENWENN einen WAHR-Wert, gibt sie die Anzahl der WAHR-Werte zurück. WENN interpretiert jede andere Zahl als 0 als WAHR und gibt daher „Berechtigt“ zurück.

Die Aufteilung der logischen Prüfungen auf diese Weise macht die Formel leichter lesbar und wenn etwas schief läuft, ist es viel einfacher, den Fehler zu finden.

Gruppierung verwenden, um Hilfsspalten auszublenden

Hilfsspalten erleichtern die Verwaltung der Formel, aber wenn man sie einmal eingerichtet hat und weiß, dass sie richtig funktionieren, nehmen sie oft nur Platz in der Tabelle weg, ohne nützliche Informationen zu liefern.

Sie könnten die Spalten ausblenden, aber das kann zu Problemen führen, weil ausgeblendete Spalten nur schwer zu erkennen sind, es sei denn, Sie schauen sich die Spaltenüberschriften genau an.

Eine bessere Möglichkeit ist die Gruppierung.

Markieren Sie die Spalten, die Sie gruppieren möchten, in unserem Fall E:I. Drücken Sie dann ALT + UMSCHALTTASTE + RECHTSPFEIL unter Windows oder COMMAND + UMSCHALTTASTE + K  unter Mac. Sie können auch zur Hauptregisterkarte „Daten“ in der Menüsleiste gehen und „Gruppieren“ aus dem Abschnitt „Gliederung“ wählen.

Die Gruppierung wird dann oberhalb der Spaltenüberschriften folgendermaßen angezeigt:

Drücken Sie dann einfach auf die Schaltfläche „-„, um die Spalten auszublenden:

Die WENNS-Funktion

Verschachtelte WENN-Anweisungen sind sehr nützlich, wenn Sie komplexere logische Vergleiche durchführen und dies in einer Zelle tun müssen. Sie können jedoch kompliziert werden, wenn sie länger werden, und sie können auf dem Bildschirm schwer zu lesen und zu aktualisieren sein.

Ab Excel 2019 und Excel 365 hat Microsoft eine weitere Funktion namens WENNS eingeführt, um diese Aufgabe etwas einfacher zu gestalten. Das obige verschachtelte WENN-Beispiel könnte mit WENNS wie folgt realisiert werden:

=WENNS(
C4=0; "Keine",
C4<=500; "Niedrig";
C4<=1000; "Mittel";
C4>1000; "Hoch";
WAHR; "Unbekannt";
)

Alles dazu können Sie auf der Hauptseite der Excel-Funktion WENNS <<link>> nachlesen.

WENN mit bedingter Formatierung verwenden

Mit der Excel-Funktion „Bedingte Formatierung“ können Sie eine Zelle je nach ihrem Inhalt auf unterschiedliche Weise formatieren. Da die WENN-Funktion auf Grundlage unserer logischen Prüfung unterschiedliche Werte zurückgibt, möchten wir vielleicht die bedingte Formatierung mit der WENN-Funktion verwenden, um diese unterschiedlichen Werte besser sichtbar zu machen.

Kehren wir also zu unserer Tabelle mit den Mitarbeiterprämien von vorhin zurück.

Wir antworten mit „Ja“ oder „Nein“, je nachdem, welchen Bonus wir geben wollen. Das sagt uns, was wir wissen müssen, aber die Information springt uns nicht ins Auge. Versuchen wir, das zu ändern.

So würden Sie es machen:

• Wählen Sie den Zellenbereich aus, der Ihre WENN-Anweisungen enthält. In unserem Fall ist das E4:F8.
• Klicken Sie auf „Bedingte Formatierung“ im Abschnitt „Formatvorlagen“ auf der Hauptregisterkarte „Start“ im Menüband.
• Klicken Sie auf „Regeln zum Hervorheben von Zellen“ und dann auf „Gleich“.
• Geben Sie „Ja“ (oder den gewünschten Rückgabewert) in das erste Feld ein, und wählen Sie dann die gewünschte Formatierung aus dem zweiten Feld. (Ich wähle hier grün).
• Wiederholen Sie diesen Vorgang für alle Rückgabewerte (ich setze Nein-Werte auf rot)

Hier ist das Ergebnis:

WENN in Array-Formeln verwenden

Ein Array ist ein Bereich von Werten und in Excel werden diese als durch Semikolon getrennte in geschweiften Klammern eingeschlossene Werte dargestellt, wie z. B.:

{1;2;3;4;5}

Das Schöne an Arrays ist die Tatsache, dass sie es Ihnen ermöglichen, mit jedem Wert im Bereich eine Berechnung durchzuführen und dann das Ergebnis zurückzugeben. Die SUMMENPRODUKT-Funktion zum Beispiel nimmt zwei Arrays, multipliziert sie miteinander und summiert die Ergebnisse.

Also diese Formel:

=SUMMENPRODUKT({1;2;3};{4;5;6})

…gibt 32 zurück. Und warum? Lassen Sie uns es durchgehen:

1 * 4 = 4
2 * 5 = 10
3 * 6 = 18

4 + 10 + 18 = 32

Wir können eine WENN-Anweisung in dieses Bild einbringen, so dass jede dieser Multiplikationen nur dann stattfindet, wenn ein logische Prüfung WAHR ergibt.

Nehmen wir zum Beispiel diese Daten:

Wenn Sie die Gesamtprovision für jeden Sales Manager berechnen wollten, würden Sie Folgendes verwenden:

=SUMMENPRODUKT(WENN($C$2:$C$10=$G2;$D$2:$D$10*$E$2:$E$10))

Hinweis: In Excel 2019 und früher müssen Sie STRG + UMSCHALTTASTE + ENTER drücken, um dies in eine Array-Formel zu verwandeln.

Das Ergebnis wäre dann etwa so:

Die Spalte „Manager“ ist die Spalte C und in diesem Beispiel steht Olivias Name in G2.

Die logische Prüfung lautet also:

$C$2:$C$10=$G2

Wenn der Name in Spalte C gleich dem Namen in G2 („Olivia“) ist, müssen die Werte in den Spalten D und E für diese Zeile multipliziert werden. Andernfalls werden sie nicht multipliziert. Dann werden alle Ergebnisse summiert.

Weitere Informationen zu dieser Formel finden Sie auf der Hauptseite der SUMMENPRODUKT-WENN-Formel.

WENN in Google Sheets

Die WENN-Funktion funktioniert in Google Sheets genau so wie in Excel:

WENN-Anweisungen in VBA

Sie können auch If-Anweisungen in VBA verwenden. Klicken Sie auf den Link, um mehr zu erfahren, aber hier ist ein einfaches Beispiel:

Sub Test_IF ()

   If Range("a1").Value < 0 Then
      Range("b1").Value = "Negativ"
   End If

End Sub

Dieser Code prüft, ob der Wert einer Zelle negativ ist. Wenn ja, wird der Text „Negativ“ in die nächste Zelle geschrieben.