SUMME mit einer SVERWEIS-Funktion – Excel & Google Sheets

In diesem Tutorial zeigen wir Ihnen, wie Sie die Ergebnisse mehrerer SVERWEIS-Funktionen in einer Formel in Excel und Google Sheets summieren können.

SUMME mit SVERWEIS

Mit der SVERWEIS-Funktion können Sie einen einzelnen Wert nachschlagen. Wenn Sie jedoch eine Array-Formel erstellen, können Sie mehrere Werte auf einmal nachschlagen und summieren.

In diesem Beispiel wird gezeigt, wie man den Gesamtumsatz einer bestimmten Filiale über 3 Monate berechnet, indem man eine Array-Funktion mit SUMME und SVERWEIS verwendet:

=SUMME(SVERWEIS(P3;B3:N6;{2;3;4};FALSCH))

Diese Array-Formel entspricht der Verwendung der folgenden drei regulären SVERWEIS-Funktionen, um die Umsätze für die Monate Januar, Februar und März zu summieren.

=SVERWEIS(P3;B3:N6;2;FALSCH)+SVERWEIS(P3;B3:N6;3;FALSCH)+SVERWEIS(P3;B3:N6;4;FALSCH)

Wir können diese Funktionen folgendermaßen miteinander kombinieren:

Zunächst legen wir die SVERWEIS-Funktion so fest, dass sie die Spalten 2, 3 und 4 als Array-Ausgabe zurückgibt (umgeben von geschweiften Klammern):

=SVERWEIS(P3;B3:N6;{2;3;4};FALSCH)

Dies wird das Array-Ergebnis erzeugen:

{98; 20; 76}

Um das Array-Ergebnis zu summieren, verwenden wir die SUMME-Funktion.

Wichtig! Wenn Sie Excel 2019 oder eine frühere Version verwenden, müssen Sie die Formel durch Drücken von STRG + UMSCHALTTASTE + ENTER eingeben, um die Array-Formel zu erstellen. Sie wissen, dass Sie dies richtig gemacht haben, wenn die geschweiften Klammern um die Formel herum erscheinen. In Excel 365 (oder neueren Versionen von Excel) ist dies nicht erforderlich.

Größere Array-Größen in einer SVERWEIS-Funktion verwenden

Wir können die Größe der Array-Eingabe erweitern, um mehr Daten darzustellen. Im folgenden Beispiel wird der Gesamtumsatz einer bestimmten Filiale für 12 Monate berechnet, indem eine Array-Funktion verwendet wird, die die Funktion SUMME enthält, um 12 Anwendungen der SVERWEIS-Funktion in einer Zelle zu kombinieren.

{=SUMME(SVERWEIS(P3;B3:N6;{2;3;4;5;6;7;8;9;10;11;12;13};FALSCH))}

Andere Zusammenfassungsfunktionen und SVERWEIS

Andere Zusammenfassungsfunktionen können auf die gleiche Weise wie die SUMME-Funktion verwendet werden, um alternative Zusammenfassungsstatistiken zu erstellen. Beispielsweise können wir die Funktionen MAX, MIN, MITTELWERT, MEDIAN, SUMME und ANZAHL verwenden, um die Umsätze von Januar bis März zusammenzufassen:

=MAX(SVERWEIS(J3;B3:H6;{2;3;4};FALSCH))

=MIN(SVERWEIS(J3;B3:H6;{2;3;4};FALSCH))

=MITTELWERT(SVERWEIS(J3;B3:H6;{2;3;4};FALSCH))

=MEDIAN(SVERWEIS(J3;B3:H6;{2;3;4};FALSCH))

=SUMME(SVERWEIS(J3;B3:H6;{2;3;4};FALSCH))

=ANZAHL(SVERWEIS(J3;B3:H6;{2;3;4};FALSCH))

Zellenbezüge sperren

Um unsere Formeln besser lesbar zu machen, haben wir die Formeln ohne gesperrte Zellenbezüge dargestellt:

=SUMME(SVERWEIS(P3;B3:N6;{2;3;4};FALSCH))

Diese Formeln funktionieren jedoch nicht richtig, wenn sie kopiert und an anderer Stelle in Ihrer Datei eingefügt werden. Stattdessen sollten Sie gesperrte Zellenverweise wie die folgenden verwenden:

{=SUMME(SVERWEIS(P3;$B$3:$N$6;{2;3;4};FALSCH))}

Lesen Sie unseren Artikel über das Sperren von Zellenbezügen, um mehr zu erfahren.

SUMME-SVERWEIS-Ergebnisse in Google Sheets

Diese Formeln funktionieren in Google Sheets genauso wie in Excel mit der Ausnahme, dass die ARRAYFORMULA-Funktion in Google Sheets verwendet werden muss, damit die Ergebnisse korrekt ausgewertet werden. Diese kann automatisch hinzugefügt werden, indem Sie die Tasten STRG + UMSCHALTTASTE + ENTER drücken, während Sie die Formel bearbeiten.

=ArrayFormula(SUMME(SVERWEIS(O2;A2:M5;{2;3;4};FALSCH)))