TEXTVERKETTEN WENN – Excel und Google Sheets

In diesem Tutorial zeigen wir Ihnen, wie Sie Zellenwerte mit der TEXTVERKETTEN-Funktion in Excel und Google Sheets anhand von Kriterien miteinander verbinden können.

Die TEXTVERKETTEN-Funktion

Benutzer von Excel 2019+ haben Zugriff auf die TEXTVERKETTEN-Funktion, mit der mehrere Textzeichenfolgen zusammengefügt werden können, wobei jede Zeichenfolge durch ein bestimmtes Trennzeichen getrennt wird.

Hinweis: Benutzer von Google Sheets können die TEXTJOIN-Funktion verwenden, haben aber eine etwas andere Weise, Array-Formeln einzugeben. Siehe den späteren Abschnitt zu diesem Thema.

In diesem Beispiel werden die Funktionen TEXTVERKETTEN und WENN in einer Array-Formel verwendet, um eine durch Komma getrennte Textfolge von Spielernamen, die sich auf einen Team-Wert von Rot beziehen, zu erstellen.

=TEXTVERKETTEN(", ";WAHR;(WENN(C3:C8="Rot";B3:B8;"")))

Benutzer von Excel 2019 müssen diese Formel als Array-Funktion eingeben, indem sie STRG + UMSCHALTTASTE + ENTER drücken. Benutzer späterer Excel-Versionen müssen diesen Schritt nicht ausführen.

Um zu erklären, was diese Formel tut, sollten wir sie in einzelne Schritte zerlegen:

Dies ist unsere endgültige Formel:

=TEXTVERKETTEN(", ";WAHR;(WENN(C3:C8="Rot";B3:B8;"")))

Zunächst werden die Werte des Zellenbereichs in die Formel eingefügt:

=TEXTVERKETTEN(", ";WAHR;WENN({"Rot"; "Blau"; "Blau"; "Rot"; "Blau"; "Rot"}="Rot";{"A"; "B"; "C"; "D"; "E"; "F"};""))

Als nächstes wird die Liste der Team-Namen mit dem Wert Rot verglichen:

=TEXTVERKETTEN(", ";WAHR;WENN({WAHR; FALSCH; FALSCH; WAHR; FALSCH; WAHR};{"A"; "B"; "C"; "D"; "E"; "F"};""))

Die WENN-Funktion ersetzt WAHR-Werte durch den Spielernamen und FALSCH-Werte durch „“

=TEXTVERKETTEN(", ";WAHR;{"A"; ""; ""; "D"; ""; "F"})

Die Funktion TEXTVERKETTEN kombiniert dann alle Werte des Arrays zu einer einzigen Textzeichenfolge. Wir haben die Funktion angewiesen, leere Werte zu ignorieren und den Text „, “ zwischen den einzelnen Werten einzufügen. Dies ergibt das Endergebnis:

="A, D, F"

TEXTVERKETTEN WENN – vor Excel 2019

Da die TEXTVERKETTEN-Funktion vor der Excel-Version 2019 nicht verfügbar ist, müssen wir dieses Problem auf andere Weise lösen. Die Funktion VERKETTEN steht zwar zur Verfügung, kann aber keine Zellenbereiche als Eingaben akzeptieren oder Array-Operationen durchführen. Daher müssen wir stattdessen eine Hilfsspalte mit einer WENN-Funktion verwenden.

Das nächste Beispiel zeigt, wie eine Hilfsspalte verwendet wird, um eine durch Komma getrennte Textzeichenfolge von Spielernamen, die sich auf einen Team-Wert von Rot beziehen, zu erstellen:

=WENN(C3="Rot";B3&", ";"")&D4

Der erste Schritt in diesem Beispiel besteht darin, eine WENN-Funktion zu verwenden, um die Bedingung „Team = Rot “ zu replizieren. Wenn die Bedingung erfüllt ist, wird der Wert des Spielernamens gefolgt von dem gewählten Trennzeichen „, “ geschrieben:

=WENN(C3="Rot";B3&", ";"")

Als nächstes können wir eine Spalte, die eine Liste dieser Werte in einer Zelle zusammenfasst, erstellen, indem wir auch auf die Zelle darunter verweisen:

=D3&E4

Diese Formel verwendet das &-Zeichen, um zwei Werte miteinander zu verbinden. Beachten Sie, dass die Funktion VERKETTEN verwendet werden könnte, um genau das gleiche Ergebnis zu erzielen, aber die &-Methode wird oft bevorzugt, da sie kürzer ist und es deutlicher macht, welche Aktion die Formel durchführt.

Diese beiden Hilfsspalten können dann in einer Formel kombiniert werden:

=WENN(C3="Rot";B3&", ";"")&D4

Eine Zusammenfassende Zelle kann dann auf den ersten Wert in der Hilfsspalte Spielerliste verweisen:

=D3

Wenn der abschließende Wert von „,“ nicht benötigt wird, sollte der Formel eine zusätzliche verschachtelte WENN-Funktion hinzugefügt werden:

=WENN(C3="Rot"; WENN(D4=""; B3; B3&", "); "")&D4

Der zusätzliche Teil der Formel ist die folgende WENN-Funktion:

=WENN(D4="";B3;B3&", ")

Dieser Teil der Formel prüft den Wert der Zelle darunter. Wenn sie leer ist, muss diese der letzte Spielername in der Liste sein und der Name wird ohne Trennzeichen geschrieben. Wenn sie einen Wert enthält, dann ist diese Zelle nicht der letzte Spielername in der Liste und das Trennzeichen „,“ wird hinzugefügt.

TEXTVERKETTEN WENN – Google Sheets

Diese Formeln funktionieren in Google Sheets genauso wie in Excel mit der Ausnahme, dass die Funktion ARRAYFORMULA in Google Sheets verwendet werden muss, um die Ergebnisse korrekt auszuwerten. Diese können Sie automatisch durch Drücken von STRG + UMSCHALTTASTE + ENTER hinzufügen, während Sie die Formel bearbeiten (oder einfach manuell hinzufügen):

=ArrayFormel(TEXTJOIN(", ";WAHR;(WENN(C3:C8="Rot";B3:B8;""))))

Hinweis: Die TEXTJOIN-Funktion behält ihre englische Bezeichnung auch in der deutschen Version von Google Sheets bei, d. h. Sie erhalten einen Fehler wenn Sie stattdessen TEXTVERKETTEN eingeben.