Geleistete Arbeitsstunden berechnen – Excel & Google Sheets

In diesem Tutorial zeigen wir Ihnen, wie Sie Arbeitsstunden in Excel und Google Sheets berechnen können.

 

Stunden mit einer einfachen Formel berechnen

In Excel werden Zeiten als Dezimalwerte gespeichert. Daher können Sie einfach die Startzeit („Arbeitsbeginn“) von der Endzeit („Arbeitsschluss“) subtrahieren, um die geleistete Arbeitszeit zu ermitteln.

Beachten Sie, dass wir mit 24 multiplizieren, um die Dezimalwerte in Stunden umzuwandeln.

=(D3-C3)*24

Im vorherigen Beispiel wurden die Zeiten als Dezimalwerte angezeigt, um zu zeigen, wie sie gespeichert werden. Dies geschah durch Änderung der Formatierung in „Zahl“:

 

Die REST-Funktion

Wenn die Endzeit vor der Startzeit liegt (z.B. Nachtschicht), gibt die Formel eine negative Zahl zurück. Um dieses Problem zu lösen, verwenden Sie die REST-Funktion.

=REST(D3-C3;1)*24

Wie bei der einfachen Formel müssen wir den mit der REST-Funktion berechneten Wert mit 24 multiplizieren, um die geleisteten Stunden zu erhalten.

Überstunden berechnen

Wir können die gleiche Formelart verwenden, um Überstunden zu berechnen.

Im obigen Beispiel beträgt die Standard-Arbeitszeit 8 Stunden.

Mit der folgenden Formel wird die normale Arbeitszeit des Tages berechnet.

=WENN((D3-C3)*24>$H$3;$H$3;(D3-C3)*24)

Wenn der Arbeitnehmer mehr als 8 Stunden gearbeitet hat, liefert die Formel nur maximal 8 Stunden. Um die Überstunden zu berechnen, können wir den Rest der geleisteten Stunden mit der folgenden Formel ermitteln:

=WENN((D3-C3)*24>$H$3;((D3-C3)*24)-$H$3;0)

Berechnen der geleisteten Stunden in einem wöchentlichen Arbeitszeitblatt

Wir können die Funktionen WENN, SUMME und MAX verwenden, um die wöchentlich geleisteten Arbeitsstunden aufgeschlüsselt nach regulärer Arbeitszeit und Überstunden zu berechnen.

Überstunden berechnen

Die Überstunden werden berechnet, sobald eine Person mehr als 40 Stunden pro Woche gearbeitet hat.

=WENN(SUMME($E$4:E4)>40;SUMME($E$4:E4)-40;0)

Der erste Teil des ersten Bereichs der SUMME-Funktion ist ein Absolutwert, der zweite Teil hingegen nicht. Wenn Sie diese Formel nach unten in die Tabelle kopieren, werden Sie feststellen, dass die SUMME-Funktion alle geleisteten Arbeitsstunden in Spalte E summiert. Wenn der Summenbereich wächst, erhöhen sich auch die geleisteten Arbeitsstunden. Sobald die SUMME mehr als 40 Stunden beträgt, werden die Überstunden in der Spalte „Überstunden“ als wachsende Summe eingetragen.

Berechnung der regulären Stunden

Die regulären Stunden werden auf Grundlage der Gesamtstunden und der geleisteten Überstunden berechnet.

=MAX(E4-G4;0)

Wir verwenden die MAX-Funktion, damit wir keine negativen Stunden erhalten, wobei der Mitarbeiter Überstunden geleistet hat, da die MAX-Funktion eine Null zurückgibt, wenn das Ergebnis negativ ist.

Die geleisteten Stunden in einem wöchentlichen Stundenzettel nach Projekt berechnen

Um die obige Berechnung noch einen Schritt voranzubringen, können wir mit Hilfe der SUMMEWENN-Funktion die geleisteten Stunden nach Projekten, an denen der Mitarbeiter gearbeitet hat, aufteilen.

=SUMMEWENN($H$4:$H$10;H5;$F$4:$F$10)

Die SUMMEWENN-Funktion summiert die regulären Stunden in Spalte F gemäß den in Spalte H ausgewählten Kriterien. Im obigen Fall sucht die Formel nach dem Projekt ABC und summiert die regulären Stunden dafür.

Berechnen von Arbeitsstunden in Google Sheets

Alle oben genannten Excel-Beispiele funktionieren in Google Sheets auf die gleiche Weise.