Summe, wenn eine Zelle einen spez. Text enthält (Platzhalter verwenden) – Excel & GS

In diesem Tutorial zeigen wir Ihnen, wie Sie Platzhalter mit der Funktion SUMMEWENNS in Excel und Google Sheets verwenden können, um Zellendaten, die einen bestimmten Text enthalten, zu summieren.

Summieren, wenn ein bestimmter Text enthalten ist

Die SUMMEWENNS-Funktion summiert Datenzeilen, die bestimmte Kriterien erfüllen. Ihre Syntax lautet:

In diesem Beispiel werden mit der SUMMEWENNS-Funktion und dem Platzhalterzeichen * alle Werte, deren Staatsname „Dakota“ enthält, summiert.

=SUMMEWENNS(C3:C9;B3:B9;"*Dakota*")

Das Zeichen * kann durch eine beliebige Anzahl (einschließlich Null) anderer Zeichen ersetzt werden.

Dieses Beispiel findet alle Zellen, die „Dakota“ enthalten. Bei dieser Suche wird nicht zwischen Groß- und Kleinschreibung unterschieden, d. h. „dakota“ ist dasselbe wie „Dakota“ oder „DAKOTA“.

Summe, wenn der Text mit einer angegebenen Zeichenfolge beginnt

Das Zeichen * kann auch verwendet werden, um nach Zellen, die mit einem angegebenen Text beginnen, zu suchen:

=SUMMEWENNS(C3:C9;B3:B9;"New*")

New York, New Jersey und New Mexico beginnen mit „New“ und sind daher in der Summe enthalten. Beachten Sie, dass die Textzelle bei dem Suchbegriff „New*“ mit „New“ beginnen muss. Es reicht nicht aus, wenn sie diese Zeichen enthält.

Summe, wenn der Text mit einer angegebenen Zeichenfolge endet

Auf ähnliche Weise können wir alle Ergebnisse für Staaten, die mit „o“ enden, summieren:

=SUMMEWENNS(C3:C9;B3:B9;"*o")

New Mexico und Ohio enden mit „o“ und sind daher in der Summe enthalten.

Verwendung des ?-Platzhalterzeichens

Das Zeichen ? kann verwendet werden, um ein beliebiges einzelnes Zeichen in einer Textzeichenfolge darzustellen.

Dieses Beispiel findet alle Staatsnamen, die mit „New“,  gefolgt von genau 7 Zeichen (einschließlich Leerzeichen), beginnen.

=SUMMEWENNS(C3:C9;B3:B9;"New???????")

New Jersey und New Mexico erfüllen diese Kriterien. New York erfüllt sie jedoch nicht, da nur 5 Zeichen auf „New“ in New York folgen.

Beachten Sie, dass die Platzhalterzeichen * und ? bei Bedarf kombiniert werden können, um sehr spezifische Suchbefehle zu erstellen. Das nächste Beispiel findet Staatsnamen, die mit „N“ beginnen und ein „o“ vor dem letzten Zeichen der Zeichenkette enthalten. Dies schließt New Mexico aus, denn es beginnt mit „N“, hat aber kein „o“ vor dem letzten Zeichen.

=SUMMEWENNS(C3:C9;B3:B9;"N*o?*")

Diese Funktion ist besonders nützlich bei der Suche nach Produktcodes, Postleitzahlen oder Seriennummern, bei denen die Position der einzelnen Zeichen eine bestimmte Bedeutung hat.

Verwendung des Zeichens ~ (Tilde)

Mit dem Sonderzeichen ~ ( Tilde) können wir die Zeichen * und ? so behandeln, als wären sie einfache Textwerte und nicht als Platzhalter zu verwenden.

Im folgenden Beispiel soll der Lagerbestand summiert werden, wenn der Produktname genau mit dem Text „Produkt ?“ übereinstimmt:

=SUMMEWENNS(C3:C8;B3:B8;"Produkt ~?")

Das ~ unmittelbar vor einem Sternchen (*) oder einem Fragezeichen (?) verwandelt es wieder in einen Textwert, so dass der Suchbegriff „Produkt ~?“ verwendet wird, um eine genaue Textübereinstimmung mit „Produkt ?“ zu finden.

Kombinieren von SUMMEWENNS-Platzhaltern mit Zellenbezügen

In der Regel ist es keine gute Praxis, Werte in Formeln „hart“ zu kodieren. Stattdessen ist es flexibler, separate Zellen zu verwenden, um Werte für unsere Suchbegriffe anzugeben.

Um zu suchen, ob die Zellen den in Zelle E3 enthaltenen Text enthalten, können wir die SUMMEWENNS-Funktion mit einem Zellenbezug und * Platzhaltern verwenden:

=SUMMEWENNS(C3:C9;B3:B9;"*"&E3&"*")

Beachten Sie, dass der Text „Dakota“ durch den Zellenbezug &E3& ersetzt wurde und die Zeichen * in Anführungszeichen (“ „) gesetzt wurden.

Es können auch mehrere Zellenbezüge und Platzhalterzeichen miteinander kombiniert werden. Um Namen von Bundesstaaten, die mit dem Text in Zelle E3 beginnen und den Text in Zelle F3, gefolgt von mindestens einem weiteren Zeichen, enthalten, zu finden, kann die folgende Formel verwendet werden:

=SUMMEWENNS(C3:C9;B3:B9;E3&"*"&F3&"?*")

Zellenbezüge sperren

Um unsere Formeln besser lesbar zu machen, haben wir die Formeln ohne gesperrte Zellbezüge dargestellt:

=SUMIFS(C3:C9,B3:B9,"*"&E3&"*")

Diese Formeln funktionieren jedoch nicht richtig, wenn sie kopiert und an anderer Stelle in Ihrer Datei eingefügt werden. Stattdessen sollten Sie gesperrte Zellenbezüge wie die folgenden verwenden:

=SUMMEWENNS($C$3:$C$9;$B$3:$B$9;"*"&E3&"*")

Lesen Sie unseren Artikel über das Sperren von Zellenbezügen, um mehr zu erfahren.

Summe, wenn die Zelle einen bestimmten Text enthält (mit Platzhaltern) – Google Sheets

Diese Formeln funktionieren in Google Sheets genau so wie in Excel.