SUMME-WENN nach Monat – Excel & Google Sheets

---

In diesem Tutorial zeigen wir Ihnen, wie Sie die SUMMEWENNS-Funktion verwenden können, um die Daten aus bestimmten Monaten in Excel und Google Sheets zu summieren.

 

Summe nach Monat

Zunächst zeigen wir, wie Daten, die in einen bestimmten Monat und ein bestimmtes Jahr fallen, summiert werden.

Wir können die SUMMEWENNS-Funktion zusammen mit den Funktionen DATUM, JAHR, MONAT und MONATSENDE verwenden, um die Anzahl der Verkäufe in jedem Monat zu summieren.

=SUMMEWENNS(C3:C9;B3:B9;">="&DATUM(JAHR(E3);MONAT(E3);1);B3:B9;"<="&MONATSENDE(E3;0))

Um die obige Formel zu erstellen, müssen wir zunächst den Datumsbereich für jeden Monat definieren. Wir verwenden die DATUM-Funktion, um den ersten Tag des Monats zu definieren (z.B. 01.05.2021). Dazu können wir das Datum in die Formel „hartkodieren“:

">="&DATUM(2021;5;1)

Oder, noch besser, wir können die Kriterien wie im obigen Beispiel gezeigt flexibel gestalten, indem wir auf ein Datum in der Zelle E3 verweisen, das Jahr und den Monat des Datums extrahieren (und den Tag gleich 1 setzen):

">="&DATUM(JAHR(E3);MONAT(E3);1)

Um den letzten Tag des Monats zu definieren, können wir die MONATSENDE-Funktion verwenden:

"<="&MONATSENDE(E3;0)

Wenn wir alle diese Kriterien zusammenfassen, können wir die folgende SUMMEWENNS-Formel schreiben:

=SUMMEWENNS(C3:C9;B3:B9;">="&DATUM(JAHR(E3);MONAT(E3);1);B3:B9;"<="&MONATSENDE(E3;0))

Zellenbezüge sperren

Um unsere Formeln besser lesbar zu machen, haben wir sie ohne gesperrte Zellenbezüge dargestellt:

=SUMMEWENNS(C3:C9;B3:B9;">="&DATUM(JAHR(E3);MONAT(E3);1);B3:B9;"<="&MONATSENDE(E3;0))

Diese Formeln funktionieren jedoch nicht richtig, wenn sie kopiert und an anderer Stelle in Ihrer Datei eingefügt werden. Stattdessen sollten Sie gesperrte Zellenverweise wie die folgenden verwenden:

=SUMMEWENNS($C$3:$C$9;$B$3:$B$9;">="&DATUM(JAHR(E3);MONAT(E3);1);$B$3:$B$9;"<="&MONATSENDE(E3;0))

Lesen Sie unseren Artikel über das Sperren von Zellenbezügen, um mehr zu erfahren.

Monatswerte formatieren

In diesem Beispiel haben wir Monate in Spalte E aufgelistet. Diese Monatswerte sind eigentlich Datumsangaben, die mit Hilfe der benutzerdefinierten Zahlenformatierung so formatiert sind, dass der Tag weggelassen wird.

Um den Mai 2021 anzuzeigen, lautet das benutzerdefinierte Datenformat „MMM JJJJ“.

 

Summe nach Monat über mehrere Jahre

Im obigen Beispiel wurden Daten mit Datumsangaben, die in einen bestimmten Monat und ein bestimmtes Jahr fallen, aufsummiert. Stattdessen können Sie Daten mit Datumsangaben, die in einen bestimmten Monat in allen beliebigen Jahren fallen, durch Verwendung der SUMMENPRODUKT-Funktion aufsummieren.

=SUMMENPRODUKT(C3:C8;--(MONAT(B3:B8)=MONAT(E3)))

In diesem Beispiel verwenden wir die SUMMENPRODUKT-Funktion, um komplizierte SUMME-WENN-Berechnungen durchzuführen. Lassen Sie uns die Formel durchgehen.

Dies ist unsere endgültige Formel:

=SUMMENPRODUKT(C3:C8;--(MONAT(B3:B8)=MONAT(E3)))

Zunächst listet die SUMMENPRODUKT-Funktion die Anzahl der Verkäufe für jedes Verkaufsdatum auf und vergleicht dann den Monat jedes Verkaufsdatums mit dem angegebenen Monat und gibt WAHR zurück, wenn die Monate übereinstimmen oder FALSCH, wenn sie nicht übereinstimmen:

=SUMMENPRODUKT({30;42;51;28;17;34};--({WAHR;FALSCH;WAHR;FALSCH;WAHR;FALSCH}))

Anschließend wandeln die Doppelstriche (–) die Werte WAHR und FALSCH in Einsen und Nullen um:

=SUMMENPRODUKT({30;42;51;28;17;34};{1;0;1;0;1;0})

Die SUMMENPRODUKT-Funktion multipliziert dann jedes Paar von Einträgen in den Arrays:

=SUMMENPRODUKT({30;0;51;0;17;0})

Schließlich werden die Zahlen in der Matrix summiert:

=98

Weitere Einzelheiten über die Verwendung boolescher Anweisungen und des Befehls „–“ in einer SUMMENPRODUKT-Funktion finden Sie hier

SUMME-WENN nach Monat in Google Sheets

Die o. g. Formeln funktionieren in Google Sheets genau so wie in Excel.