Adresse des höchsten Wertes im Bereich zurückgeben – Excel & GS

Written by

Editorial Team

Reviewed by

Steve Rynearson

Translated by

Zakarya El Oirzadi

Last updated on August 24, 2023

Beispielarbeitsmappe herunterladen

Die Beispielarbeitsmappe herunterladen

In diesem Tutorial zeigen wir Ihnen, wie Sie die Zellenadresse des höchsten Wertes in einem Zellenbereich in Excel und Google Sheets finden und verwenden können.

Adresse des höchsten Wertes im Bereich Hauptfunktion

Den höchsten Wert in einem Bereich ermitteln

Zunächst wird gezeigt, wie man den höchsten Wert in einem Zellenbereich mithilfe der MAX-Funktion ermittelt.

In diesem Beispiel wird der höchste Wert in einer Liste ermittelt:

=MAX(D3:D8)

höchsten Wert im Bereich mit MAX Funktion ermitteln

Weitere Informationen über den höchsten Wert finden

Um weitere Informationen über die höchste Punktzahl in einer Liste anzuzeigen, können wir eine Kombination aus den Funktionen INDEX und VERGLEICH verwenden.

Die endgültige Formel, um den Namen des Spielers mit der höchsten Punktzahl zu finden, lautet:

=INDEX(B3:B8;VERGLEICH(MAX(D3:D8);D3:D8;0))

Adresse des höchsten Wertes im Bereich MAX VERGLEICH INDEX Funktion

Um dies schrittweise zu erklären, ermitteln wir zunächst genau, welche Zelle die höchste Punktzahl im Datenbereich enthält.

=VERGLEICH(MAX(D3:D8);D3:D8;0)

Diese Formel verwendet die VERGLEICH-Funktion, um die erste Zelle, die mit dem höchsten Wert übereinstimmt, in der Liste der Werte zu identifizieren.

=VERGLEICH(8;{2; 4; 6; 8; 3; 5};0)

Sie findet die erste exakte Übereinstimmung in der 4. Zelle und liefert somit das Ergebnis 4.

=4

Zurück zur vollständigen Formel:

=INDEX(B3:B8;VERGLEICH(MAX(D3:D8);D3:D8;0))

Wir fügen nun die Liste der Spielernamen hinzu und ersetzen den Wert der VERGLEICH-Formel.

=INDEX({"A"; "B"; "C"; "D"; "E"; "F"}; 4)

Jetzt gibt die INDEX-Funktion den Zellenwert der 4. Zelle in der Liste der Spielernamen zurück

="D"

Beachten Sie, dass nur die erste Übereinstimmung durch diese Formel identifiziert wird, wenn mehr als eine Zelle eine Punktzahl von 8 enthält.

Zusätzliche Informationen über die Datenzeile mit der höchsten Punktzahl können angezeigt werden, indem diese Formel angepasst wird, um Werte aus anderen Spalten anzuzeigen.

Um das Datum der höchsten Punktzahl anzuzeigen, können wir Folgendes schreiben:

=INDEX(C3:C8;VERGLEICH(MAX(D3:D8);D3:D8;0))

Datum des höchsten Wertes im Bereich MAX VERGLEICH INDEX Funktion

Die Zellenadresse des höchsten Wertes in einem Bereich ermitteln

Wir können die Logik des vorherigen Beispiels erweitern, um die Zellenadresse des höchsten Wertes anzuzeigen, indem wir die Funktion ZELLE neben den bereits verwendeten Funktionen INDEX, VERGLEICH und MAX verwenden.

=ZELLE("ADDRESS";INDEX(D3:D8;VERGLEICH(MAX(D3:D8);D3:D8;0))

Adresse des höchsten Wertes im Bereich ZELLE MAX VERGLEICH INDEX Funktion

Der INDEX- und VERGLEICH-Teil der Formel würde normalerweise verwendet werden, um den Wert einer Zelle auszugeben, aber wir werden die ZELLE-Funktion verwenden, um ein anderes Merkmal auszugeben. Durch die Verwendung des Arguments „ADDRESS“ und der vorherigen INDEX-VERGLEICH-Formel können wir einen Zellbezug erzeugen, der die höchste Punktzahl angibt.

Dieser Zellbezug kann dann als Eingabe in anderen Formeln verwendet werden, indem man die INDIREKT-Funktion verwendet.