Dieses Tutorial zeigt Ihnen, wie Sie Text und Zahlen von einer alphanumerischen Zeichenkette in Excel und Google Sheets trennen können.

Zahlen und Text von einer Zeichenkette trennen

In diesem Artikel erfahren Sie, wie Sie Zahlen und Text trennen können, wenn Sie alphanumerische Daten haben, bei denen der erste Teil aus Text und der letzte Teil Zahlen besteht (oder umgekehrt), und Sie nur den Zahlenteil benötigen. Für komplexere Fälle siehe den Artikel Nicht-numerische Zeichen entfernen.

Zahl von rechts extrahieren

Am einfachsten ist es, Zahlen aus einer Zeichenkette zu extrahieren, wenn diese am rechten Ende der Zeichenkette zu finden sind. Zuerst suchen wir die Anfangsposition der Zahl mit der Funktion FINDEN und extrahieren sie dann mit der Funktion RECHTS.

=RECHTS(B3;LÄNGE(B3)-MIN(FINDEN({0;1;2;3;4;5;6;7;8;9};B3&"0123456789"))+1)

Gehen wir die obige Formel durch.

Erste Zahl finden

Wir können die Funktion FINDEN verwenden, um die Anfangsposition der Zahl zu ermitteln.

=MIN(FINDEN({0;1;2;3;4;5;6;7;8;9};B3&"0123456789"))

Für das Argument Suchtext der Funktion FINDEN wird die Array-Konstante {0;1;2;3;4;5;6;7;8;9} verwendet, so dass die Funktion FINDEN für jeden Wert in dieser Array-Konstante eine eigene Suche durchführt.

Das Argument Text der FINDEN-Funktion ist der Zellenwert & „0123456789“. In unserem Beispiel: „Montag010123456789“.

Da die Array-Konstante 10 Zahlen enthält, wird das Ergebnis ein Array mit 10 Werten sein. In unserem Beispiel: {7;8;11;12;13;14;15;16;17;18}. Dann suchen wir einfach nach dem Minimum der Zahlenpositionen innerhalb dieses Arrays und erhalten somit die Stelle der ersten Zahl.

Zahlenteil extrahieren

Sobald wir die Anfangsposition der Zahl am Ende unserer alphanumerischen Zeichenkette gefunden haben, können wir die Funktion RECHTS verwenden, um sie zu extrahieren:

=RECHTS(B3;LÄNGE(B3)-C3+1)

Textteil extrahieren

Mit der Anfangsposition des Zahlenteils können wir gleichzeitig das Ende des Textteils bestimmen. Wir können die Funktion LINKS verwenden, um ihn zu extrahieren:

=LINKS(B3;C3-1)

Zahl von links extrahieren

Ein komplizierterer Fall des Extrahierens von Zahlen aus einer Zeichenkette ist es, wenn die Zahl am Anfang (d. h. auf der linken Seite) der Zeichenkette zu finden ist. Offensichtlich muss man nicht die Anfangsposition finden, sondern die Position, an der sie endet. Zuerst wird die Position der letzten Zahl mit Hilfe der Funktion WECHSELN ermittelt und dann die Zahl mit der Funktion LINKS extrahiert:

=LINKS(B3;SUMME(LÄNGE(B3)-LÄNGE(WECHSELN(B3;{"0";"1";"2";"3";"4";"5";"6";"7";"8";"9"};""))))

Gehen wir die obige Formel durch.

Letzte Zahl finden

Mit der Funktion WECHSELN können Sie jede Zahl einzeln durch eine leere Zeichenfolge ersetzen und dann zusammenzählen, wie oft Sie dies tun mussten.

=SUMME(LÄNGE(B3)-LÄNGE(WECHSELN(B3;{"0";"1";"2";"3";"4";"5";"6";"7";"8";"9"};"")))

Wenn Sie jede Zahl einzeln durch eine leere Zeichenkette ersetzen, erhalten Sie jedes Mal eine Zeichenkette, deren Länge um eins kleiner als die ursprüngliche Länge ist. In unserem Fall ist die Länge von 1-Montag und 0-Montag jeweils 8. Subtrahiert man diese Länge von der ursprünglichen Länge (in unserem Fall 9), erhält man immer 1. Wenn Sie diese addieren, erhalten Sie die Position Ihrer letzten Zahl.

Zahlenteil extrahieren

Sobald wir die letzte Position der Zahl am Anfang unserer alphanumerischen Zeichenfolge gefunden haben, können wir die Funktion LINKS verwenden, um sie zu extrahieren.

=LINKS(B3;C3)

Textteil extrahieren

Da wir die letzte Position der Zahl am Anfang unserer alphanumerischen Zeichenkette gefunden haben, haben wir bereits die Anfangsposition unseres Textteils und können die Funktion RECHTS verwenden, um ihn zu extrahieren.

=RECHTS(B3;LÄNGE(B3)-C3)

Text und Zahlen in Google Sheets trennen

Alle oben erläuterten Beispiele funktionieren in Google Sheets genauso wie in Excel.