Summe wenn leer – Excel & Google Sheets

In diesem Tutorial zeigen wir Ihnen, wie Sie die Funktion SUMMEWENNS in Excel und Google Sheets verwenden können, um Daten, die leeren Zellen entsprechen, zu summieren.

Summe wenn leer

Zunächst zeigen wir Ihnen, wie Sie Zeilen mit leeren Zellen summieren können.

Die Funktion SUMMEWENNS summiert Daten, die bestimmte Kriterien erfüllen.

Im folgenden Beispiel können wir die Funktion SUMMEWENNS verwenden, um alle Punktzahlen von Spielern ohne Namen zu summieren.

=SUMMEWENNS(C3:C8;B3:B8;"")

Wir verwenden doppelte Anführungszeichen („“), um eine leere Zelle in Excel darzustellen. In unserem Beispiel werden die Spieler A, B, C und D ignoriert und die Punktzahlen der unbekannten Spieler summiert.

Behandlung von Leerzeichen als leere Zellen (mit Hilfsspalte)

Bei der Interaktion mit leeren Zellen in Excel müssen Sie vorsichtig sein. Zellen können für Sie leer erscheinen, aber Excel behandelt sie nicht als leer. Dies kann der Fall sein, wenn die Zelle Leerzeichen, Zeilenumbrüche oder andere unsichtbare Zeichen enthält. Dies ist ein häufiges Problem beim Importieren von Daten aus anderen Quellen in Excel.

Wenn wir Zellen, die nur Leerzeichen enthalten, so behandeln müssen, als wären sie leer, dann funktioniert die Formel im vorherigen Beispiel nicht. Beachten Sie, dass die SUMMEWENNS-Formel die Zelle B9 unten (“ „) nicht als leeres Feld betrachtet:

Um eine Zelle, die nur Leerzeichen enthält, so zu behandeln, als wäre sie eine leere Zelle, können wir eine Hilfsspalte mit der GLÄTTEN-Funktion hinzufügen, um die zusätzlichen Leerzeichen aus den Werten der einzelnen Zellen zu entfernen:

=GLÄTTEN(B3)

Wir wenden die Funktion SUMMEWENNS auf die Hilfsspalte an und sie berechnet nun die Summe genau.

=SUMMEWENNS(E3:E9;D3:D9;"")

Die Hilfsspalte ist einfach zu erstellen und leicht zu lesen, aber vielleicht möchten Sie eine einzige Formel haben, um die Aufgabe zu erfüllen. Dies wird im nächsten Abschnitt behandelt.

Behandlung von Leerzeichen als leere Zellen (ohne Hilfsspalte)

Wenn eine Hilfsspalte für Ihre Zwecke nicht geeignet ist, können Sie die Funktion SUMMENPRODUKT in Kombination mit den Funktionen LÄNGE und GLÄTTEN verwenden, um leere Zeilen zu summieren.

=SUMMENPRODUKT(--(LÄNGE(GLÄTTEN(B3:B9))=0);D3:D9)

In diesem Beispiel verwenden wir die SUMMENPRODUKT-Funktion, um eine komplizierte Summe-wenn-Berechnung durchzuführen. Lassen Sie uns die Formel durchgehen.

Dies ist unsere endgültige Formel:

=SUMMENPRODUKT(--(LÄNGE(GLÄTTEN(B3:B9))=0);D3:D9)

Zunächst listet die SUMMENPRODUKT-Funktion die Werte aus den beiden Zellenbereichen auf:

=SUMMENPRODUKT(--(LÄNGE(GLÄTTEN({"A"; "B"; ""; "C"; ""; "XX"; ""}))=0);{25; 10; 15; 5; 8; 17; 50})

Anschließend werden führende und nachfolgende Leerzeichen mit der GLÄTTEN-Funktion aus den Spielernamen entfernt:

=SUMMENPRODUKT(--(LÄNGE({"A"; "B"; ""; "C"; ""; "XX"; ""})=0);{25; 10; 15; 5; 8; 17; 50})

Die Funktion LÄNGE berechnet die Längen der gekürzten Spielernamen:

=SUMMENPRODUKT(--({1; 1; 0; 1; 0; 2; 0}=0);{25; 10; 15; 5; 8; 17; 50})

Mit dem logischen Test (=0) werden alle gekürzten Spielernamen mit 0 Zeichen in WAHR geändert:

=SUMMENPRODUKT(--({FALSCH; FALSCH; WAHR; FALSCH; WAHR; FALSCH; WAHR});{25; 10; 15; 5; 8; 17; 50})

Anschließend wandeln die Doppelstriche (–) die Werte WAHR und FALSCH in Einsen und Nullen um:

=SUMMENPRODUKT({0; 0; 1; 0; 1; 0; 1};{25; 10; 15; 5; 8; 17; 50})

Die Funktion SUMMENPRODUKT multipliziert dann jedes Paar von Einträgen in den Arrays, um ein Array von Punktzahlen nur für Spielernamen, die leer sind oder nur aus Leerzeichen bestehen, zu erzeugen:

=SUMMENPRODUKT({0; 0; 15; 0; 8; 0; 50})

Schließlich werden die Zahlen in der Matrix summiert:

=73

Weitere Details zur Verwendung boolescher Anweisungen und des Befehls „–“ in einer SUMMENPRODUKT-Funktion finden Sie hier.

Summe wenn leer – Google Sheets

Diese Formeln funktionieren in Google Sheets genau so wie in Excel.